Revbumps for 2.10.2 and 2.11.4 wrt bug 333403. New valgrind use flag added.

(Portage version: 2.2.0_alpha4/cvs/Linux i686)

4 files changed, 146 insertions, 12 deletions

diff --git a/net-libs/gnutls/ChangeLog b/net-libs/gnutls/ChangeLog
index bb84df4ecd2b..5cfab6e8d387 100644
--- a/net-libs/gnutls/ChangeLog
+++ b/net-libs/gnutls/ChangeLog
@@ -1,6 +1,22 @@
 # ChangeLog for net-libs/gnutls
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.276 2010/11/06 17:40:45 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.277 2010/11/10 20:23:59 c1pher Exp $
+
+*gnutls-2.11.4-r1 (10 Nov 2010)
+*gnutls-2.10.2-r1 (10 Nov 2010)
+
+  10 Nov 2010; Dane Smith <c1pher@gentoo.org> -gnutls-2.10.1-r1.ebuild,
+  +gnutls-2.10.2-r1.ebuild, +gnutls-2.11.4-r1.ebuild, metadata.xml:
+  *Revision bumps for 2.10.2 and 2.11.4 include new valgrind use flag to fix
+  automahic dependency wrt bug 333403. 
+  *Small QA fixes in both.
+  *Removed keywords for alpha ia64 m68k s390 sh sparc in 2.10.2-r1 as
+  datefudge
+  is not keyworded for those archs. I will be opening a keyword req for
+  datefudge.
+  *Removed 2.10.1-r1 as it contained an ~alpha keyword when datefudge was
+  not
+  keyworded for alpha.
 
   06 Nov 2010; Markus Meier <maekke@gentoo.org> gnutls-2.10.2.ebuild:
   arm stable, bug #343755
diff --git a/net-libs/gnutls/gnutls-2.10.1-r1.ebuild b/net-libs/gnutls/gnutls-2.10.2-r1.ebuild
index 3de1eb80aa24..642d400dc224 100644
--- a/net-libs/gnutls/gnutls-2.10.1-r1.ebuild
+++ b/net-libs/gnutls/gnutls-2.10.2-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-2.10.1-r1.ebuild,v 1.2 2010/10/10 16:07:40 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-2.10.2-r1.ebuild,v 1.1 2010/11/10 20:23:59 c1pher Exp $
 
 EAPI="3"
 
@@ -26,8 +26,8 @@ fi
 # GPL-3 for the gnutls-extras library and LGPL for the gnutls library.
 LICENSE="LGPL-2.1 GPL-3"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86 ~sparc-fbsd ~x86-fbsd"
-IUSE="bindist +cxx doc examples guile lzo nls test zlib"
+KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="bindist +cxx doc examples guile lzo nls test valgrind zlib"
 
 RDEPEND="dev-libs/libgpg-error
 	>=dev-libs/libgcrypt-1.4.0
@@ -40,14 +40,18 @@ DEPEND="${RDEPEND}
 	sys-devel/libtool
 	doc? ( dev-util/gtk-doc )
 	nls? ( sys-devel/gettext )
-	test? ( app-misc/datefudge )"
+	test? ( valgrind? ( dev-util/valgrind ) app-misc/datefudge )"
 
 S="${WORKDIR}/${P%_pre*}"
 
 pkg_setup() {
 	if use lzo && use bindist; then
-		ewarn "lzo support was disabled for binary distribution of GnuTLS"
-		ewarn "due to licensing issues. See Bug #202381 for details."
+		ewarn "lzo support is disabled for binary distribution of GnuTLS due to licensing issues."
+	fi
+
+	if use valgrind && ! use test; then
+		ewarn "Valgrind is part of the test suite and which is not currently \
+		being used. Disabling valgrind."
 	fi
 }
 
@@ -65,12 +69,16 @@ src_prepare() {
 		popd > /dev/null
 	done
 
-	elibtoolize # for sane .so versioning on FreeBSD
+	# Use sane .so versioning on FreeBSD.
+	elibtoolize
 }
 
 src_configure() {
 	local myconf
 	use bindist && myconf="--without-lzo" || myconf="$(use_with lzo)"
+	use test && myconf="${myconf} $(use_enable valgrind valgrind-tests)" || \
+	myconf="${myconf} --disable-valgrind-tests"
+
 	econf --htmldir=/usr/share/doc/${P}/html \
 		$(use_enable cxx) \
 		$(use_enable doc gtk-doc) \
@@ -83,15 +91,15 @@ src_configure() {
 src_install() {
 	emake DESTDIR="${D}" install || die "emake install failed"
 
-	dodoc AUTHORS ChangeLog NEWS README THANKS doc/TODO
+	dodoc AUTHORS ChangeLog NEWS README THANKS doc/TODO || die
 
 	if use doc; then
-		dodoc doc/gnutls.{pdf,ps}
-		dohtml doc/gnutls.html
+		dodoc doc/gnutls.{pdf,ps} || die
+		dohtml doc/gnutls.html || die
 	fi
 
 	if use examples; then
 		docinto examples
-		dodoc doc/examples/*.c
+		dodoc doc/examples/*.c || die
 	fi
 }
diff --git a/net-libs/gnutls/gnutls-2.11.4-r1.ebuild b/net-libs/gnutls/gnutls-2.11.4-r1.ebuild
new file mode 100644
index 000000000000..b36f83e07695
--- /dev/null
+++ b/net-libs/gnutls/gnutls-2.11.4-r1.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-2.11.4-r1.ebuild,v 1.1 2010/11/10 20:23:59 c1pher Exp $
+
+EAPI="3"
+
+inherit autotools libtool
+
+DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
+HOMEPAGE="http://www.gnutls.org/"
+
+if [[ "${PV}" == *pre* ]]; then
+	SRC_URI="http://daily.josefsson.org/${P%.*}/${P%.*}-${PV#*pre}.tar.gz"
+else
+	MINOR_VERSION="${PV#*.}"
+	MINOR_VERSION="${MINOR_VERSION%.*}"
+	if [[ $((MINOR_VERSION % 2)) == 0 ]]; then
+		#SRC_URI="ftp://ftp.gnu.org/pub/gnu/${PN}/${P}.tar.bz2"
+		SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"
+	else
+		SRC_URI="ftp://alpha.gnu.org/gnu/${PN}/${P}.tar.bz2"
+	fi
+	unset MINOR_VERSION
+fi
+
+# GPL-3 for the gnutls-extras library and LGPL for the gnutls library.
+LICENSE="LGPL-2.1 GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="bindist +cxx doc examples guile lzo +nettle nls test valgrind zlib"
+
+# lib/m4/hooks.m4 says that GnuTLS uses a fork of PaKChoiS.
+RDEPEND=">=dev-libs/libtasn1-0.3.4
+	nls? ( virtual/libintl )
+	guile? ( dev-scheme/guile[networking] )
+	nettle? ( >=dev-libs/nettle-2.1[gmp] )
+	!nettle? ( >=dev-libs/libgcrypt-1.4.0 )
+	zlib? ( >=sys-libs/zlib-1.1 )
+	!bindist? ( lzo? ( >=dev-libs/lzo-2 ) )"
+DEPEND="${RDEPEND}
+	sys-devel/libtool
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )
+	test? ( valgrind? ( dev-util/valgrind ) app-misc/datefudge )"
+
+S="${WORKDIR}/${P%_pre*}"
+
+pkg_setup() {
+	if use lzo && use bindist; then
+		ewarn "lzo support is disabled for binary distribution of GnuTLS due to licensing issues."
+	fi
+
+	if use valgrind && ! use test; then
+		ewarn "Valgrind is part of the test suite and which is not currently \
+		being used. Disabling valgrind."
+	fi
+}
+
+src_prepare() {
+	sed -e 's/imagesdir = $(infodir)/imagesdir = $(htmldir)/' -i doc/Makefile.am
+
+	local dir
+	for dir in m4 lib/m4 libextra/m4; do
+		rm -f "${dir}/lt"* "${dir}/libtool.m4"
+	done
+	find . -name ltmain.sh -exec rm {} \;
+	for dir in . lib libextra; do
+		pushd "${dir}" > /dev/null
+		eautoreconf
+		popd > /dev/null
+	done
+
+	# Use sane .so versioning on FreeBSD.
+	elibtoolize
+}
+
+src_configure() {
+	local myconf
+	use bindist && myconf="--without-lzo" || myconf="$(use_with lzo)"
+	use test && myconf="${myconf} $(use_enable valgrind valgrind-tests)" || \
+	myconf="${myconf} --disable-valgrind-tests"
+
+	econf --htmldir=/usr/share/doc/${P}/html \
+		$(use_enable cxx) \
+		$(use_enable doc gtk-doc) \
+		$(use_enable guile) \
+		$(use_with !nettle libgcrypt) \
+		$(use_enable nls) \
+		$(use_with zlib) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	dodoc AUTHORS ChangeLog NEWS README THANKS doc/TODO || die
+
+	if use doc; then
+		dodoc doc/gnutls.{pdf,ps} || die
+		dohtml doc/gnutls.html || die
+	fi
+
+	if use examples; then
+		docinto examples
+		dodoc doc/examples/*.c || die
+	fi
+}
diff --git a/net-libs/gnutls/metadata.xml b/net-libs/gnutls/metadata.xml
index 6f279968eaa1..a7f757cbfdf8 100644
--- a/net-libs/gnutls/metadata.xml
+++ b/net-libs/gnutls/metadata.xml
@@ -5,4 +5,7 @@
 	<use>
 		<flag name="nettle">Use <pkg>dev-libs/nettle</pkg> as crypto backend</flag>
 	</use>
+	<use>
+		<flag name="valgrind">Enable testing using <pkg>dev-util/valgrind</pkg>.</flag>
+	</use>
 </pkgmetadata>