Re-disable USE=tty-helpers by default and add an elog #483798 by Allen Parker.

(Portage version: 2.2.0/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

2 files changed, 131 insertions, 1 deletions

diff --git a/sys-apps/util-linux/ChangeLog b/sys-apps/util-linux/ChangeLog
index 294cd86e1da2..881d1c33d2f8 100644
--- a/sys-apps/util-linux/ChangeLog
+++ b/sys-apps/util-linux/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/util-linux
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.437 2013/09/29 01:20:15 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.438 2013/09/29 01:41:58 vapier Exp $
+
+*util-linux-2.23.2-r2 (29 Sep 2013)
+
+  29 Sep 2013; Mike Frysinger <vapier@gentoo.org> +util-linux-2.23.2-r2.ebuild:
+  Re-disable USE=tty-helpers by default and add an elog #483798 by Allen Parker.
 
   29 Sep 2013; Mike Frysinger <vapier@gentoo.org> metadata.xml,
   util-linux-2.23.2-r1.ebuild:
diff --git a/sys-apps/util-linux/util-linux-2.23.2-r2.ebuild b/sys-apps/util-linux/util-linux-2.23.2-r2.ebuild
new file mode 100644
index 000000000000..a02c399bd50e
--- /dev/null
+++ b/sys-apps/util-linux/util-linux-2.23.2-r2.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-2.23.2-r2.ebuild,v 1.1 2013/09/29 01:41:58 vapier Exp $
+
+EAPI="4"
+inherit eutils toolchain-funcs libtool flag-o-matic bash-completion-r1
+
+MY_PV=${PV/_/-}
+MY_P=${PN}-${MY_PV}
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-2 autotools
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/util-linux/util-linux.git"
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux"
+	SRC_URI="mirror://kernel/linux/utils/util-linux/v${PV:0:4}/${MY_P}.tar.xz"
+fi
+
+DESCRIPTION="Various useful Linux utilities"
+HOMEPAGE="http://www.kernel.org/pub/linux/utils/util-linux/"
+
+LICENSE="GPL-2 GPL-3 LGPL-2.1 BSD-4 MIT public-domain"
+SLOT="0"
+IUSE="bash-completion caps +cramfs cytune fdformat ncurses nls old-linux pam selinux slang static-libs +suid test tty-helpers udev unicode"
+
+RDEPEND="!sys-process/schedutils
+	!sys-apps/setarch
+	!<sys-apps/sysvinit-2.88-r5
+	!sys-block/eject
+	!<sys-libs/e2fsprogs-libs-1.41.8
+	!<sys-fs/e2fsprogs-1.41.8
+	!<app-shells/bash-completion-1.3-r2
+	caps? ( sys-libs/libcap-ng )
+	cramfs? ( sys-libs/zlib )
+	ncurses? ( >=sys-libs/ncurses-5.2-r2 )
+	pam? ( sys-libs/pam )
+	selinux? ( sys-libs/libselinux )
+	slang? ( sys-libs/slang )
+	udev? ( virtual/udev )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( sys-devel/bc )
+	virtual/os-headers"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	if [[ ${PV} == 9999 ]] ; then
+		po/update-potfiles
+		eautoreconf
+	fi
+	elibtoolize
+}
+
+lfs_fallocate_test() {
+	# Make sure we can use fallocate with LFS #300307
+	cat <<-EOF > "${T}"/fallocate.c
+		#define _GNU_SOURCE
+		#include <fcntl.h>
+		main() { return fallocate(0, 0, 0, 0); }
+	EOF
+	append-lfs-flags
+	$(tc-getCC) ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} "${T}"/fallocate.c -o /dev/null >/dev/null 2>&1 \
+		|| export ac_cv_func_fallocate=no
+	rm -f "${T}"/fallocate.c
+}
+
+src_configure() {
+	lfs_fallocate_test
+	export ac_cv_header_security_pam_misc_h=$(usex pam) #485486
+	econf \
+		--enable-fs-paths-extra=/usr/sbin:/bin:/usr/bin \
+		$(use_enable nls) \
+		--enable-agetty \
+		--with-bashcompletiondir="$(get_bashcompdir)" \
+		$(use_enable bash-completion) \
+		$(use_enable caps setpriv) \
+		$(use_enable cramfs) \
+		$(use_enable cytune) \
+		$(use_enable fdformat) \
+		$(use_enable old-linux elvtune) \
+		--with-ncurses=$(usex ncurses $(usex unicode auto yes) no) \
+		--disable-kill \
+		--disable-last \
+		--disable-login \
+		$(use_enable tty-helpers mesg) \
+		--enable-partx \
+		--enable-raw \
+		--enable-rename \
+		--disable-reset \
+		--enable-schedutils \
+		--disable-su \
+		$(use_enable tty-helpers wall) \
+		$(use_enable tty-helpers write) \
+		$(use_enable suid makeinstall-chown) \
+		$(use_enable suid makeinstall-setuid) \
+		$(use_with selinux) \
+		$(use_with slang) \
+		$(use_enable static-libs static) \
+		$(use_with udev) \
+		$(tc-has-tls || echo --disable-tls)
+}
+
+src_install() {
+	default
+	dodoc AUTHORS NEWS README* Documentation/{TODO,*.txt,releases/*}
+
+	# need the libs in /
+	gen_usr_ldscript -a blkid mount uuid
+
+	# e2fsprogs-libs didnt install .la files, and .pc work fine
+	prune_libtool_files
+}
+
+pkg_postinst() {
+	if ! use tty-helpers; then
+		elog "The mesg/wall/write tools have been disabled due to USE=-tty-helpers."
+	fi
+
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog "The agetty util now clears the terminal by default. You"
+		elog "might want to add --noclear to your /etc/inittab lines."
+	fi
+}