Version bump #225455 by teidakankan.

(Portage version: 2.2_pre7-r1/cvs/Linux 2.6.25 AMD Athlon(tm) 64 X2 Dual Core Processor 4200+)

2 files changed, 96 insertions, 1 deletions

diff --git a/sys-apps/iproute2/ChangeLog b/sys-apps/iproute2/ChangeLog
index 45859c1bc4ad..9dd4de38433d 100644
--- a/sys-apps/iproute2/ChangeLog
+++ b/sys-apps/iproute2/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/iproute2
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v 1.104 2008/03/29 17:26:14 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v 1.105 2008/06/09 00:58:21 vapier Exp $
+
+*iproute2-2.6.25.20080417 (09 Jun 2008)
+
+  09 Jun 2008; Mike Frysinger <vapier@gentoo.org>
+  +iproute2-2.6.25.20080417.ebuild:
+  Version bump #225455 by teidakankan.
 
 *iproute2-2.6.24.20080108 (29 Mar 2008)
 
diff --git a/sys-apps/iproute2/iproute2-2.6.25.20080417.ebuild b/sys-apps/iproute2/iproute2-2.6.25.20080417.ebuild
new file mode 100644
index 000000000000..40768b0cccfc
--- /dev/null
+++ b/sys-apps/iproute2/iproute2-2.6.25.20080417.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-2.6.25.20080417.ebuild,v 1.1 2008/06/09 00:58:21 vapier Exp $
+
+inherit eutils toolchain-funcs
+
+MY_PV="${PV%.*}"
+SNAP=${PV##*.}
+SNAP=${SNAP:2}
+MY_P="${PN}-${MY_PV}"
+DESCRIPTION="kernel routing and traffic control utilities"
+HOMEPAGE="http://linux-net.osdl.org/index.php/Iproute2"
+SRC_URI="http://developer.osdl.org/dev/iproute2/download/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="atm berkdb minimal"
+
+RDEPEND="!minimal? ( berkdb? ( sys-libs/db ) )
+	atm? ( net-dialup/linux-atm )"
+DEPEND="${RDEPEND}
+	>=virtual/os-headers-2.4.21"
+
+S=${WORKDIR}/${MY_P}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i "s:-O2:${CFLAGS}:" Makefile || die "sed Makefile failed"
+
+	local check base=${PORTAGE_CONFIGROOT}/etc/portage/patches
+	for check in {${CATEGORY}/${PF},${CATEGORY}/${P},${CATEGORY}/${PN}}; do
+		EPATCH_SOURCE=${base}/${CTARGET}/${check}
+		[[ -r ${EPATCH_SOURCE} ]] || EPATCH_SOURCE=${base}/${CHOST}/${check}
+		[[ -r ${EPATCH_SOURCE} ]] || EPATCH_SOURCE=${base}/${check}
+		if [[ -d ${EPATCH_SOURCE} ]] ; then
+			EPATCH_SUFFIX="patch"
+			EPATCH_FORCE="yes" \
+			EPATCH_MULTI_MSG="Applying user patches from ${EPATCH_SOURCE} ..." \
+			epatch
+			break
+		fi
+	done
+
+	# don't build arpd if USE=-berkdb #81660
+	use berkdb || sed -i '/^TARGETS=/s: arpd : :' misc/Makefile
+	# Multilib fixes
+	sed -i 's:/usr/local:/usr:' tc/m_ipt.c include/iptables.h
+	sed -i "s:/usr/lib:/usr/$(get_libdir):g" \
+		netem/Makefile tc/{Makefile,tc.c,q_netem.c,m_ipt.c} include/iptables.h || die
+	# Use correct iptables dir, #144265.
+	sed -i "s:/usr/local/lib/iptables:/$(get_libdir)/iptables:g" \
+		include/iptables.h
+}
+
+src_compile() {
+	echo -n 'TC_CONFIG_ATM:=' > Config
+	use atm \
+		&& echo 'y' >> Config \
+		|| echo 'n' >> Config
+
+	use minimal && sed -i -e '/^SUBDIRS=/s:=.*:=lib tc:' Makefile
+	emake \
+		CC="$(tc-getCC)" \
+		AR="$(tc-getAR)" \
+		|| die "make"
+}
+
+src_install() {
+	if use minimal ; then
+		into /
+		dosbin tc/tc || die "minimal"
+		return 0
+	fi
+
+	emake \
+		DESTDIR="${D}" \
+		SBINDIR=/sbin \
+		DOCDIR=/usr/share/doc/${PF} \
+		install \
+		|| die "make install failed"
+	if use berkdb ; then
+		dodir /var/lib/arpd
+		# bug 47482, arpd doesn't need to be in /sbin
+		dodir /usr/sbin
+		mv "${D}"/sbin/arpd "${D}"/usr/sbin/
+	fi
+}