Version bump.

(Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

3 files changed, 96 insertions, 7 deletions

diff --git a/sys-apps/kmod/ChangeLog b/sys-apps/kmod/ChangeLog
index 6749214e8fa1..ebcd32759328 100644
--- a/sys-apps/kmod/ChangeLog
+++ b/sys-apps/kmod/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/kmod
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.34 2012/04/06 21:04:02 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.35 2012/04/20 12:14:30 ssuominen Exp $
+
+*kmod-8 (20 Apr 2012)
+
+  20 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> +kmod-8.ebuild,
+  kmod-9999.ebuild:
+  Version bump.
 
   06 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> kmod-7.ebuild,
   kmod-9999.ebuild:
diff --git a/sys-apps/kmod/kmod-8.ebuild b/sys-apps/kmod/kmod-8.ebuild
new file mode 100644
index 000000000000..99d83f011af1
--- /dev/null
+++ b/sys-apps/kmod/kmod-8.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-8.ebuild,v 1.1 2012/04/20 12:14:30 ssuominen Exp $
+
+EAPI=4
+
+EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/kernel/${PN}/${PN}.git"
+
+[[ ${PV} == 9999 ]] && vcs=git-2
+inherit ${vcs} autotools eutils toolchain-funcs
+unset vcs
+
+if [[ ${PV} != 9999 ]] ; then
+	SRC_URI="mirror://kernel/linux/utils/kernel/kmod/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86"
+fi
+
+DESCRIPTION="library and tools for managing linux kernel modules"
+HOMEPAGE="http://git.kernel.org/?p=utils/kernel/kmod/kmod.git"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="debug doc lzma static-libs +tools zlib"
+
+RDEPEND="!sys-apps/module-init-tools
+	!sys-apps/modutils
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	lzma? ( dev-util/pkgconfig )
+	zlib? ( dev-util/pkgconfig )"
+
+# Upstream does not support running the test suite with custom configure flags.
+# I was also told that the test suite is intended for kmod developers.
+# So we have to restrict it.
+# See bug #408915.
+RESTRICT="test"
+
+src_prepare()
+{
+	if [ ! -e configure ]; then
+		if use doc; then
+			gtkdocize --copy --docdir libkmod/docs || die
+		else
+			touch libkmod/docs/gtk-doc.make
+		fi
+		eautoreconf
+	else
+		elibtoolize
+	fi
+}
+
+src_configure()
+{
+	# http://bugs.gentoo.org/410865
+	if has_version '<sys-libs/zlib-1.2.6'; then
+		export zlib_CFLAGS="-I/usr/include"
+		export zlib_LIBS="-lz"
+	fi
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable tools) \
+		$(use_enable debug) \
+		$(use_enable doc gtk-doc) \
+		$(use_with lzma xz) \
+		$(use_with zlib)
+}
+
+src_install()
+{
+	default
+
+	find "${D}" -name libkmod.la -exec rm -f {} +
+
+	if use tools; then
+		dodir /bin
+		dosym /usr/bin/kmod /bin/lsmod
+		dodir /sbin
+		local cmd
+		for cmd in depmod insmod modinfo modprobe rmmod; do
+			dosym /usr/bin/kmod /sbin/${cmd}
+		done
+	fi
+}
diff --git a/sys-apps/kmod/kmod-9999.ebuild b/sys-apps/kmod/kmod-9999.ebuild
index 871fd714b75b..fe680fd89fbc 100644
--- a/sys-apps/kmod/kmod-9999.ebuild
+++ b/sys-apps/kmod/kmod-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9999.ebuild,v 1.24 2012/04/06 21:04:44 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9999.ebuild,v 1.25 2012/04/20 12:14:30 ssuominen Exp $
 
 EAPI=4
 
@@ -59,16 +59,13 @@ src_configure()
 		export zlib_LIBS="-lz"
 	fi
 
-	local myconf
-	[[ ${PV} == 9999 ]] && myconf="$(use_enable doc gtk-doc)"
-
 	econf \
 		$(use_enable static-libs static) \
 		$(use_enable tools) \
 		$(use_enable debug) \
+		$(use_enable doc gtk-doc) \
 		$(use_with lzma xz) \
-		$(use_with zlib) \
-		${myconf}
+		$(use_with zlib)
 }
 
 src_install()