add multilib support wrt #496586, patch by Michael Mair-Keimberger

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

2 files changed, 81 insertions, 2 deletions

diff --git a/sys-libs/slang/ChangeLog b/sys-libs/slang/ChangeLog
index 208b07fc8524..920dc9b57eaa 100644
--- a/sys-libs/slang/ChangeLog
+++ b/sys-libs/slang/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-libs/slang
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/ChangeLog,v 1.134 2013/11/19 12:41:59 slyfox Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/ChangeLog,v 1.135 2014/04/18 13:21:45 hasufell Exp $
+
+*slang-2.2.4-r1 (18 Apr 2014)
+
+  18 Apr 2014; Julian Ospald <hasufell@gentoo.org> +slang-2.2.4-r1.ebuild:
+  add multilib support wrt #496586, patch by Michael Mair-Keimberger
 
   19 Nov 2013; Sergei Trofimovich <slyfox@gentoo.org>
   +files/slang-2.2.4-memset.patch, slang-2.2.4.ebuild:
diff --git a/sys-libs/slang/slang-2.2.4-r1.ebuild b/sys-libs/slang/slang-2.2.4-r1.ebuild
new file mode 100644
index 000000000000..74ab6bad8ce3
--- /dev/null
+++ b/sys-libs/slang/slang-2.2.4-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/slang-2.2.4-r1.ebuild,v 1.1 2014/04/18 13:21:45 hasufell Exp $
+
+EAPI=5
+inherit eutils multilib-minimal
+
+DESCRIPTION="A multi-platform programmer's library designed to allow a developer to create robust software"
+HOMEPAGE="http://www.jedsoft.org/slang/"
+SRC_URI="mirror://slang/v${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x86-solaris"
+IUSE="cjk pcre png readline static-libs zlib"
+
+# ncurses for ncurses5-config to get terminfo directory
+RDEPEND="sys-libs/ncurses
+	pcre? ( dev-libs/libpcre[${MULTILIB_USEDEP}] )
+	png? ( >=media-libs/libpng-1.2:0[${MULTILIB_USEDEP}] )
+	cjk? ( dev-libs/oniguruma[${MULTILIB_USEDEP}] )
+	readline? ( sys-libs/readline:0[${MULTILIB_USEDEP}] )
+	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
+	abi_x86_32? (
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+		!<=app-emulation/emul-linux-x86-baselibs-20131008-r19
+	)"
+DEPEND="${RDEPEND}"
+
+MAKEOPTS="${MAKEOPTS} -j1"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.2.3-slsh-libs.patch
+	epatch "${FILESDIR}"/${PN}-2.2.4-memset.patch
+
+	# avoid linking to -ltermcap race with some systems
+	sed -i -e '/^TERMCAP=/s:=.*:=:' configure || die
+	# we use the GNU linker also on Solaris
+	sed -i -e 's/-G -fPIC/-shared -fPIC/g' \
+		-e 's/-Wl,-h,/-Wl,-soname,/g' configure || die
+
+	# slang does not support configuration from another dir
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local myconf=slang
+	use readline && myconf=gnu
+
+	econf \
+		--with-readline=${myconf} \
+		$(use_with pcre) \
+		$(use_with cjk onig) \
+		$(use_with png) \
+		$(use_with zlib z)
+}
+
+multilib_src_compile() {
+	emake elf $(use static-libs && echo static)
+
+	pushd slsh >/dev/null
+	emake slsh
+	popd
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install $(use static-libs && echo install-static)
+}
+
+multilib_src_install_all() {
+	rm -rf "${ED}"/usr/share/doc/{slang,slsh}
+	dodoc NEWS README *.txt doc/{,internal,text}/*.txt
+	dohtml doc/slangdoc.html slsh/doc/html/*.html
+}