Bump to 1.2.10c

(Portage version: 2.1.2.3)

3 files changed, 102 insertions, 1 deletions

diff --git a/net-news/liferea/ChangeLog b/net-news/liferea/ChangeLog
index 7c972b2c5724..5fcc9856399b 100644
--- a/net-news/liferea/ChangeLog
+++ b/net-news/liferea/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-news/liferea
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v 1.93 2007/03/28 03:12:25 dang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v 1.94 2007/04/15 19:56:03 dang Exp $
+
+*liferea-1.2.10c (15 Apr 2007)
+
+  15 Apr 2007; Daniel Gryniewicz <dang@gentoo.org> +liferea-1.2.10c.ebuild:
+  Bump to 1.2.10c
 
 *liferea-1.2.10 (28 Mar 2007)
 
diff --git a/net-news/liferea/files/digest-liferea-1.2.10c b/net-news/liferea/files/digest-liferea-1.2.10c
new file mode 100644
index 000000000000..04bfe2b45b29
--- /dev/null
+++ b/net-news/liferea/files/digest-liferea-1.2.10c
@@ -0,0 +1,3 @@
+MD5 aaa1f8ec09944a269d2f1fedecd27375 liferea-1.2.10c.tar.gz 1402817
+RMD160 b54023166255d28b3b7b0bf85504de31db7519a9 liferea-1.2.10c.tar.gz 1402817
+SHA256 ffb72efdc11ccb13fb784f82c4e0b62f2932a0e3316730df41f9f60db9ffc732 liferea-1.2.10c.tar.gz 1402817
diff --git a/net-news/liferea/liferea-1.2.10c.ebuild b/net-news/liferea/liferea-1.2.10c.ebuild
new file mode 100644
index 000000000000..eb7f5fe35231
--- /dev/null
+++ b/net-news/liferea/liferea-1.2.10c.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/liferea-1.2.10c.ebuild,v 1.1 2007/04/15 19:56:03 dang Exp $
+
+WANT_AUTOMAKE=1.7
+WANT_AUTOCONF=latest
+inherit gnome2 flag-o-matic eutils autotools
+
+DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo/etc feeds"
+HOMEPAGE="http://liferea.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="dbus firefox gtkhtml seamonkey libnotify gnutls xulrunner"
+
+RDEPEND=">=x11-libs/gtk+-2.8
+	x11-libs/pango
+	>=gnome-base/gconf-2
+	>=dev-libs/libxml2-2.6.27
+	>=dev-libs/libxslt-1.1.19
+	>=dev-libs/glib-2
+	xulrunner? ( net-libs/xulrunner )
+	!xulrunner? ( firefox? ( www-client/mozilla-firefox ) )
+	!xulrunner? ( !firefox? ( seamonkey? ( www-client/seamonkey ) ) )
+	!amd64? ( !xulrunner? ( !firefox? ( !seamonkey? ( =gnome-extra/gtkhtml-2* ) ) ) )
+	!amd64? ( gtkhtml? ( =gnome-extra/gtkhtml-2* ) )
+	dbus? ( || ( >=dev-libs/dbus-glib-0.71
+		( <sys-apps/dbus-0.90 >=sys-apps/dbus-0.36 ) )
+	)
+	libnotify? ( >=x11-libs/libnotify-0.3.2 )
+	gnutls? ( net-libs/gnutls )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	>=dev-util/intltool-0.35"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+
+src_unpack() {
+	unpack ${A}
+	# XXX DFG Why can't the directory names be consistent?
+	mv "${PN}-1.2.10" ${S} || die
+
+	cd ${S}
+
+	epatch "${FILESDIR}/${PN}-1.1.0-libnotify.patch"
+
+	eautoreconf || die "Autoreconf failed"
+}
+
+pkg_setup() {
+	# On amd64, gtkhtml isn't supported.  You need one of the gecko use flags
+	if use amd64 && ! use firefox && ! use seamonkey && ! use xulrunner; then
+		elog "gtkhtml is no longer supported on amd64; you will need to select"
+		elog "one of the gecko backends to use liferea"
+		die "You must enable on of the gecko backends on amd64"
+	fi
+
+	# if you don't choose a gecko to use, we will automatically
+	# use gtkhtml2 as the backend except on amd64 (where we failed above)
+	if ! use seamonkey && ! use firefox && ! use xulrunner && ! use amd64 ; then
+		G2CONF="${G2CONF} --enable-gtkhtml2"
+	elif ! use amd64 && use gtkhtml ; then
+		G2CONF="${G2CONF} --enable-gtkhtml2"
+	else
+		G2CONF="${G2CONF} --disable-gtkhtml2"
+	fi
+
+	# we prefer xulrunner over firefox over seamonkey
+	if use xulrunner ; then
+		G2CONF="${G2CONF} --enable-xulrunner"
+	elif use firefox ; then
+		G2CONF="${G2CONF} --enable-gecko=firefox"
+	elif use seamonkey ; then
+		G2CONF="${G2CONF} --enable-gecko=seamonkey"
+	else
+		G2CONF="${G2CONF} --disable-gecko"
+	fi
+
+	G2CONF="${G2CONF} \
+		$(use_enable dbus) \
+		$(use_enable gnutls) \
+		$(use_enable libnotify)"
+}
+
+src_install() {
+	gnome2_src_install
+	rm -f ${D}/usr/bin/${PN}
+	mv ${D}/usr/bin/${PN}-bin ${D}/usr/bin/${PN}
+}