Moved from sunrise overlay. Fixes bug #299819

(Portage version: 2.2_rc67/cvs/Linux x86_64)

3 files changed, 90 insertions, 0 deletions

diff --git a/media-video/rtmpdump/ChangeLog b/media-video/rtmpdump/ChangeLog
new file mode 100644
index 000000000000..8d48f0ae5517
--- /dev/null
+++ b/media-video/rtmpdump/ChangeLog
@@ -0,0 +1,15 @@
+# ChangeLog for media-video/rtmpdump
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/rtmpdump/ChangeLog,v 1.1 2010/06/05 11:07:22 hwoarang Exp $
+
+*rtmpdump-2.2d (05 Jun 2010)
+
+  05 Jun 2010; Markos Chandras <hwoarang@gentoo.org> +rtmpdump-2.2d.ebuild,
+  +metadata.xml:
+  Moved from sunrise overlay. Fixes bug #299819. Thanks to Maxime de Roucy
+  (maxime1986) <maxime.deroucy@gmail.com> for the sunrise ebuild
+
+  30 May 2010; Maxime de Roucy (maxime1986) <maxime.deroucy@gmail.com>
+  +rtmpdump-2.2d.ebuild, +metadata.xml:
+  New Ebuild for bug 299819 (thanks to Alec M.)
+
diff --git a/media-video/rtmpdump/metadata.xml b/media-video/rtmpdump/metadata.xml
new file mode 100644
index 000000000000..11704efe06b1
--- /dev/null
+++ b/media-video/rtmpdump/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>no-herd</herd>
+<maintainer>
+<email>hwoarang@gentoo.org</email>
+<name>Markos Chandras</name>
+</maintainer>
+<use>
+	<flag name='gnutls'>Use GnuTLS library instead of the default OpenSSL</flag>
+	<flag name='polarssl'>Use PolarSSL library instead of the default OpenSSL</flag>
+</use>
+<longdescription lang="en">
+</longdescription>
+</pkgmetadata>
+
diff --git a/media-video/rtmpdump/rtmpdump-2.2d.ebuild b/media-video/rtmpdump/rtmpdump-2.2d.ebuild
new file mode 100644
index 000000000000..4d2ca4b10f4a
--- /dev/null
+++ b/media-video/rtmpdump/rtmpdump-2.2d.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/rtmpdump/rtmpdump-2.2d.ebuild,v 1.1 2010/06/05 11:07:22 hwoarang Exp $
+
+EAPI="2"
+
+inherit toolchain-funcs
+
+DESCRIPTION="Open source command-line RTMP client intended to stream audio or video flash content"
+HOMEPAGE="http://rtmpdump.mplayerhq.hu/"
+SRC_URI="http://rtmpdump.mplayerhq.hu/download/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnutls polarssl ssl"
+
+DEPEND="ssl? (
+		gnutls? ( net-libs/gnutls )
+		polarssl? ( !gnutls? ( net-libs/polarssl ) )
+		!gnutls? ( !polarssl? ( dev-libs/openssl ) )
+	)
+	sys-libs/zlib"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	if ! use ssl && ( use gnutls ||	use polarssl ) ; then
+		ewarn "USE='gnutls polarssl' are ignored without USE='ssl'."
+		ewarn "Please review the local USE flags for this package."
+	fi
+}
+
+src_prepare() {
+	# fix Makefile ( bug #298535 and bug #318353 )
+	sed -i 's/\$(MAKEFLAGS)//g' Makefile \
+		|| die "failed to fix Makefile"
+}
+
+src_compile() {
+	local crypto=""
+	if use ssl ; then
+		if use gnutls ;	then
+			crypto="GNUTLS"
+		elif use polarssl ; then
+			crypto="POLARSSL"
+		else
+			crypto="OPENSSL"
+		fi
+	fi
+
+	emake CC=$(tc-getCC) LD=$(tc-getLD) \
+		OPT="${CFLAGS}" XLDFLAGS="${LDFLAGS}" CRYPTO="${crypto}" posix || die "emake failed"
+}
+
+src_install() {
+	dobin rtmpdump rtmpsuck rtmpsrv rtmpgw || die "dobin failed"
+	dodoc README ChangeLog rtmpdump.1.html rtmpgw.8.html || die "dodoc failed"
+	doman rtmpdump.1 rtmpgw.8 || die "doman failed"
+}