Bump to ngircd-18.

(Portage version: 2.2.0_alpha50-r1/cvs/Linux x86_64)

2 files changed, 87 insertions, 1 deletions

diff --git a/net-irc/ngircd/ChangeLog b/net-irc/ngircd/ChangeLog
index 80747969342e..7a02751fb443 100644
--- a/net-irc/ngircd/ChangeLog
+++ b/net-irc/ngircd/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-irc/ngircd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/ngircd/ChangeLog,v 1.52 2011/02/01 17:38:24 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/ngircd/ChangeLog,v 1.53 2011/09/11 04:01:29 binki Exp $
+
+*ngircd-18 (11 Sep 2011)
+
+  11 Sep 2011; Nathan Phillip Brink <binki@gentoo.org> +ngircd-18.ebuild:
+  Bump to ngircd-18.
 
 *ngircd-17.1 (01 Feb 2011)
 
diff --git a/net-irc/ngircd/ngircd-18.ebuild b/net-irc/ngircd/ngircd-18.ebuild
new file mode 100644
index 000000000000..fe484ad12f2c
--- /dev/null
+++ b/net-irc/ngircd/ngircd-18.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/ngircd/ngircd-18.ebuild,v 1.1 2011/09/11 04:01:29 binki Exp $
+
+EAPI=4
+
+inherit autotools-utils eutils
+
+DESCRIPTION="A IRC server written from scratch"
+HOMEPAGE="http://ngircd.barton.de/"
+SRC_URI="ftp://ftp.berlios.de/pub/${PN}/${P}.tar.gz
+	ftp://ngircd.barton.de/pub/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x64-macos"
+IUSE="debug gnutls ident ipv6 pam ssl tcpd zlib"
+
+RDEPEND="
+	ident? ( net-libs/libident )
+	ssl? (
+		gnutls? ( net-libs/gnutls )
+		!gnutls? ( dev-libs/openssl )
+	)
+	pam? ( virtual/pam )
+	tcpd? ( sys-apps/tcp-wrappers )
+	zlib? ( sys-libs/zlib )
+"
+DEPEND="${RDEPEND}
+	>=sys-apps/sed-4
+"
+
+RESTRICT="test"
+
+src_configure() {
+	if ! use prefix; then
+		sed -i \
+			-e "s:;ServerUID = 65534:ServerUID = ngircd:" \
+			-e "s:;ServerGID = 65534:ServerGID = nogroup:" \
+			doc/sample-ngircd.conf.tmpl || die
+	fi
+
+	local myeconfargs=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		--sysconfdir="${EPREFIX}"/etc/ngircd
+		$(use_enable ipv6)
+		$(use_with zlib)
+		$(use_with tcpd tcp-wrappers)
+		$(use_with ident)
+		$(use_with pam)
+		$(use_enable debug)
+		$(use_enable debug sniffer)
+	)
+
+	if use ssl; then
+		myeconfargs+=(
+			$(use_with !gnutls openssl)
+			$(use_with gnutls)
+		)
+	else
+		myeconfargs+=(
+			--without-gnutls
+			--without-ssl
+		)
+	fi
+
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	newinitd "${FILESDIR}"/ngircd.init.d ngircd
+}
+
+pkg_postinst() {
+	if ! use prefix; then
+		enewuser ngircd
+		chown ngircd "${ROOT}"/etc/ngircd/ngircd.conf
+	fi
+}