version bump, live ebuild update, fixed bug #376203

(Portage version: 2.2.0_alpha46/cvs/Linux x86_64)

4 files changed, 138 insertions, 30 deletions

diff --git a/www-client/uget/ChangeLog b/www-client/uget/ChangeLog
index c40cb1d75b9d..4343476abfdb 100644
--- a/www-client/uget/ChangeLog
+++ b/www-client/uget/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/uget
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/uget/ChangeLog,v 1.26 2011/05/19 21:01:54 wired Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/uget/ChangeLog,v 1.27 2011/07/25 09:46:22 wired Exp $
+
+*uget-1.8.0 (25 Jul 2011)
+
+  25 Jul 2011; Alex Alexander <wired@gentoo.org> +uget-1.8.0.ebuild,
+  uget-9999.ebuild, metadata.xml:
+  version bump, live ebuild update, fixed bug #376203
 
 *uget-1.7.6 (19 May 2011)
 
diff --git a/www-client/uget/metadata.xml b/www-client/uget/metadata.xml
index 71272a32ebfd..98121dea5694 100644
--- a/www-client/uget/metadata.xml
+++ b/www-client/uget/metadata.xml
@@ -1,20 +1,21 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>no-herd</herd>
-<maintainer>
-<email>wired@gentoo.org</email>
-<name>Alex Alexander</name>
-</maintainer>
-<longdescription lang="en">
-Uget is a download manager. It allows you to classify URLs before downloading
-them, and allows you to import URLs from HTML files. Every category has an
-independent configuration that can be inherited by each download in that
-category.
-</longdescription>
-<use>
-	<flag name='aria2'>Enable support for <pkg>net-misc/aria2</pkg> through xmlrpc.
-		You'll find the plugin in the app's settings.</flag>
-	<flag name='hide-temp-files'>Make temporary files that are used while downloading hidden.</flag>
-</use>
+	<herd>no-herd</herd>
+	<maintainer>
+		<email>wired@gentoo.org</email>
+		<name>Alex Alexander</name>
+	</maintainer>
+	<longdescription lang="en">
+		Uget is a download manager. It allows you to classify URLs before downloading
+		them, and allows you to import URLs from HTML files. Every category has an
+		independent configuration that can be inherited by each download in that
+		category.
+	</longdescription>
+	<use>
+		<flag name='aria2'>Enable support for <pkg>net-misc/aria2</pkg> through xmlrpc.
+			You'll find the plugin in the app's settings.</flag>
+		<flag name='hide-temp-files'>Make temporary files that are used while downloading hidden.</flag>
+		<flag name='gtk3'>Use x11-libs/gtk+:3 instead of x11-libs/gtk+:2</flag>
+	</use>
 </pkgmetadata>
diff --git a/www-client/uget/uget-1.8.0.ebuild b/www-client/uget/uget-1.8.0.ebuild
new file mode 100644
index 000000000000..e79e887e4898
--- /dev/null
+++ b/www-client/uget/uget-1.8.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/uget/uget-1.8.0.ebuild,v 1.1 2011/07/25 09:46:22 wired Exp $
+
+EAPI="4"
+
+inherit base
+
+DESCRIPTION="Download manager using gtk+ and libcurl"
+HOMEPAGE="http://urlget.sourceforge.net/"
+SRC_URI="mirror://sourceforge/urlget/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="aria2 +curl gstreamer gtk3 hide-temp-files libnotify nls"
+
+REQUIRED_USE="|| ( aria2 curl )"
+
+RDEPEND="
+	dev-libs/libpcre
+	>=dev-libs/glib-2:2
+	!gtk3? (
+		>=x11-libs/gtk+-2.18:2
+	)
+	gtk3? (
+		x11-libs/gtk+:3
+	)
+	curl? ( >=net-misc/curl-7.10 )
+	gstreamer? ( media-libs/gstreamer )
+	libnotify? ( x11-libs/libnotify )
+	"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	sys-devel/gettext"
+
+src_prepare() {
+	# add missing file, fix tests, bug #376203
+	echo "uglib/UgPlugin-aria2.c" >> po/POTFILES.in ||
+		die "echo in po/POTFILES.in failed"
+}
+
+src_configure() {
+	econf $(use_enable nls) \
+		  $(use_with gtk3) \
+		  $(use_enable curl plugin-curl) \
+		  $(use_enable aria2 plugin-aria2) \
+		  $(use_enable gstreamer) \
+		  $(use_enable hide-temp-files hidden) \
+		  $(use_enable libnotify notify)
+}
+
+src_compile() {
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	# the build system forgets this :p
+	dobin uget-cmd/uget-cmd
+
+	dodoc AUTHORS ChangeLog NEWS README
+}
+
+pkg_postinst() {
+	if use aria2; then
+		echo
+		elog "You've enabled the aria2 USE flag, so the aria2 plug-in has been"
+		elog "built. This allows you to control a local or remote instance of aria2"
+		elog "through xmlrpc. To use aria2 locally you have to emerge"
+		elog "net-misc/aria2 with the xmlrpc USE enabled manually."
+		echo
+	fi
+}
diff --git a/www-client/uget/uget-9999.ebuild b/www-client/uget/uget-9999.ebuild
index f912037ee5bf..99f308244ba0 100644
--- a/www-client/uget/uget-9999.ebuild
+++ b/www-client/uget/uget-9999.ebuild
@@ -1,28 +1,34 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/uget/uget-9999.ebuild,v 1.4 2011/05/19 20:53:08 wired Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/uget/uget-9999.ebuild,v 1.5 2011/07/25 09:46:22 wired Exp $
 
-EAPI="2"
+EAPI="4"
 
-inherit autotools subversion
+inherit autotools git-2
 
 DESCRIPTION="Download manager using gtk+ and libcurl"
 HOMEPAGE="http://urlget.sourceforge.net/"
 SRC_URI=""
 
-ESVN_REPO_URI="https://urlget.svn.sourceforge.net/svnroot/urlget/trunk"
-ESVN_PROJECT="uget"
+EGIT_REPO_URI="git://urlget.git.sourceforge.net/gitroot/urlget/uget"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
 KEYWORDS=""
-IUSE="gstreamer libnotify nls"
+IUSE="aria2 +curl gstreamer gtk3 hide-temp-files libnotify nls"
+
+REQUIRED_USE="|| ( aria2 curl )"
 
 RDEPEND="
 	dev-libs/libpcre
 	>=dev-libs/glib-2:2
-	>=net-misc/curl-7.10
-	>=x11-libs/gtk+-2.4:2
+	!gtk3? (
+		>=x11-libs/gtk+-2.18:2
+	)
+	gtk3? (
+		x11-libs/gtk+:3
+	)
+	curl? ( >=net-misc/curl-7.10 )
 	gstreamer? ( media-libs/gstreamer )
 	libnotify? ( x11-libs/libnotify )
 	"
@@ -32,9 +38,9 @@ DEPEND="${RDEPEND}
 	sys-devel/gettext"
 
 src_prepare() {
-	for i in AUTHORS NEWS README ChangeLog;	do
-		[[ ! -f ${i} ]] && touch ${i}
-	done
+	# add missing file, fix tests, bug #376203
+	echo "uglib/UgPlugin-aria2.c" >> po/POTFILES.in ||
+		die "echo in po/POTFILES.in failed"
 
 	eautoreconf
 	intltoolize || die "intltoolize failed"
@@ -43,7 +49,11 @@ src_prepare() {
 
 src_configure() {
 	econf $(use_enable nls) \
+		  $(use_with gtk3) \
+		  $(use_enable curl plugin-curl) \
+		  $(use_enable aria2 plugin-aria2) \
 		  $(use_enable gstreamer) \
+		  $(use_enable hide-temp-files hidden) \
 		  $(use_enable libnotify notify) || die "econf failed"
 }
 
@@ -52,6 +62,21 @@ src_compile() {
 }
 
 src_install() {
-	make DESTDIR="${D}" install || die "make install failed"
-	dodoc AUTHORS ChangeLog NEWS README || die "dodoc failed"
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	# the build system forgets this :p
+	dobin uget-cmd/uget-cmd || die "uget-cmd install failed"
+
+	dodoc AUTHORS ChangeLog README || die "dodoc failed"
+}
+
+pkg_postinst() {
+	if use aria2; then
+		echo
+		elog "You've enabled the aria2 USE flag, so the aria2 plug-in has been"
+		elog "built. This allows you to control a local or remote instance of aria2"
+		elog "through xmlrpc. To use aria2 locally you have to emerge"
+		elog "net-misc/aria2 with the xmlrpc USE enabled manually."
+		echo
+	fi
 }