Version bump.

(Portage version: 2.2.0_alpha65/cvs/Linux x86_64)

2 files changed, 117 insertions, 1 deletions

diff --git a/net-proxy/c-icap/ChangeLog b/net-proxy/c-icap/ChangeLog
index bd1302b9c16f..85223837063d 100644
--- a/net-proxy/c-icap/ChangeLog
+++ b/net-proxy/c-icap/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-proxy/c-icap
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/c-icap/ChangeLog,v 1.8 2011/07/24 09:19:09 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/c-icap/ChangeLog,v 1.9 2011/10/11 17:24:43 flameeyes Exp $
+
+*c-icap-0.1.7 (11 Oct 2011)
+
+  11 Oct 2011; Diego E. Pettenò <flameeyes@gentoo.org> +c-icap-0.1.7.ebuild:
+  Version bump.
 
   24 Jul 2011; Markos Chandras <hwoarang@gentoo.org> c-icap-0.1.6.ebuild:
   Stable on amd64 wrt bug #374285
diff --git a/net-proxy/c-icap/c-icap-0.1.7.ebuild b/net-proxy/c-icap/c-icap-0.1.7.ebuild
new file mode 100644
index 000000000000..0bcd347fac48
--- /dev/null
+++ b/net-proxy/c-icap/c-icap-0.1.7.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/c-icap/c-icap-0.1.7.ebuild,v 1.1 2011/10/11 17:24:43 flameeyes Exp $
+
+EAPI=2
+
+inherit eutils multilib flag-o-matic autotools
+
+MY_PN=${PN/-/_}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="C Implementation of an ICAP server"
+HOMEPAGE="http://c-icap.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="berkdb ldap ipv6 ldap"
+
+RDEPEND="berkdb? ( sys-libs/db )
+	ldap? ( net-nds/openldap )
+	sys-libs/zlib"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-0.1.3-asneeded.patch"
+	epatch "${FILESDIR}/${PN}-0.1.3-implicit.patch"
+	epatch "${FILESDIR}/${PN}-0.1.3+db-5.0.patch"
+	epatch "${FILESDIR}/${PN}-0.1.4-crosscompile.patch"
+	epatch "${FILESDIR}/${PN}-0.1.6-implicit.patch"
+	eautoreconf
+}
+
+src_configure() {
+	# some void *** pointers get casted around and can be troublesome to
+	# fix properly.
+	append-flags -fno-strict-aliasing
+
+	econf \
+		--sysconfdir=/etc/${PN} \
+		--disable-dependency-tracking \
+		--disable-maintainer-mode \
+		--disable-static \
+		--enable-large-files \
+		$(use_enable ipv6) \
+		$(use_with berkdb bdb) \
+		$(use_with ldap)
+}
+
+src_compile() {
+	emake LOGDIR="/var/log" || die
+}
+
+src_install() {
+	emake \
+		LOGDIR="/var/log" \
+		DESTDIR="${D}" install || die
+
+	find "${D}" -name '*.la' -delete || die
+
+	# Move the daemon out of the way
+	dodir /usr/libexec
+	mv "${D}"/usr/bin/c-icap "${D}"/usr/libexec || die
+
+	# Remove the default configuration files since we have etc-update to
+	# take care of it for us.
+	rm "${D}"/etc/${PN}/c-icap.*.default || die
+
+	# Fix the configuration file; for some reason it's a bit messy
+	# around.
+	sed -i \
+		-e 's:/usr/var/:/var/:g' \
+		-e 's:/var/log/:/var/log/c-icap/:g' \
+		-e 's:/usr/etc/:/etc/c-icap/:g' \
+		-e 's:/usr/local/c-icap/etc/:/etc/c-icap/:g' \
+		-e 's:/usr/lib/:/usr/'$(get_libdir)'/:g' \
+		"${D}"/etc/${PN}/c-icap.conf \
+		|| die
+
+	dodoc AUTHORS README TODO ChangeLog || die
+
+	newinitd "${FILESDIR}/${PN}.init" ${PN} || die
+	keepdir /var/log/c-icap || die
+
+	insopts -m0644
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotate ${PN}
+}
+
+pkg_postinst() {
+	elog "To enable Squid to call the ICAP modules from a local server you should set"
+	elog "the following in your squid.conf:"
+	elog ""
+	elog "    icap_enable on"
+	elog ""
+	elog "    # not strictly needed, but some modules might make use of these"
+	elog "    icap_send_client_ip on"
+	elog "    icap_send_client_username on"
+	elog ""
+	elog "    icap_service service_req reqmod_precache bypass=1 icap://localhost:1344/service"
+	elog "    adaptation_access service_req allow all"
+	elog ""
+	elog "    icap_service service_resp respmod_precache bypass=0 icap://localhost:1344/service"
+	elog "    adaptation_access service_resp allow all"
+	elog ""
+	elog "You obviously will have to replace \"service\" with the actual ICAP service to"
+	elog "use."
+}