Update with newer version of polkit-shadow patch

(Portage version: 2.1.8.3/cvs/Linux i686)

2 files changed, 104 insertions, 1 deletions

diff --git a/sys-auth/polkit/ChangeLog b/sys-auth/polkit/ChangeLog
index d18406e48efe..04fa39269487 100644
--- a/sys-auth/polkit/ChangeLog
+++ b/sys-auth/polkit/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-auth/polkit
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/ChangeLog,v 1.10 2010/03/07 00:13:49 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/ChangeLog,v 1.11 2010/03/21 10:17:50 nirbheek Exp $
+
+*polkit-0.96-r1 (21 Mar 2010)
+
+  21 Mar 2010; Nirbheek Chauhan <nirbheek@gentoo.org>
+  +polkit-0.96-r1.ebuild:
+  Update with newer version of polkit-shadow patch
 
   07 Mar 2010; Nirbheek Chauhan <nirbheek@gentoo.org> polkit-0.96.ebuild:
   Fix minor problems with SRC_URI
diff --git a/sys-auth/polkit/polkit-0.96-r1.ebuild b/sys-auth/polkit/polkit-0.96-r1.ebuild
new file mode 100644
index 000000000000..314f35625024
--- /dev/null
+++ b/sys-auth/polkit/polkit-0.96-r1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/polkit-0.96-r1.ebuild,v 1.1 2010/03/21 10:17:50 nirbheek Exp $
+
+EAPI="2"
+
+inherit autotools eutils multilib pam
+
+DESCRIPTION="Policy framework for controlling privileges for system-wide services"
+HOMEPAGE="http://hal.freedesktop.org/docs/PolicyKit"
+SRC_URI="http://hal.freedesktop.org/releases/${P}.tar.gz
+!pam? ( mirror://gentoo/${P}-r1-shadow-support.patch.lzma )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug doc examples expat nls pam"
+# introspection
+
+# not mature enough
+#	introspection? ( dev-libs/gobject-introspection )
+RDEPEND=">=dev-libs/glib-2.21.4
+	>=dev-libs/eggdbus-0.6
+	pam? ( virtual/pam )
+	expat? ( dev-libs/expat )"
+DEPEND="${RDEPEND}
+	!!>=sys-auth/policykit-0.92
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	>=dev-util/pkgconfig-0.18
+	>=dev-util/intltool-0.36
+	dev-util/gtk-doc-am
+	doc? ( >=dev-util/gtk-doc-1.10 )"
+PDEPEND=">=sys-auth/consolekit-0.4[policykit]"
+
+pkg_setup() {
+	enewgroup polkituser
+	enewuser polkituser -1 "-1" /dev/null polkituser
+}
+
+src_prepare() {
+	if ! use pam; then
+		# Experimental shadow support, bug 291116
+		epatch "${WORKDIR}/${P}-r1-shadow-support.patch"
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	local conf
+
+	if use expat; then
+		conf="${conf} --with-expat=/usr"
+	fi
+
+	if use pam; then
+		conf="${conf} --with-authfw=pam
+			--with-pam-module-dir=$(getpam_mod_dir)"
+	else
+		conf="${conf} --with-authfw=shadow"
+	fi
+
+	# We define libexecdir due to fdo bug #22951
+	# easier to maintain than patching everything
+	econf ${conf} \
+		--disable-introspection \
+		--disable-ansi \
+		--disable-examples \
+		--enable-fast-install \
+		--enable-libtool-lock \
+		--enable-man-pages \
+		--disable-dependency-tracking \
+		--with-os-type=gentoo \
+		--localstatedir=/var \
+		--libexecdir='${exec_prefix}/libexec/polkit-1' \
+		$(use_enable debug verbose-mode) \
+		$(use_enable doc gtk-doc) \
+		$(use_enable nls)
+		#$(use_enable introspection)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	dodoc NEWS README AUTHORS ChangeLog || die "dodoc failed"
+
+	# We disable example compilation above, and handle it here
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins src/examples/{*.c,*.policy*}
+	fi
+
+	# Need to keep a few directories around...
+	diropts -m0700 -o root -g polkituser
+	keepdir /var/run/polkit-1
+	keepdir /var/lib/polkit-1
+}