Clean old versions, fix for bug 280857 & bug 280858

(Portage version: 2.2_rc62/cvs/Linux x86_64)

1 files changed, 56 insertions, 0 deletions

diff --git a/sci-chemistry/reduce/reduce-3.13.080428-r1.ebuild b/sci-chemistry/reduce/reduce-3.13.080428-r1.ebuild
new file mode 100644
index 000000000000..a4c7ea549cb7
--- /dev/null
+++ b/sci-chemistry/reduce/reduce-3.13.080428-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/reduce/reduce-3.13.080428-r1.ebuild,v 1.1 2010/02/05 23:41:04 jlec Exp $
+
+EAPI="3"
+
+inherit eutils toolchain-funcs
+
+MY_P="${PN}.${PV}.src"
+
+DESCRIPTION="Adds hydrogens to a Protein Data Bank (PDB) molecule structure file"
+HOMEPAGE="http://kinemage.biochem.duke.edu/software/reduce.php"
+SRC_URI="http://kinemage.biochem.duke.edu/downloads/software/reduce31/${MY_P}.tgz"
+
+LICENSE="richardson"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PV}-LDFLAGS.patch
+}
+
+src_compile() {
+	DICT_DIR="/usr/share/reduce"
+	DICT_FILE="reduce_het_dict.txt"
+
+	emake \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		OPT="${CXXFLAGS}" \
+		DICT_HOME="${EPREFIX}/${DICT_DIR}/${DICT_FILE}" \
+		|| die "make failed"
+}
+
+src_install() {
+	dobin "${S}"/reduce_src/reduce || die
+	insinto ${DICT_DIR}
+	doins "${S}"/${DICT_FILE} "${S}"/reduce_wwPDB_het_dict.txt || die
+	dodoc README.usingReduce.txt || die
+}
+
+pkg_info() {
+	elog "To use the PDBv3 dictionary instead of PDBv2, set the environment"
+	elog "variable REDUCE_HET_DICT to /usr/share/reduce/reduce_wwPDB_het_dict.txt"
+}
+
+pkg_postinst() {
+	pkg_info
+}