Backport the distutils-r1 conversion to the stable branch. Respect the Python interpreter.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 61 insertions, 1 deletions

diff --git a/net-misc/arm/ChangeLog b/net-misc/arm/ChangeLog
index ef05b4dbfc95..2e03027a2956 100644
--- a/net-misc/arm/ChangeLog
+++ b/net-misc/arm/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/arm
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/arm/ChangeLog,v 1.33 2014/11/15 19:28:27 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/arm/ChangeLog,v 1.34 2014/12/08 22:47:30 mgorny Exp $
+
+*arm-1.4.5.0-r2 (08 Dec 2014)
+
+  08 Dec 2014; Michał Górny <mgorny@gentoo.org> +arm-1.4.5.0-r2.ebuild:
+  Backport the distutils-r1 conversion to the stable branch. Respect the Python
+  interpreter.
 
   15 Nov 2014; Anthony G. Basile <blueness@gentoo.org>
   arm-1.4.5.0_p20140714-r2.ebuild:
diff --git a/net-misc/arm/arm-1.4.5.0-r2.ebuild b/net-misc/arm/arm-1.4.5.0-r2.ebuild
new file mode 100644
index 000000000000..ae86674b2b9c
--- /dev/null
+++ b/net-misc/arm/arm-1.4.5.0-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/arm/arm-1.4.5.0-r2.ebuild,v 1.1 2014/12/08 22:47:30 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE='ncurses'
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1
+
+DESCRIPTION="A ncurses-based status monitor for Tor relays"
+HOMEPAGE="http://www.atagar.com/arm/"
+SRC_URI="http://www.atagar.com/arm/resources/static/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE=""
+
+# Note: While we depend on net-misc/tor, we strictly speaking
+# don't have to because it could run on a different machine.
+RDEPEND="
+	>=net-misc/tor-0.2.1.27
+	app-admin/sudo
+	sys-apps/man
+	sys-process/lsof
+	net-dns/bind-tools"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+python_prepare_all() {
+	python_fix_shebang .
+
+	distutils-r1_python_prepare_all
+}
+
+python_install() {
+	distutils-r1_python_install \
+		--docPath "${EPREFIX}/usr/share/doc/${PF}"
+
+	sed -i -e "s:python:${EPYTHON}:" "${ED}"usr/bin/arm || die
+}
+
+pkg_postinst() {
+	elog "Some graphing data issues have been noted in testing"
+	elog "when run as root. It is not recommended to run arm as"
+	elog "root until those issues have been isolated and fixed."
+	elog
+	elog "Trouble with graphs under app-misc/screen? Try:"
+	elog 'TERM="rxvt-unicode" arm'
+}