Version bump

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 00F7AB331B0F097F)

2 files changed, 75 insertions, 1 deletions

diff --git a/net-ftp/filezilla/ChangeLog b/net-ftp/filezilla/ChangeLog
index a61c4bed7a1e..599991eae8ce 100644
--- a/net-ftp/filezilla/ChangeLog
+++ b/net-ftp/filezilla/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-ftp/filezilla
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-ftp/filezilla/ChangeLog,v 1.121 2015/03/03 16:10:37 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/filezilla/ChangeLog,v 1.122 2015/03/30 12:05:01 voyageur Exp $
+
+*filezilla-3.10.3 (30 Mar 2015)
+
+  30 Mar 2015; Bernard Cafarelli <voyageur@gentoo.org>
+  +filezilla-3.10.3.ebuild:
+  Version bump
 
 *filezilla-3.10.2 (03 Mar 2015)
 
diff --git a/net-ftp/filezilla/filezilla-3.10.3.ebuild b/net-ftp/filezilla/filezilla-3.10.3.ebuild
new file mode 100644
index 000000000000..7315b0a5303e
--- /dev/null
+++ b/net-ftp/filezilla/filezilla-3.10.3.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/filezilla/filezilla-3.10.3.ebuild,v 1.1 2015/03/30 12:05:01 voyageur Exp $
+
+EAPI=5
+
+WX_GTK_VER="3.0"
+
+inherit autotools eutils flag-o-matic multilib wxwidgets
+
+MY_PV=${PV/_/-}
+MY_P="FileZilla_${MY_PV}"
+
+DESCRIPTION="FTP client with lots of useful features and an intuitive interface"
+HOMEPAGE="http://filezilla-project.org/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}_src.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux ~x86-macos"
+IUSE="aqua dbus nls test"
+
+RDEPEND=">=app-admin/eselect-wxwidgets-0.7-r1
+	>=dev-db/sqlite-3.7
+	>=dev-libs/tinyxml-2.6.1-r1[stl]
+	net-dns/libidn
+	>=net-libs/gnutls-3.1.12
+	aqua? ( >=x11-libs/wxGTK-3.0.2.0-r1:3.0[aqua] )
+	!aqua? ( >=x11-libs/wxGTK-3.0.2.0-r1:3.0[X] x11-misc/xdg-utils )
+	dbus? ( sys-apps/dbus )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	>=sys-devel/libtool-1.4
+	nls? ( >=sys-devel/gettext-0.11 )
+	test? ( dev-util/cppunit )"
+
+S="${WORKDIR}"/${PN}-${MY_PV}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-3.10.2-debug.patch
+	append-cppflags -DTIXML_USE_STL
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_with dbus) $(use_enable nls locales) \
+		--with-tinyxml=system \
+		--disable-autoupdatecheck
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	doicon src/interface/resources/48x48/${PN}.png
+
+	dodoc AUTHORS ChangeLog NEWS
+
+	if use aqua ; then
+		cat > "${T}/${PN}" <<-EOF
+			#!${EPREFIX}/bin/bash
+			open "${EPREFIX}"/Applications/FileZilla.app
+		EOF
+		rm "${ED}/usr/bin/${PN}" || die
+		dobin "${T}/${PN}"
+		insinto /Applications
+		doins -r "${S}"/FileZilla.app
+	fi
+}