sys-kernel/dracut: Version bump to 013 and EAPI bump to 4.

(Portage version: 2.1.10.11/cvs/Linux x86_64)

4 files changed, 353 insertions, 1 deletions

diff --git a/sys-kernel/dracut/ChangeLog b/sys-kernel/dracut/ChangeLog
index eff531fbcfc3..706edc5fbe09 100644
--- a/sys-kernel/dracut/ChangeLog
+++ b/sys-kernel/dracut/ChangeLog
@@ -1,6 +1,30 @@
 # ChangeLog for sys-kernel/dracut
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/ChangeLog,v 1.27 2011/07/18 17:49:19 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/ChangeLog,v 1.28 2011/08/21 12:24:31 aidecoe Exp $
+
+*dracut-013 (21 Aug 2011)
+
+  21 Aug 2011; Amadeusz Żołnowski <aidecoe@gentoo.org> +dracut-013.ebuild,
+  +files/dracut-013-livenet-gentoo-ca-bundle-path.patch,
+  +files/dracut-013-multipath-udev-rules.patch:
+  Version bump to 013 and EAPI bump to 4.
+
+  This version provides new modules:
+  - livenet
+  - fs-lib
+
+  sys-fs/udev-164 is OK after all. Some dependencies were removed, because
+  they are optional:
+  - net-misc/ifenslave
+  - net-misc/bridge-utils
+  - virtual/eject
+  dracut will warn if something optional is missing, but will continue build an
+  image without issues.
+
+  New important for bug #378863 option was introduced: --force-add
+
+  Dracut can now mount /usr if it's defined in /etc/fstab on destination
+  rootfs.
 
 *dracut-011 (18 Jul 2011)
 
diff --git a/sys-kernel/dracut/dracut-013.ebuild b/sys-kernel/dracut/dracut-013.ebuild
new file mode 100644
index 000000000000..a199290e704d
--- /dev/null
+++ b/sys-kernel/dracut/dracut-013.ebuild
@@ -0,0 +1,224 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-013.ebuild,v 1.1 2011/08/21 12:24:31 aidecoe Exp $
+
+EAPI=4
+
+inherit eutils
+
+DESCRIPTION="Generic initramfs generation tool"
+HOMEPAGE="http://dracut.wiki.kernel.org"
+SRC_URI="mirror://kernel/linux/utils/boot/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+
+BASIC_MODULES="
+	"
+COMMON_MODULES="
+	dracut_modules_biosdevname
+	dracut_modules_btrfs
+	dracut_modules_caps
+	dracut_modules_crypt-gpg
+	dracut_modules_gensplash
+	dracut_modules_mdraid
+	dracut_modules_multipath
+	dracut_modules_plymouth
+	dracut_modules_syslog
+	dracut_modules_xen
+	"
+NETWORK_MODULES="
+	dracut_modules_iscsi
+	dracut_modules_livenet
+	dracut_modules_nbd
+	dracut_modules_nfs
+	"
+DM_MODULES="
+	dracut_modules_crypt
+	dracut_modules_dmraid
+	dracut_modules_dmsquash-live
+	dracut_modules_livenet
+	dracut_modules_lvm
+	"
+IUSE_DRACUT_MODULES="${COMMON_MODULES} ${DM_MODULES} ${NETWORK_MODULES}"
+IUSE="debug selinux ${IUSE_DRACUT_MODULES}"
+RESTRICT="test"
+
+NETWORK_DEPS=">=net-misc/dhcp-4.2.1-r1 sys-apps/iproute2"
+DM_DEPS="|| ( sys-fs/device-mapper >=sys-fs/lvm2-2.02.33 )"
+
+RDEPEND="
+	>=app-shells/bash-4.0
+	>=app-shells/dash-0.5.4.11
+	>=sys-apps/baselayout-1.12.14-r1
+	>=sys-apps/module-init-tools-3.8
+	>=sys-apps/sysvinit-2.87-r3
+	>=sys-apps/util-linux-2.16
+	>=sys-fs/udev-164
+
+	debug? ( dev-util/strace )
+	selinux? ( sys-libs/libselinux sys-libs/libsepol )
+	dracut_modules_biosdevname? ( sys-apps/biosdevname )
+	dracut_modules_btrfs? ( sys-fs/btrfs-progs )
+	dracut_modules_caps? ( sys-libs/libcap )
+	dracut_modules_crypt? ( sys-fs/cryptsetup ${DM_DEPS} )
+	dracut_modules_crypt-gpg? ( app-crypt/gnupg )
+	dracut_modules_dmraid? ( sys-fs/dmraid sys-fs/multipath-tools ${DM_DEPS} )
+	dracut_modules_dmsquash-live? ( ${DM_DEPS} )
+	dracut_modules_gensplash? ( media-gfx/splashutils )
+	dracut_modules_iscsi? ( >=sys-block/open-iscsi-2.0.871.3 ${NETWORK_DEPS} )
+	dracut_modules_lvm? ( >=sys-fs/lvm2-2.02.33 )
+	dracut_modules_mdraid? ( sys-fs/mdadm )
+	dracut_modules_multipath? ( sys-fs/multipath-tools )
+	dracut_modules_nbd? ( sys-block/nbd ${NETWORK_DEPS} )
+	dracut_modules_nfs? ( net-fs/nfs-utils net-nds/rpcbind ${NETWORK_DEPS} )
+	dracut_modules_plymouth? ( >=sys-boot/plymouth-0.8.3-r1 )
+	dracut_modules_syslog? ( || ( app-admin/syslog-ng app-admin/rsyslog ) )
+	dracut_modules_xen? ( app-emulation/xen )
+	"
+DEPEND="
+	>=dev-libs/libxslt-1.1.26
+	app-text/docbook-xml-dtd:4.5
+	>=app-text/docbook-xsl-stylesheets-1.75.2
+	"
+
+REQUIRED_USE="dracut_modules_livenet? ( dracut_modules_dmsquash-live )"
+
+#
+# Helper functions
+#
+
+# Returns true if any of specified modules is enabled by USE flag and false
+# otherwise.
+# $1 = list of modules (which have corresponding USE flags of the same name)
+any_module() {
+	local m modules=" $@ "
+
+	for m in ${modules}; do
+		! use $m && modules=${modules/ $m / }
+	done
+
+	shopt -s extglob
+	modules=${modules%%+( )}
+	shopt -u extglob
+
+	[[ ${modules} ]]
+}
+
+# Removes module from modules.d.
+# $1 = module name
+# Module name can be specified without number prefix.
+rm_module() {
+	local m
+
+	for m in $@; do
+		if [[ $m =~ ^[0-9][0-9][^\ ]*$ ]]; then
+			rm -rf "${modules_dir}"/$m
+		else
+			rm -rf "${modules_dir}"/[0-9][0-9]$m
+		fi
+	done
+}
+
+# Displays Gentoo Base System major release number
+base_sys_maj_ver() {
+	local line
+
+	read line < /etc/gentoo-release
+	line=${line##* }
+	echo "${line%%.*}"
+}
+
+#
+# ebuild functions
+#
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-multipath-udev-rules.patch"
+	epatch "${FILESDIR}/${P}-livenet-gentoo-ca-bundle-path.patch"
+}
+
+src_compile() {
+	emake WITH_SWITCH_ROOT=0
+}
+
+src_install() {
+	emake WITH_SWITCH_ROOT=0 \
+		prefix=/usr sysconfdir=/etc DESTDIR="${D}" \
+		install
+
+	local gen2conf
+
+	dodir /var/lib/dracut/overlay
+	dodoc HACKING TODO AUTHORS NEWS README*
+
+	case "$(base_sys_maj_ver)" in
+		1) gen2conf=gentoo.conf ;;
+		2) gen2conf=gentoo-openrc.conf ;;
+		*) die "Expected ver. 1 or 2 of Gentoo Base System (/etc/gentoo-release)."
+	esac
+
+	insinto /etc/dracut.conf.d
+	newins dracut.conf.d/${gen2conf}.example ${gen2conf}
+
+	insinto /etc/logrotate.d
+	newins dracut.logrotate dracut
+
+	#
+	# Modules
+	#
+	local module
+	modules_dir="${D}/usr/share/dracut/modules.d"
+
+	echo "${PF}" > "${modules_dir}"/10rpmversion/dracut-version \
+		|| die 'dracut-version failed'
+
+	# Remove modules not enabled by USE flags
+	for module in ${IUSE_DRACUT_MODULES} ; do
+		! use ${module} && rm_module ${module#dracut_modules_}
+	done
+
+	# Those flags are specific, and even are corresponding to modules, they need
+	# to be declared as regular USE flags.
+	use debug || rm_module 95debug
+	use selinux || rm_module 98selinux
+
+	! any_module ${DM_MODULES} && rm_module 90dm
+	! any_module ${NETWORK_MODULES} && rm_module 45ifcfg 40network
+
+	# Remove S/390 modules which are not tested at all
+	rm_module 95dasd 95dasd_mod 95zfcp 95znet
+
+	# Remove modules which won't work for sure
+	rm_module 95fcoe # no tools
+	# fips module depends on masked app-crypt/hmaccalc
+	rm_module 01fips
+
+	# Remove extra modules which go to future dracut-extras
+	rm_module 00bootchart 05busybox 97masterkey 98ecryptfs 98integrity
+}
+
+pkg_postinst() {
+	elog 'To generate the initramfs:'
+	elog '    # mount /boot (if necessary)'
+	elog '    # dracut "" <kernel-version>'
+	elog ''
+	elog 'For command line documentation see dracut.kernel(7).'
+	elog ''
+	elog 'Simple example to select root and resume partition:'
+	elog '    root=/dev/sda1 resume=/dev/sda2'
+	elog ''
+	elog 'The default config (in /etc/dracut.conf) is very minimal and is highly'
+	elog 'recommended you adjust based on your needs. To include only dracut'
+	elog 'modules and kernel drivers for this system, use the "-H" option.'
+	elog 'Some modules need to be explicitly added with "-a" option even if'
+	elog 'required tools are installed.'
+	echo
+	elog 'Options (documented in dracut.kernel(7)) have new format since'
+	elog 'version 008. Old format is preserved, but will be removed in future.'
+	elog 'Please migrate to the new one.'
+	echo
+	elog 'Some dependencies were removed, because they are optional. dracut'
+	elog "will inform you with a warning when you're lacking something optional."
+}
diff --git a/sys-kernel/dracut/files/dracut-013-livenet-gentoo-ca-bundle-path.patch b/sys-kernel/dracut/files/dracut-013-livenet-gentoo-ca-bundle-path.patch
new file mode 100644
index 000000000000..ff84df1ec42f
--- /dev/null
+++ b/sys-kernel/dracut/files/dracut-013-livenet-gentoo-ca-bundle-path.patch
@@ -0,0 +1,80 @@
+From 09b08578edf50aaa2bbf8a95c4dc74af5663318a Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Amadeusz=20=C5=BBo=C5=82nowski?= <aidecoe@aidecoe.name>
+Date: Sun, 21 Aug 2011 12:44:31 +0200
+Subject: [PATCH 1/2] dracut-functions: new function: inst_any [-d dest] f1
+ [f2 [f3 ...]]
+
+---
+ dracut-functions |   28 ++++++++++++++++++++++++++++
+ 1 files changed, 28 insertions(+), 0 deletions(-)
+
+diff --git a/dracut-functions b/dracut-functions
+index d7f2e5f..43a6843 100755
+--- a/dracut-functions
++++ b/dracut-functions
+@@ -537,6 +537,34 @@ inst_hook() {
+     inst_simple "$3" "/lib/dracut/hooks/${1}/${2}${3##*/}"
+ }
+ 
++# install any of listed files
++#
++# If first argument is '-d' and second some destination path, first accessible
++# source is installed into this path, otherwise it will installed in the same
++# path as source.  If none of listed files was installed, function return 1.
++# On first successful installation it returns with 0 status.
++#
++# Example:
++#
++# inst_any -d /bin/foo /bin/bar /bin/baz
++#
++# Lets assume that /bin/baz exists, so it will be installed as /bin/foo in
++# initramfs.
++inst_any() {
++    local to f
++
++    [[ $1 = '-d' ]] && to="$2" && shift 2
++
++    for f in "$@"; do
++        if [[ -e $f ]]; then
++            [[ $to ]] && inst "$f" "$to" && return 0
++            inst "$f" && return 0
++        fi
++    done
++
++    return 1
++}
++
+ dracut_install() {
+     local _optional=no
+     if [[ $1 = '-o' ]]; then
+-- 
+1.7.6
+
+From 40bdddfdcf02f0c48ae73ead237589d65a39bb6a Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Amadeusz=20=C5=BBo=C5=82nowski?= <aidecoe@aidecoe.name>
+Date: Sun, 21 Aug 2011 12:45:45 +0200
+Subject: [PATCH 2/2] livenet: take into account other ca-bundle paths; use
+ inst_any for that
+
+---
+ modules.d/90livenet/module-setup.sh |    4 +++-
+ 1 files changed, 3 insertions(+), 1 deletions(-)
+
+diff --git a/modules.d/90livenet/module-setup.sh b/modules.d/90livenet/module-setup.sh
+index 3ae72de..b166859 100755
+--- a/modules.d/90livenet/module-setup.sh
++++ b/modules.d/90livenet/module-setup.sh
+@@ -15,7 +15,9 @@ depends() {
+ install() {
+     dracut_install wget
+     mkdir -m 0755 -p "$initdir/etc/ssl/certs"
+-    if ! inst_simple /etc/ssl/certs/ca-bundle.crt; then
++    if ! inst_any -t /etc/ssl/certs/ca-bundle.crt \
++            /etc/ssl/certs/ca-bundle.crt \
++            /etc/ssl/certs/ca-certificates.crt; then
+         dwarn "Couldn't find SSL CA cert bundle; HTTPS won't work."
+     fi
+ 
+-- 
+1.7.6
+
diff --git a/sys-kernel/dracut/files/dracut-013-multipath-udev-rules.patch b/sys-kernel/dracut/files/dracut-013-multipath-udev-rules.patch
new file mode 100644
index 000000000000..2b9cffad38c4
--- /dev/null
+++ b/sys-kernel/dracut/files/dracut-013-multipath-udev-rules.patch
@@ -0,0 +1,24 @@
+From 7f3e0c13f1c10e93c3823b6367f9ac83865f3d90 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Amadeusz=20=C5=BBo=C5=82nowski?= <aidecoe@aidecoe.name>
+Date: Fri, 25 Feb 2011 01:44:25 +0100
+Subject: [PATCH] 90multipath: added kpartx.rules; multipath.rules - different prefix
+
+---
+ modules.d/90multipath/module-setup.sh |    2 +-
+ 1 files changed, 1 insertions(+), 1 deletions(-)
+
+diff --git a/modules.d/90multipath/module-setup.sh b/modules.d/90multipath/module-setup.sh
+index f78517c..3f4f612 100755
+--- a/modules.d/90multipath/module-setup.sh
++++ b/modules.d/90multipath/module-setup.sh
+@@ -58,6 +58,6 @@ install() {
+ 
+     inst_hook pre-trigger 02 "$moddir/multipathd.sh"
+     inst_hook pre-pivot   02 "$moddir/multipathd-stop.sh"
+-    inst_rules 40-multipath.rules
++    inst_rules 40-multipath.rules 65-multipath.rules 66-kpartx.rules
+ }
+ 
+-- 
+1.7.4.1
+