Add version 0.69

(Portage version: 2.1.9.39/cvs/Linux x86_64)

3 files changed, 83 insertions, 1 deletions

diff --git a/net-misc/connman/ChangeLog b/net-misc/connman/ChangeLog
index 57d84a051297..229a88e1b29e 100644
--- a/net-misc/connman/ChangeLog
+++ b/net-misc/connman/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/connman
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/connman/ChangeLog,v 1.33 2011/01/25 13:47:16 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/connman/ChangeLog,v 1.34 2011/02/15 10:35:00 dagger Exp $
+
+*connman-0.69 (15 Feb 2011)
+
+  15 Feb 2011; Robert Piasek <dagger@gentoo.org> +connman-0.69.ebuild:
+  Add version 0.69
 
   25 Jan 2011; Tiziano Müller <dev-zero@gentoo.org> connman-0.67-r1.ebuild:
   Moved linux-headers dep to DEPEND, added missing gnutls dependency.
diff --git a/net-misc/connman/connman-0.69.ebuild b/net-misc/connman/connman-0.69.ebuild
new file mode 100644
index 000000000000..b71f75982458
--- /dev/null
+++ b/net-misc/connman/connman-0.69.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/connman/connman-0.69.ebuild,v 1.1 2011/02/15 10:35:00 dagger Exp $
+
+EAPI="2"
+
+inherit multilib eutils
+
+DESCRIPTION="Provides a daemon for managing internet connections"
+HOMEPAGE="http://connman.net"
+SRC_URI="mirror://kernel/linux/network/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="bluetooth +caps debug doc examples +ethernet google ofono ntpd openvpn policykit threads tools vpnc +wifi wimax"
+# gps meego ospm openconnect
+
+RDEPEND=">=dev-libs/glib-2.16
+	>=sys-apps/dbus-1.2.24
+	>=dev-libs/libnl-1.1
+	>=net-firewall/iptables-1.4.8
+	net-libs/gnutls
+	bluetooth? ( net-wireless/bluez )
+	caps? ( sys-libs/libcap-ng )
+	ntpd? ( net-misc/ntp )
+	ofono? ( net-misc/ofono )
+	policykit? ( sys-auth/polkit )
+	openvpn? ( net-misc/openvpn )
+	vpnc? ( net-misc/vpnc )
+	wifi? ( >=net-wireless/wpa_supplicant-0.7[dbus] )
+	wimax? ( net-wireless/wimax )"
+
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.30
+	doc? ( dev-util/gtk-doc )"
+
+src_configure() {
+	econf \
+		--localstatedir=/var \
+		--enable-client \
+		--enable-nmcompat=builtin \
+		--enable-fake \
+		--enable-datafiles \
+		--enable-loopback=builtin \
+		$(use_enable caps capng) \
+		$(use_enable examples test) \
+		$(use_enable ethernet ethernet builtin) \
+		$(use_enable wifi wifi builtin) \
+		$(use_enable bluetooth bluetooth builtin) \
+		$(use_enable ntpd ntpd builtin) \
+		$(use_enable ofono ofono builtin) \
+		$(use_enable google google builtin) \
+		$(use_enable openvpn openvpn builtin) \
+		$(use_enable policykit polkit builtin) \
+		$(use_enable vpnc vpnc builtin) \
+		$(use_enable wimax iwmx builtin) \
+		$(use_enable debug) \
+		$(use_enable doc gtk-doc) \
+		$(use_enable threads) \
+		$(use_enable tools) \
+		--disable-iospm \
+		--disable-hh2serial-gps \
+		--disable-portal \
+		--disable-meego \
+		--disable-openconnect
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dobin client/cm || die "client installation failed"
+
+	keepdir /var/"$(get_libdir)"/${PN} || die
+	newinitd "${FILESDIR}"/${PN}.initd ${PN} || die
+	newconfd "${FILESDIR}"/${PN}.confd ${PN} || die
+}
diff --git a/net-misc/connman/metadata.xml b/net-misc/connman/metadata.xml
index 8c1a21c4f751..467882102eea 100644
--- a/net-misc/connman/metadata.xml
+++ b/net-misc/connman/metadata.xml
@@ -14,6 +14,7 @@
 		<flag name="ofono">Use <pkg>net-misc/ofono</pkg> for telephony support.</flag>
 		<flag name="openvpn">Use <pkg>net-misc/openvpn</pkg> for openvpn support.</flag>
 		<flag name="tools">Enable testing tools.</flag>
+		<flag name="vpnc">Use <pkg>net-misc/vpnc</pkg> for cisco VPN support.</flag>
 		<flag name="wimax">Use <pkg>net-wireless/wimax</pkg> for WiMAX support.</flag>
 	</use>
 </pkgmetadata>