Fix DoS vulnerability and remove vulnerable version (CVE-2013-5745, bug #486694, thanks to Agostino Sarubbo).

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

3 files changed, 95 insertions, 78 deletions

diff --git a/net-misc/vino/ChangeLog b/net-misc/vino/ChangeLog
index 39b5d9d55376..8041f916b7e0 100644
--- a/net-misc/vino/ChangeLog
+++ b/net-misc/vino/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/vino
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/vino/ChangeLog,v 1.191 2013/09/13 22:41:08 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/vino/ChangeLog,v 1.192 2013/10/01 21:42:06 tetromino Exp $
+
+*vino-2.32.2-r2 (01 Oct 2013)
+
+  01 Oct 2013; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +vino-2.32.2-r2.ebuild, -vino-3.8.1.ebuild:
+  Fix DoS vulnerability and remove vulnerable version (CVE-2013-5745, bug
+  #486694, thanks to Agostino Sarubbo).
 
 *vino-3.8.1-r1 (14 Sep 2013)
 
diff --git a/net-misc/vino/vino-2.32.2-r2.ebuild b/net-misc/vino/vino-2.32.2-r2.ebuild
new file mode 100644
index 000000000000..7a6df9105c05
--- /dev/null
+++ b/net-misc/vino/vino-2.32.2-r2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/vino/vino-2.32.2-r2.ebuild,v 1.1 2013/10/01 21:42:06 tetromino Exp $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+GNOME_TARBALL_SUFFIX="bz2"
+
+inherit eutils gnome2
+
+DESCRIPTION="An integrated VNC server for GNOME"
+HOMEPAGE="http://live.gnome.org/Vino"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="avahi crypt ipv6 jpeg gnome-keyring libnotify networkmanager ssl +telepathy zlib"
+
+RDEPEND=">=dev-libs/glib-2.17:2
+	>=x11-libs/gtk+-2.20:2
+	>=gnome-base/gconf-2:2
+	>=sys-apps/dbus-1.2.3
+	>=net-libs/libsoup-2.24:2.4
+	dev-libs/libunique:1
+	dev-libs/dbus-glib
+	x11-libs/libXext
+	x11-libs/libXtst
+	avahi? ( >=net-dns/avahi-0.6:=[dbus] )
+	crypt? ( >=dev-libs/libgcrypt-1.1.90:= )
+	gnome-keyring? ( || ( gnome-base/libgnome-keyring <gnome-base/gnome-keyring-2.29.4 ) )
+	jpeg? ( virtual/jpeg:0= )
+	libnotify? ( >=x11-libs/libnotify-0.4.4:= )
+	networkmanager? ( >=net-misc/networkmanager-0.7 )
+	ssl? ( >=net-libs/gnutls-1:= )
+	telepathy? ( >=net-libs/telepathy-glib-0.11.6 )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	>=dev-lang/perl-5
+	virtual/pkgconfig
+	>=dev-util/intltool-0.40
+	|| (
+		gnome-base/libgnome-keyring
+		<gnome-base/gnome-keyring-2.29.4 )"
+# keyring is always required at build time per bug 322763
+
+# bug #394611; tight encoding requires zlib encoding
+REQUIRED_USE="jpeg? ( zlib )"
+
+src_prepare() {
+	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README"
+
+	# Fix autorestart loop, bug #277989
+	epatch "${FILESDIR}/${PN}-2.26.2-autorestart-loop.patch"
+
+	# clipboard leak to unauthenticated clients, bug #434930
+	epatch "${FILESDIR}/${PN}-3.6.2-clipboard-leak.patch"
+
+	# DoS fix from 3.8.2/3.10, bug #486694
+	epatch "${FILESDIR}/${PN}-3.8.1-new-client.patch"
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable avahi) \
+		$(use_enable crypt gcrypt) \
+		$(use_enable ipv6) \
+		$(use_with jpeg) \
+		$(use_enable gnome-keyring) \
+		$(use_enable libnotify) \
+		$(use_enable networkmanager network-manager) \
+		$(use_enable ssl gnutls) \
+		$(use_enable telepathy) \
+		$(use_with zlib) \
+		$(use_with zlib libz) \
+		--enable-libunique
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog "If you are getting refresh problems when using special 3D effects,"
+	elog "try disabling XDamage extension. For that, you can run the following:"
+	elog " gconftool-2 --type boolean --set /desktop/gnome/remote_access/disable_xdamage true"
+	elog "This is due http://bugs.freedesktop.org/12255"
+}
diff --git a/net-misc/vino/vino-3.8.1.ebuild b/net-misc/vino/vino-3.8.1.ebuild
deleted file mode 100644
index 559595ee681b..000000000000
--- a/net-misc/vino/vino-3.8.1.ebuild
+++ /dev/null
@@ -1,77 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/vino/vino-3.8.1.ebuild,v 1.1 2013/04/19 18:04:49 pacho Exp $
-
-EAPI="5"
-GCONF_DEBUG="yes"
-
-inherit eutils gnome2
-
-DESCRIPTION="An integrated VNC server for GNOME"
-HOMEPAGE="http://live.gnome.org/Vino"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
-IUSE="avahi crypt gnome-keyring ipv6 jpeg networkmanager ssl +telepathy +zlib"
-
-# cairo used in vino-fb
-# libSM and libICE used in eggsmclient-xsmp
-RDEPEND="
-	>=dev-libs/glib-2.26:2
-	>=x11-libs/gtk+-3.0.0:3
-	>=dev-libs/libgcrypt-1.1.90:=
-	>=net-libs/libsoup-2.24:2.4
-
-	dev-libs/dbus-glib
-	x11-libs/cairo:=
-	x11-libs/pango[X]
-	x11-libs/libICE
-	x11-libs/libX11
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libSM
-	x11-libs/libXtst
-
-	>=x11-libs/libnotify-0.7.0:=
-
-	avahi? ( >=net-dns/avahi-0.6:=[dbus] )
-	crypt? ( >=dev-libs/libgcrypt-1.1.90:= )
-	gnome-keyring? ( app-crypt/libsecret )
-	jpeg? ( virtual/jpeg:0= )
-	networkmanager? ( >=net-misc/networkmanager-0.7 )
-	ssl? ( >=net-libs/gnutls-2.2.0:= )
-	telepathy? ( >=net-libs/telepathy-glib-0.18.0 )
-	zlib? ( sys-libs/zlib:= )
-"
-DEPEND="${RDEPEND}
-	>=dev-lang/perl-5
-	>=dev-util/intltool-0.50
-	virtual/pkgconfig
-	app-crypt/libsecret"
-# libsecret is always required at build time per bug 322763
-
-# bug #394611; tight encoding requires zlib encoding
-REQUIRED_USE="jpeg? ( zlib )"
-
-src_prepare() {
-	# <glib-2.31 compatibility
-	rm -v server/vino-marshal.{c,h} || die
-	gnome2_src_prepare
-}
-
-src_configure() {
-	gnome2_src_configure \
-		--enable-http-server \
-		--with-gcrypt \
-		$(use_with avahi) \
-		$(use_with crypt gcrypt) \
-		$(use_enable ipv6) \
-		$(use_with jpeg) \
-		$(use_with gnome-keyring secret) \
-		$(use_with networkmanager network-manager) \
-		$(use_with ssl gnutls) \
-		$(use_with telepathy) \
-		$(use_with zlib)
-}