Version bump to 1.6, smaller cleanup. Add -j1 for 1.1 since it's not parallel-build safe (it's fixed in 1.4 and later).

(Portage version: 2.2_rc67/cvs/Linux x86_64)

3 files changed, 79 insertions, 5 deletions

diff --git a/net-misc/radvd/ChangeLog b/net-misc/radvd/ChangeLog
index 6d8e86a43572..c404b7e017c6 100644
--- a/net-misc/radvd/ChangeLog
+++ b/net-misc/radvd/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/radvd
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/radvd/ChangeLog,v 1.56 2009/11/16 09:15:46 wschlich Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/radvd/ChangeLog,v 1.57 2010/07/06 14:37:11 flameeyes Exp $
+
+*radvd-1.6 (06 Jul 2010)
+
+  06 Jul 2010; Diego E. Pettenò <flameeyes@gentoo.org> radvd-1.1.ebuild,
+  +radvd-1.6.ebuild:
+  Version bump to 1.6, smaller cleanup. Add -j1 for 1.1 since it's not
+  parallel-build safe (it's fixed in 1.4 and later).
 
 *radvd-1.5 (16 Nov 2009)
 
diff --git a/net-misc/radvd/radvd-1.1.ebuild b/net-misc/radvd/radvd-1.1.ebuild
index aeebbf291f29..ee20333402fc 100644
--- a/net-misc/radvd/radvd-1.1.ebuild
+++ b/net-misc/radvd/radvd-1.1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2009 Gentoo Foundation
+# Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/radvd/radvd-1.1.ebuild,v 1.9 2009/08/20 11:42:38 rbu Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/radvd/radvd-1.1.ebuild,v 1.10 2010/07/06 14:37:11 flameeyes Exp $
 
 inherit eutils autotools
 
@@ -38,7 +38,7 @@ src_compile() {
 		--with-pidfile=/var/run/radvd/radvd.pid \
 		|| die "econf failed"
 
-	emake || die "emake failed"
+	emake -j1 || die "emake failed"
 }
 
 src_install() {
diff --git a/net-misc/radvd/radvd-1.6.ebuild b/net-misc/radvd/radvd-1.6.ebuild
new file mode 100644
index 000000000000..ba35b426ac81
--- /dev/null
+++ b/net-misc/radvd/radvd-1.6.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/radvd/radvd-1.6.ebuild,v 1.1 2010/07/06 14:37:11 flameeyes Exp $
+
+EAPI=2
+inherit eutils
+
+DESCRIPTION="Linux IPv6 Router Advertisement Daemon"
+HOMEPAGE="http://v6web.litech.org/radvd/"
+SRC_URI="http://v6web.litech.org/radvd/dist/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sparc ~x86 ~x86-fbsd"
+IUSE="kernel_FreeBSD"
+
+DEPEND="sys-devel/bison
+	sys-devel/flex"
+RDEPEND=""
+
+pkg_setup() {
+	enewgroup radvd
+	enewuser radvd -1 -1 /dev/null radvd
+
+	# force ownership of radvd user and group (bug #19647)
+	[[ -d ${ROOT}/var/run/radvd ]] && chown radvd:radvd "${ROOT}"/var/run/radvd
+}
+
+src_configure() {
+	econf \
+		--with-pidfile=/var/run/radvd/radvd.pid \
+		|| die "econf failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+
+	dodoc CHANGES README TODO radvd.conf.example || die
+	dohtml INTRO.html || die
+
+	newinitd "${FILESDIR}/${PN}".init "${PN}" || die
+	newconfd "${FILESDIR}/${PN}".conf "${PN}" || die
+
+	# location of radvd.pid needs to be writeable by the radvd user
+	keepdir /var/run/radvd
+	chown -R radvd:radvd "${D}"/var/run/radvd || die
+	fperms 755 /var/run/radvd
+
+	if use kernel_FreeBSD ; then
+		sed -i -e \
+			's/^SYSCTL_FORWARD=.*$/SYSCTL_FORWARD=net.inet6.ip6.forwarding/g' \
+			"${D}"/etc/init.d/"${PN}" || die
+	fi
+}
+
+pkg_postinst() {
+	elog
+	elog "To use ${PN} you must create the configuration file"
+	elog "${ROOT}etc/radvd.conf"
+	elog
+	elog "An example configuration file has been installed under"
+	elog "${ROOT}usr/share/doc/${PF}"
+	elog
+	elog "grsecurity users should allow a specific group to read /proc"
+	elog "and add the radvd user to that group, otherwise radvd may"
+	elog "segfault on startup."
+}