[www-client/arora] resurrected 0.10.1 - most recent version that supports Qt 4.5

(Portage version: 2.2_rc62/cvs/Linux x86_64)

2 files changed, 84 insertions, 1 deletions

diff --git a/www-client/arora/ChangeLog b/www-client/arora/ChangeLog
index 30a99ed909cc..177cc259f05e 100644
--- a/www-client/arora/ChangeLog
+++ b/www-client/arora/ChangeLog
@@ -1,6 +1,10 @@
 # ChangeLog for www-client/arora
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/arora/ChangeLog,v 1.32 2010/02/09 20:12:46 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/arora/ChangeLog,v 1.33 2010/02/17 11:18:41 wired Exp $
+
+  17 Feb 2010; Alex Alexander <wired@gentoo.org> +arora-0.10.1-r1.ebuild:
+  resurrected 0.10.1 - the last version that supports Qt 4.5 which we still
+  support
 
   09 Feb 2010; Ben de Groot <yngwin@gentoo.org> -arora-0.10.1-r1.ebuild:
   Remove old version
diff --git a/www-client/arora/arora-0.10.1-r1.ebuild b/www-client/arora/arora-0.10.1-r1.ebuild
new file mode 100644
index 000000000000..ca6679cb262d
--- /dev/null
+++ b/www-client/arora/arora-0.10.1-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/arora/arora-0.10.1-r1.ebuild,v 1.4 2010/02/17 11:18:41 wired Exp $
+
+EAPI=2
+inherit eutils qt4
+
+DESCRIPTION="A cross-platform Qt4 WebKit browser"
+HOMEPAGE="http://arora.googlecode.com/"
+SRC_URI="http://arora.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="|| ( GPL-3 GPL-2 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug doc"
+
+RDEPEND="=x11-libs/qt-gui-4.5*
+	=x11-libs/qt-sql-4.5*
+	=x11-libs/qt-webkit-4.5*
+	=x11-libs/qt-xmlpatterns-4.5*" # incompatible with Qt 4.6, bug 295808
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+ARORA_LANGS="ast ca es es_CR et_EE fr_CA gl ms nb_NO pt_BR pt_PT sr@latin sr_CS uk
+zh_CN zh_TW"
+ARORA_NOLONGLANGS="cs_CZ da_DK de_DE el_GR fi_FI fr_FR he_IL hu_HU it_IT ja_JP
+nl_NL pl_PL ru_RU sk_SK tr_TR"
+
+for L in $ARORA_LANGS; do
+	IUSE="$IUSE linguas_$L"
+done
+for L in $ARORA_NOLONGLANGS; do
+	IUSE="$IUSE linguas_${L%_*}"
+done
+
+src_prepare() {
+	# use Gentoo lingua designations
+	mv src/locale/sr_RS@latin.ts src/locale/sr@latin.ts
+	mv src/locale/sr_RS.ts src/locale/sr_CS.ts
+
+	# process linguas
+	local langs=
+	for lingua in $LINGUAS; do
+		if has $lingua $ARORA_LANGS; then
+			langs="$langs ${lingua}.ts"
+		else
+			for a in $ARORA_NOLONGLANGS; do
+				if [[ $lingua == ${a%_*} ]]; then
+					langs="$langs ${a}.ts"
+				fi
+			done
+		fi
+	done
+
+	# remove all translations, then add only the ones we want
+	sed -i '/ts/d' src/locale/locale.pri || die 'sed failed'
+	sed -i "/^TRANSLATIONS/s:\\\:${langs}:" src/locale/locale.pri \
+		|| die 'sed failed'
+
+	if ! use doc ; then
+		sed -i 's|QMAKE_EXTRA|#QMAKE_EXTRA|' arora.pro || die 'sed failed'
+	fi
+}
+
+src_configure() {
+	eqmake4 arora.pro PREFIX=/usr
+}
+
+src_compile() {
+	emake || die "make failed"
+
+	# don't pre-strip
+	sed -i "/strip/d" src/Makefile || die 'sed failed'
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install || die 'make install failed'
+	dodoc AUTHORS ChangeLog README
+}