Version bump for slang, slotted to be installed side-by-side with slang 1.x. Thanks to Mark Lee and Alastair Tse in bug #95247 for the work and the brainstorm. Masked till bug #141947 is completed.

(Portage version: 2.1.1_pre3-r5)

3 files changed, 75 insertions, 1 deletions

diff --git a/sys-libs/slang/ChangeLog b/sys-libs/slang/ChangeLog
index 5f905c10b9a2..637553f41998 100644
--- a/sys-libs/slang/ChangeLog
+++ b/sys-libs/slang/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for sys-libs/slang
 # Copyright 2002-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/ChangeLog,v 1.52 2006/07/22 15:47:49 kloeri Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/ChangeLog,v 1.53 2006/07/28 00:05:33 flameeyes Exp $
+
+*slang-2.0.6 (28 Jul 2006)
+
+  28 Jul 2006; Diego Pettenò <flameeyes@gentoo.org> +slang-2.0.6.ebuild:
+  Version bump for slang, slotted to be installed side-by-side with slang 1.x.
+  Thanks to Mark Lee and Alastair Tse in bug #95247 for the work and the
+  brainstorm. Masked till bug #141947 is completed.
 
   22 Jul 2006; Bryan Østergaard <kloeri@gentoo.org> slang-1.4.9-r2.ebuild:
   Stable on alpha.
diff --git a/sys-libs/slang/files/digest-slang-2.0.6 b/sys-libs/slang/files/digest-slang-2.0.6
new file mode 100644
index 000000000000..bdebd18e98fa
--- /dev/null
+++ b/sys-libs/slang/files/digest-slang-2.0.6
@@ -0,0 +1,3 @@
+MD5 fb8ab2dfc3d8f44b9161b9b0e0c94141 slang-2.0.6.tar.gz 1325084
+RMD160 caf879e440f28297b00cea8bf504af813998424a slang-2.0.6.tar.gz 1325084
+SHA256 5e73fddd052c1a62a20002dafbe7215cf9e449d8a50e81065972f0317caa286c slang-2.0.6.tar.gz 1325084
diff --git a/sys-libs/slang/slang-2.0.6.ebuild b/sys-libs/slang/slang-2.0.6.ebuild
new file mode 100644
index 000000000000..bb7eb548f5ea
--- /dev/null
+++ b/sys-libs/slang/slang-2.0.6.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/slang-2.0.6.ebuild,v 1.1 2006/07/28 00:05:33 flameeyes Exp $
+
+inherit eutils
+
+DESCRIPTION="Console display library used by most text viewer"
+HOMEPAGE="http://www.s-lang.org/"
+SRC_URI="ftp://space.mit.edu/pub/davis/slang/v${PV%.*}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~amd64"
+# USE=cjk is broken; see http://www.jedsoft.org/pipermail/slang-users_jedsoft.org/2006/000399.html
+IUSE="pcre png"
+
+DEPEND=">=sys-libs/ncurses-5.2-r2
+	pcre? ( dev-libs/libpcre )
+	png? ( media-libs/libpng )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i \
+		-e '/^SLANG_INST_INC/s/-I@includedir@/-I@SRCDIR@ -I@includedir@/' \
+		-e '/^SLANG_INST_LIB/s/-L@libdir@/-L@OBJDIR@ -L@ELFDIR@ -L@libdir@/' \
+		slsh/Makefile.in || die
+
+	epatch "${FILESDIR}"/${PN}-2.0.6-slsh-libs.patch
+
+	grep -rlZ -- '-lslang\>' "${S}" | xargs -0 sed -i -e 's:-lslang:-lslang-2:g'
+}
+
+src_compile() {
+	econf \
+		$(use_with pcre) \
+		$(use_with png) || die "econf failed"
+	emake THIS_LIB="slang-2" all || die "make all failed"
+	emake THIS_LIB="slang-2" elf || die "make elf failed"
+	cd slsh
+	emake THIS_LIB="slang-2" slsh || die "make slsh failed"
+}
+
+src_install() {
+	emake THIS_LIB="slang-2" DESTDIR="${D}" install install-elf || die "make install failed"
+
+	# Move headers around
+	dodir /usr/include/slang-2
+	mv "${D}"/usr/include/*.h "${D}/usr/include/slang-2"
+
+	rm -rf "${D}/usr/share/doc/slang"
+	dodoc NEWS README *.txt
+	dodoc doc/*.txt doc/internal/*.txt doc/text/*.txt
+	dohtml doc/slangdoc.html
+}
+
+pkg_postinst() {
+	elog "For compatibility reason slang 2.x is installed in Gentoo as libslang-2."
+	elog "This has the unfortunate consequence that if you want to build something"
+	elog "from sources that uses slang 2.x, you need to change the linking library"
+	elog "to -lslang-2 instead of simply -lslang."
+	elog "We're sorry for the inconvenience, but it's to overcome an otherwise"
+	elog "problematic situation."
+}