Version bump.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

2 files changed, 91 insertions, 1 deletions

diff --git a/sys-block/fio/ChangeLog b/sys-block/fio/ChangeLog
index beaa52056c1d..e2f6ffe57cd4 100644
--- a/sys-block/fio/ChangeLog
+++ b/sys-block/fio/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-block/fio
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-block/fio/ChangeLog,v 1.60 2015/03/11 06:02:43 prometheanfire Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-block/fio/ChangeLog,v 1.61 2015/07/07 10:09:07 vapier Exp $
+
+*fio-2.2.9 (07 Jul 2015)
+
+  07 Jul 2015; Mike Frysinger <vapier@gentoo.org> +fio-2.2.9.ebuild:
+  Version bump.
 
   11 Mar 2015; Matthew Thode <prometheanfire@gentoo.org> fio-2.2.4-r1.ebuild:
   removing badness arm? 542850 and fixing 542640
diff --git a/sys-block/fio/fio-2.2.9.ebuild b/sys-block/fio/fio-2.2.9.ebuild
new file mode 100644
index 000000000000..18e2e2f8352e
--- /dev/null
+++ b/sys-block/fio/fio-2.2.9.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-block/fio/fio-2.2.9.ebuild,v 1.1 2015/07/07 10:09:07 vapier Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python2_7 )
+inherit eutils python-r1 toolchain-funcs
+
+MY_PV="${PV/_rc/-rc}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="Jens Axboe's Flexible IO tester"
+HOMEPAGE="http://brick.kernel.dk/snaps/"
+SRC_URI="http://brick.kernel.dk/snaps/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="aio glusterfs gnuplot gtk numa rbd rdma zlib"
+
+DEPEND="aio? ( dev-libs/libaio )
+	glusterfs? ( !arm? ( sys-cluster/glusterfs ) )
+	gtk? (
+		dev-libs/glib:2
+		x11-libs/gtk+:2
+	)
+	numa? ( sys-process/numactl )
+	rbd? ( sys-cluster/ceph )
+	zlib? ( sys-libs/zlib )"
+RDEPEND="${DEPEND}
+	gnuplot? (
+		sci-visualization/gnuplot
+		${PYTHON_DEPS}
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	sed -i '/^DEBUGFLAGS/s: -D_FORTIFY_SOURCE=2::g' Makefile || die
+	epatch_user
+
+	# Many checks don't have configure flags.
+	sed -i \
+		-e "s:\<pkg-config\>:$(tc-getPKG_CONFIG):" \
+		-e '/if compile_prog "" "-lz" "zlib" *; *then/  '"s::if $(usex zlib true false) ; then:" \
+		-e '/if compile_prog "" "-laio" "libaio" ; then/'"s::if $(usex aio true false) ; then:" \
+		configure || die
+}
+
+src_configure() {
+	chmod g-w "${T}"
+	# not a real configure script
+	./configure \
+		--extra-cflags="${CFLAGS} ${CPPFLAGS}" \
+		--cc="$(tc-getCC)" \
+		$(usex glusterfs '' '--disable-gfapi') \
+		$(usex gtk '--enable-gfio' '') \
+		$(usex numa '' '--disable-numa') \
+		$(usex rbd '' '--disable-rbd') \
+		|| die 'configure failed'
+}
+
+src_compile() {
+	emake V=1 OPTFLAGS=
+}
+
+src_install() {
+	emake install DESTDIR="${D}" prefix="${EPREFIX}/usr" mandir="${EPREFIX}/usr/share/man"
+
+	if use gnuplot ; then
+		python_replicate_script "${ED}/usr/bin/fio2gnuplot"
+	else
+		rm "${ED}"/usr/bin/{fio2gnuplot,fio_generate_plots} || die
+		rm "${ED}"/usr/share/man/man1/{fio2gnuplot,fio_generate_plots}.1 || die
+		rm "${ED}"/usr/share/fio/*.gpm || die
+		rmdir "${ED}"/usr/share/fio/ 2>/dev/null
+	fi
+
+	# This tool has security/parallel issues -- it hardcodes /tmp/template.fio.
+	rm "${ED}"/usr/bin/genfio || die
+
+	dodoc README REPORTING-BUGS HOWTO
+	docinto examples
+	dodoc examples/*
+}