Version bump.

(Portage version: 2.2_rc40/cvs/Linux x86_64)

2 files changed, 95 insertions, 1 deletions

diff --git a/sys-apps/util-linux/ChangeLog b/sys-apps/util-linux/ChangeLog
index e2f7b093d59c..c7644a6bf0cb 100644
--- a/sys-apps/util-linux/ChangeLog
+++ b/sys-apps/util-linux/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/util-linux
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.275 2009/08/16 18:33:27 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.276 2009/09/07 13:41:14 vapier Exp $
+
+*util-linux-2.16.1 (07 Sep 2009)
+
+  07 Sep 2009; Mike Frysinger <vapier@gentoo.org> +util-linux-2.16.1.ebuild:
+  Version bump.
 
 *util-linux-2.16-r1 (16 Aug 2009)
 
diff --git a/sys-apps/util-linux/util-linux-2.16.1.ebuild b/sys-apps/util-linux/util-linux-2.16.1.ebuild
new file mode 100644
index 000000000000..7649eb14329e
--- /dev/null
+++ b/sys-apps/util-linux/util-linux-2.16.1.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-2.16.1.ebuild,v 1.1 2009/09/07 13:41:14 vapier Exp $
+
+EAPI="2"
+
+EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/util-linux-ng/util-linux-ng.git"
+inherit eutils toolchain-funcs
+[[ ${PV} == "9999" ]] && inherit git autotools
+
+MY_PV=${PV/_/-}
+MY_P=${PN}-ng-${MY_PV}
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="Various useful Linux utilities"
+HOMEPAGE="http://www.kernel.org/pub/linux/utils/util-linux-ng/"
+if [[ ${PV} == "9999" ]] ; then
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="mirror://kernel/linux/utils/util-linux-ng/v${PV:0:4}/${MY_P}.tar.bz2
+		loop-aes? ( http://loop-aes.sourceforge.net/updates/util-linux-ng-2.16-20090725.diff.bz2 )"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="crypt loop-aes nls old-linux selinux slang uclibc unicode"
+
+RDEPEND="!sys-process/schedutils
+	!sys-apps/setarch
+	>=sys-libs/ncurses-5.2-r2
+	!<sys-libs/e2fsprogs-libs-1.41.8
+	!<sys-fs/e2fsprogs-1.41.8
+	selinux? ( sys-libs/libselinux )
+	slang? ( sys-libs/slang )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	virtual/os-headers"
+
+src_prepare() {
+	if [[ ${PV} == "9999" ]] ; then
+		autopoint --force
+		eautoreconf
+	else
+		use loop-aes && epatch "${WORKDIR}"/util-linux-ng-*.diff
+	fi
+	use uclibc && sed -i -e s/versionsort/alphasort/g -e s/strverscmp.h/dirent.h/g mount/lomount.c
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		--enable-agetty \
+		--enable-cramfs \
+		$(use_enable old-linux elvtune) \
+		--disable-init \
+		--disable-kill \
+		--disable-last \
+		--disable-mesg \
+		--enable-partx \
+		--enable-raw \
+		--enable-rdev \
+		--enable-rename \
+		--disable-reset \
+		--disable-login-utils \
+		--enable-schedutils \
+		--disable-wall \
+		--enable-write \
+		--without-pam \
+		$(use unicode || echo --with-ncurses) \
+		$(use_with selinux) \
+		$(use_with slang)
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "install failed"
+	dodoc AUTHORS NEWS README* TODO docs/*
+
+	# need the libs in /
+	gen_usr_ldscript -a blkid uuid
+	# e2fsprogs-libs didnt install .la files, and .pc work fine
+	rm -f "${D}"/usr/$(get_libdir)/*.la
+
+	if use crypt ; then
+		newinitd "${FILESDIR}"/crypto-loop.initd crypto-loop || die
+		newconfd "${FILESDIR}"/crypto-loop.confd crypto-loop || die
+	fi
+}