Upstream patch for fuser to work with unix sockets wrt #398811. Thanks to Piotr Karbowski and Mike Frysinger.

(Portage version: 2.2.0_alpha122/cvs/Linux x86_64)

2 files changed, 63 insertions, 1 deletions

diff --git a/sys-process/psmisc/ChangeLog b/sys-process/psmisc/ChangeLog
index c957aa14ba6e..59f622da636e 100644
--- a/sys-process/psmisc/ChangeLog
+++ b/sys-process/psmisc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-process/psmisc
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-process/psmisc/ChangeLog,v 1.136 2012/08/25 22:33:18 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-process/psmisc/ChangeLog,v 1.137 2012/08/31 07:35:39 ssuominen Exp $
+
+*psmisc-22.19-r1 (31 Aug 2012)
+
+  31 Aug 2012; Samuli Suominen <ssuominen@gentoo.org> +psmisc-22.19-r1.ebuild:
+  Upstream patch for fuser to work with unix sockets wrt #398811. Thanks to
+  Piotr Karbowski and Mike Frysinger.
 
   25 Aug 2012; Mike Frysinger <vapier@gentoo.org> psmisc-22.16.ebuild,
   psmisc-22.18.ebuild, psmisc-22.19.ebuild:
diff --git a/sys-process/psmisc/psmisc-22.19-r1.ebuild b/sys-process/psmisc/psmisc-22.19-r1.ebuild
new file mode 100644
index 000000000000..c6347efd2563
--- /dev/null
+++ b/sys-process/psmisc/psmisc-22.19-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-process/psmisc/psmisc-22.19-r1.ebuild,v 1.1 2012/08/31 07:35:39 ssuominen Exp $
+
+EAPI=4
+inherit eutils
+
+DESCRIPTION="A set of tools that use the proc filesystem"
+HOMEPAGE="http://psmisc.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+	http://dev.gentoo.org/~ssuominen/${P}-fuser-unix-sockets.patch.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux"
+IUSE="ipv6 nls selinux X"
+
+RDEPEND=">=sys-libs/ncurses-5.7-r7
+	nls? ( virtual/libintl )
+	selinux? ( sys-libs/libselinux )"
+DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2.2.6b
+	nls? ( sys-devel/gettext )"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+src_prepare() {
+	epatch "${WORKDIR}"/${P}-fuser-unix-sockets.patch
+}
+
+src_configure() {
+	econf \
+		$(use_enable selinux) \
+		--disable-harden-flags \
+		$(use_enable ipv6) \
+		$(use_enable nls)
+}
+
+src_compile() {
+	# peekfd is a fragile crap hack #330631
+	nonfatal emake -C src peekfd || touch src/peekfd{.o,}
+	emake
+}
+
+src_install() {
+	default
+
+	use X || rm -f "${ED}"/usr/bin/pstree.x11
+
+	[[ -s ${ED}/usr/bin/peekfd ]] || rm -f "${ED}"/usr/bin/peekfd
+	[[ -e ${ED}/usr/bin/peekfd ]] || rm -f "${ED}"/usr/share/man/man1/peekfd.1
+
+	# fuser is needed by init.d scripts
+	dodir /bin
+	mv "${ED}"/usr/bin/fuser "${ED}"/bin || die
+}