Version bump. Includes fix for bug #487922.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 67 insertions, 1 deletions

diff --git a/net-misc/netifrc/ChangeLog b/net-misc/netifrc/ChangeLog
index e1b25fc2b7c1..734f1fead059 100644
--- a/net-misc/netifrc/ChangeLog
+++ b/net-misc/netifrc/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/netifrc
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/netifrc/ChangeLog,v 1.18 2014/01/19 19:38:15 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/netifrc/ChangeLog,v 1.19 2014/03/05 18:44:26 robbat2 Exp $
+
+*netifrc-0.2.1 (05 Mar 2014)
+
+  05 Mar 2014; Robin H. Johnson <robbat2@gentoo.org> +netifrc-0.2.1.ebuild:
+  Version bump. Includes fix for bug #487922.
 
   19 Jan 2014; Agostino Sarubbo <ago@gentoo.org> netifrc-0.1.ebuild:
   Stable for sparc, wrt bug #487332
diff --git a/net-misc/netifrc/netifrc-0.2.1.ebuild b/net-misc/netifrc/netifrc-0.2.1.ebuild
new file mode 100644
index 000000000000..3f74612649a6
--- /dev/null
+++ b/net-misc/netifrc/netifrc-0.2.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/netifrc/netifrc-0.2.1.ebuild,v 1.1 2014/03/05 18:44:26 robbat2 Exp $
+
+EAPI=5
+
+inherit eutils
+
+DESCRIPTION="Gentoo Network Interface Management Scripts"
+HOMEPAGE="http://www.gentoo.org/proj/en/base/openrc/"
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="git://git.overlays.gentoo.org/proj/${PN}.git"
+	inherit git-2
+else
+	SRC_URI="http://dev.gentoo.org/~robbat2/distfiles/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE=""
+
+DEPEND=""
+RDEPEND=">=sys-apps/openrc-0.12
+	!<sys-apps/openrc-0.12"
+
+src_prepare() {
+	if [[ ${PV} == "9999" ]] ; then
+		local ver="git-${EGIT_VERSION:0:6}"
+		sed -i "/^GITVER[[:space:]]*=/s:=.*:=${ver}:" mk/git.mk || die
+		einfo "Producing ChangeLog from Git history"
+		GIT_DIR="${S}/.git" git log >"${S}"/ChangeLog
+	fi
+
+	# Allow user patches to be applied without modifying the ebuild
+	epatch_user
+}
+
+src_compile() {
+	MAKE_ARGS="${MAKE_ARGS}
+		LIBEXECDIR=${EPREFIX}/lib/${PN} PF=${PF}"
+
+	use prefix && MAKE_ARGS="${MAKE_ARGS} MKPREFIX=yes PREFIX=${EPREFIX}"
+
+	emake ${MAKE_ARGS} all
+}
+
+src_install() {
+	emake ${MAKE_ARGS} DESTDIR="${D}" install
+	dodoc README CREDITS FEATURE-REMOVAL-SCHEDULE STYLE TODO ChangeLog
+}
+
+pkg_postinst() {
+	if [[ ! -e "${EROOT}"/etc/conf.d/net && -z $REPLACING_VERSIONS ]]; then
+		elog "The network configuration scripts will use dhcp by"
+		elog "default to set up your interfaces."
+		elog "If you need to set up something more complete, see"
+		elog "${EROOT}/usr/share/doc/${P}/README"
+	fi
+}