Version bump #269378 by Matthias Schwarzott.

(Portage version: 2.2_rc33/cvs/Linux x86_64)

3 files changed, 120 insertions, 20 deletions

diff --git a/sys-apps/util-linux/ChangeLog b/sys-apps/util-linux/ChangeLog
index 0390cdbf2390..5ca87e4330d1 100644
--- a/sys-apps/util-linux/ChangeLog
+++ b/sys-apps/util-linux/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/util-linux
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.270 2009/06/28 16:21:52 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.271 2009/07/16 03:13:25 vapier Exp $
+
+*util-linux-2.16 (16 Jul 2009)
+
+  16 Jul 2009; Mike Frysinger <vapier@gentoo.org> +util-linux-2.16.ebuild,
+  util-linux-9999.ebuild:
+  Version bump #269378 by Matthias Schwarzott.
 
   28 Jun 2009; Mike Frysinger <vapier@gentoo.org> util-linux-2.15.1.ebuild:
   Update loop-aes patch #273883 by Fabio Coatti.
diff --git a/sys-apps/util-linux/util-linux-2.16.ebuild b/sys-apps/util-linux/util-linux-2.16.ebuild
new file mode 100644
index 000000000000..3a92113662d9
--- /dev/null
+++ b/sys-apps/util-linux/util-linux-2.16.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-2.16.ebuild,v 1.1 2009/07/16 03:13:25 vapier Exp $
+
+EAPI="2"
+
+EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/util-linux-ng/util-linux-ng.git"
+inherit eutils toolchain-funcs
+[[ ${PV} == "9999" ]] && inherit git autotools
+
+MY_PV=${PV/_/-}
+MY_P=${PN}-ng-${MY_PV}
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="Various useful Linux utilities"
+HOMEPAGE="http://www.kernel.org/pub/linux/utils/util-linux-ng/"
+if [[ ${PV} == "9999" ]] ; then
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="mirror://kernel/linux/utils/util-linux-ng/v${PV:0:4}/${MY_P}.tar.bz2
+		loop-aes? ( http://loop-aes.sourceforge.net/updates/util-linux-ng-2.15-20090511.diff.bz2 )"
+	#KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="crypt loop-aes nls old-linux selinux slang uclibc unicode"
+
+RDEPEND="!sys-process/schedutils
+	!sys-apps/setarch
+	>=sys-libs/ncurses-5.2-r2
+	!<sys-libs/e2fsprogs-libs-1.41.8
+	!<sys-fs/e2fsprogs-1.41.8
+	selinux? ( sys-libs/libselinux )
+	slang? ( sys-libs/slang )"
+DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2
+	nls? ( sys-devel/gettext )
+	virtual/os-headers"
+
+src_prepare() {
+	if [[ ${PV} == "9999" ]] ; then
+		eautoreconf
+	else
+		use loop-aes && epatch "${WORKDIR}"/util-linux-ng-*.diff
+	fi
+	use uclibc && sed -i -e s/versionsort/alphasort/g -e s/strverscmp.h/dirent.h/g mount/lomount.c
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		--enable-agetty \
+		--enable-cramfs \
+		$(use_enable old-linux elvtune) \
+		--disable-init \
+		--disable-kill \
+		--disable-last \
+		--disable-mesg \
+		--enable-partx \
+		--enable-raw \
+		--enable-rdev \
+		--enable-rename \
+		--disable-reset \
+		--disable-login-utils \
+		--enable-schedutils \
+		--disable-wall \
+		--enable-write \
+		--without-pam \
+		$(use unicode || echo --with-ncurses) \
+		$(use_with selinux) \
+		$(use_with slang)
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "install failed"
+	dodoc AUTHORS NEWS README* TODO docs/*
+
+	# need the libs in /
+	gen_usr_ldscript -a blkid uuid
+	# e2fsprogs-libs didnt install .la files, and .pc work fine
+	rm -f "${D}"/usr/$(get_libdir)/*.la
+
+	if use crypt ; then
+		newinitd "${FILESDIR}"/crypto-loop.initd crypto-loop || die
+		newconfd "${FILESDIR}"/crypto-loop.confd crypto-loop || die
+	fi
+}
diff --git a/sys-apps/util-linux/util-linux-9999.ebuild b/sys-apps/util-linux/util-linux-9999.ebuild
index b9e059b2aa6b..f427c3736e49 100644
--- a/sys-apps/util-linux/util-linux-9999.ebuild
+++ b/sys-apps/util-linux/util-linux-9999.ebuild
@@ -1,10 +1,12 @@
-# Copyright 1999-2008 Gentoo Foundation
+# Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-9999.ebuild,v 1.7 2008/12/30 04:33:59 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-9999.ebuild,v 1.8 2009/07/16 03:13:25 vapier Exp $
+
+EAPI="2"
 
 EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/util-linux-ng/util-linux-ng.git"
-inherit eutils
-[[ ${PV} == "9999" ]] && inherit git
+inherit eutils toolchain-funcs
+[[ ${PV} == "9999" ]] && inherit git autotools
 
 MY_PV=${PV/_/-}
 MY_P=${PN}-ng-${MY_PV}
@@ -14,40 +16,40 @@ DESCRIPTION="Various useful Linux utilities"
 HOMEPAGE="http://www.kernel.org/pub/linux/utils/util-linux-ng/"
 if [[ ${PV} == "9999" ]] ; then
 	SRC_URI=""
+	KEYWORDS=""
 else
 	SRC_URI="mirror://kernel/linux/utils/util-linux-ng/v${PV:0:4}/${MY_P}.tar.bz2
-		loop-aes? ( http://loop-aes.sourceforge.net/loop-AES/loop-AES-v3.2c.tar.bz2 )"
+		loop-aes? ( http://loop-aes.sourceforge.net/updates/util-linux-ng-2.15-20090511.diff.bz2 )"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
 fi
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS=""
-IUSE="crypt loop-aes nls old-linux selinux slang unicode"
+IUSE="crypt loop-aes nls old-linux selinux slang uclibc unicode"
 
 RDEPEND="!sys-process/schedutils
 	!sys-apps/setarch
 	>=sys-libs/ncurses-5.2-r2
-	>=sys-libs/e2fsprogs-libs-1.41
+	!<sys-libs/e2fsprogs-libs-1.41.8
+	!<sys-fs/e2fsprogs-1.41.8
 	selinux? ( sys-libs/libselinux )
 	slang? ( sys-libs/slang )"
 DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2
 	nls? ( sys-devel/gettext )
 	virtual/os-headers"
 
-src_unpack() {
+src_prepare() {
 	if [[ ${PV} == "9999" ]] ; then
-		git_src_unpack
-		cd "${S}"
-		./autogen.sh || die
+		eautoreconf
 	else
-		unpack ${A}
-		use loop-aes && epatch "${WORKDIR}"/loop-AES-*/util-linux-ng-*.diff
+		use loop-aes && epatch "${WORKDIR}"/util-linux-ng-*.diff
 	fi
+	use uclibc && sed -i -e s/versionsort/alphasort/g -e s/strverscmp.h/dirent.h/g mount/lomount.c
 }
 
-src_compile() {
+src_configure() {
 	econf \
-		--with-fsprobe=blkid \
 		$(use_enable nls) \
 		--enable-agetty \
 		--enable-cramfs \
@@ -68,15 +70,18 @@ src_compile() {
 		--without-pam \
 		$(use unicode || echo --with-ncurses) \
 		$(use_with selinux) \
-		$(use_with slang) \
-		|| die "configure failed"
-	emake || die "emake failed"
+		$(use_with slang)
 }
 
 src_install() {
 	emake install DESTDIR="${D}" || die "install failed"
 	dodoc AUTHORS NEWS README* TODO docs/*
 
+	# need the libs in /
+	gen_usr_ldscript -a blkid uuid
+	# e2fsprogs-libs didnt install .la files, and .pc work fine
+	rm -f "${D}"/usr/$(get_libdir)/*.la
+
 	if use crypt ; then
 		newinitd "${FILESDIR}"/crypto-loop.initd crypto-loop || die
 		newconfd "${FILESDIR}"/crypto-loop.confd crypto-loop || die