Version bump, bug #261201, thank DrChandra the Gentoo Person for report. Fixes statical linking with libpcap and make sure we don't use bundled libopts, bug #252940, thank Diego E. 'Flameeyes' Pettenò for report.

(Portage version: 2.2_rc28/cvs/Linux i686)

1 files changed, 56 insertions, 0 deletions

diff --git a/net-analyzer/tcpreplay/tcpreplay-3.4.1.ebuild b/net-analyzer/tcpreplay/tcpreplay-3.4.1.ebuild
new file mode 100644
index 000000000000..8c6fa9d9f971
--- /dev/null
+++ b/net-analyzer/tcpreplay/tcpreplay-3.4.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/tcpreplay/tcpreplay-3.4.1.ebuild,v 1.1 2009/04/05 19:14:22 pva Exp $
+
+EAPI="2"
+
+inherit eutils
+
+DESCRIPTION="replay saved tcpdump or snoop files at arbitrary speeds"
+HOMEPAGE="http://tcpreplay.synfin.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+IUSE="debug pcapnav +tcpdump"
+
+DEPEND="
+	>=sys-devel/autogen-5.9.7
+	dev-libs/libdnet	
+	>=net-libs/libpcap-0.9
+	tcpdump? ( net-analyzer/tcpdump )
+	pcapnav? ( net-libs/libpcapnav )"
+
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	echo "We don't use bundled libopts" > libopts/options.h
+	epatch "${FILESDIR}/tcpreplay-3.4.1-errx-exit.patch"
+}
+
+src_configure() {
+	# By default it uses static linking. Avoid that, bug 252940
+	econf --enable-shared \
+		--disable-local-libopts \
+		$(use_with tcpdump tcpdump /usr/sbin/tcpdump) \
+		$(use_with pcapnav pcapnav-config /usr/bin/pcapnav-config) \
+		$(use_enable debug)
+}
+
+src_test() {
+	if hasq userpriv "${FEATURES}"; then
+		ewarn "Some tested disabled due to FEATURES=userpriv"
+		ewarn "For a full test as root - make -C ${S}/test"
+		make -C test tcpprep || die "self test failed - see ${S}/test/test.log"
+	else
+		make test || {
+			ewarn "Note, that some tests require eth0 iface to be UP." ;
+			die "self test failed - see ${S}/test/test.log" ; }
+	fi
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die "emake install failed"
+	dodoc README docs/{CHANGELOG,CREDIT,HACKING,TODO} || die
+}