Version bump for Gnome 3.8

(Portage version: 2.1.11.58/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 69 insertions, 1 deletions

diff --git a/net-misc/vinagre/ChangeLog b/net-misc/vinagre/ChangeLog
index 178f7ab25a56..72742c07d80a 100644
--- a/net-misc/vinagre/ChangeLog
+++ b/net-misc/vinagre/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/vinagre
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/vinagre/ChangeLog,v 1.88 2013/02/02 23:07:03 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/vinagre/ChangeLog,v 1.89 2013/03/28 17:57:56 pacho Exp $
+
+*vinagre-3.8.0 (28 Mar 2013)
+
+  28 Mar 2013; Pacho Ramos <pacho@gentoo.org> +vinagre-3.8.0.ebuild:
+  Version bump for Gnome 3.8
 
   02 Feb 2013; Agostino Sarubbo <ago@gentoo.org> vinagre-3.6.2.ebuild:
   Add ~arm, wrt bug #449220
diff --git a/net-misc/vinagre/vinagre-3.8.0.ebuild b/net-misc/vinagre/vinagre-3.8.0.ebuild
new file mode 100644
index 000000000000..2eaae3076bc8
--- /dev/null
+++ b/net-misc/vinagre/vinagre-3.8.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/vinagre/vinagre-3.8.0.ebuild,v 1.1 2013/03/28 17:57:56 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+VALA_MIN_API_VERSION=0.18
+
+inherit gnome2 vala
+
+DESCRIPTION="VNC client for the GNOME desktop"
+HOMEPAGE="http://live.gnome.org/Vinagre"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="avahi rdp +ssh spice +telepathy"
+
+# cairo used in vinagre-tab
+# gdk-pixbuf used all over the place
+RDEPEND="
+	>=dev-libs/glib-2.28.0:2
+	>=x11-libs/gtk+-3.0.3:3
+	app-crypt/libsecret
+	>=dev-libs/libxml2-2.6.31:2
+	>=net-libs/gtk-vnc-0.4.3[gtk3]
+	x11-libs/cairo:=
+	x11-libs/gdk-pixbuf:2
+	x11-themes/gnome-icon-theme
+
+	avahi? ( >=net-dns/avahi-0.6.26[dbus,gtk3] )
+	rdp? ( net-misc/rdesktop )
+	ssh? ( >=x11-libs/vte-0.20:2.90 )
+	spice? ( >=net-misc/spice-gtk-0.5[gtk3] )
+	telepathy? (
+		dev-libs/dbus-glib
+		>=net-libs/telepathy-glib-0.11.6 )
+"
+DEPEND="${RDEPEND}
+	>=dev-lang/perl-5
+	>=dev-util/intltool-0.50
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+	$(vala_depend)
+"
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog ChangeLog.pre-git NEWS README"
+	G2CONF="${G2CONF} ITSTOOL=$(type -P true)"
+	gnome2_src_configure \
+		$(use_with avahi) \
+		$(use_enable rdp) \
+		$(use_enable ssh) \
+		$(use_enable spice) \
+		$(use_with telepathy)
+}
+
+src_install() {
+	gnome2_src_install
+
+	# Remove its own installation of DOCS that go to $PN instead of $P and aren't ecompressed
+	rm -rf "${ED}"/usr/share/doc/vinagre
+}