Ensure that vte properly uses gnome-pty-helper (bug #401389, thanks to زياد بن عبدالعزيز الباتلي for reporting).

(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

4 files changed, 202 insertions, 1 deletions

diff --git a/x11-libs/vte/ChangeLog b/x11-libs/vte/ChangeLog
index 99b372d3ef3f..a38e515e0b6d 100644
--- a/x11-libs/vte/ChangeLog
+++ b/x11-libs/vte/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for x11-libs/vte
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/ChangeLog,v 1.305 2012/01/18 21:11:23 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/ChangeLog,v 1.306 2012/01/30 17:26:59 tetromino Exp $
+
+*vte-0.30.1-r3 (30 Jan 2012)
+*vte-0.28.2-r301 (30 Jan 2012)
+*vte-0.28.2-r203 (30 Jan 2012)
+
+  30 Jan 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +vte-0.28.2-r203.ebuild, +vte-0.28.2-r301.ebuild, +vte-0.30.1-r3.ebuild:
+  Ensure that vte properly uses gnome-pty-helper (bug #401389, thanks to
+  زياد بن عبدالعزيز الباتلي for reporting).
 
   18 Jan 2012; Markus Meier <maekke@gentoo.org> vte-0.28.2-r202.ebuild:
   arm stable, bug #393007
diff --git a/x11-libs/vte/vte-0.28.2-r203.ebuild b/x11-libs/vte/vte-0.28.2-r203.ebuild
new file mode 100644
index 000000000000..06b095c7dd4e
--- /dev/null
+++ b/x11-libs/vte/vte-0.28.2-r203.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/vte-0.28.2-r203.ebuild,v 1.1 2012/01/30 17:26:59 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+PYTHON_DEPEND="python? 2:2.4"
+
+inherit eutils gnome2 python
+
+DESCRIPTION="GNOME terminal widget"
+HOMEPAGE="http://git.gnome.org/browse/vte"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-linux"
+IUSE="debug doc glade +introspection python"
+
+PDEPEND="x11-libs/gnome-pty-helper"
+RDEPEND=">=dev-libs/glib-2.26:2
+	>=x11-libs/gtk+-2.20:2[introspection?]
+	>=x11-libs/pango-1.22.0
+
+	sys-libs/ncurses
+	x11-libs/libX11
+	x11-libs/libXft
+
+	glade? ( dev-util/glade:3 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
+	python? ( >=dev-python/pygtk-2.4:2 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
+	>=dev-util/pkgconfig-0.9
+	sys-devel/gettext
+	doc? ( >=dev-util/gtk-doc-1.13 )"
+
+pkg_setup() {
+	# Do not disable gnome-pty-helper, bug #401389
+	G2CONF="${G2CONF}
+		--disable-deprecation
+		--disable-maintainer-mode
+		--disable-static
+		$(use_enable debug)
+		$(use_enable glade glade-catalogue)
+		$(use_enable introspection)
+		$(use_enable python)
+		--with-gtk=2.0"
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	# https://bugzilla.gnome.org/show_bug.cgi?id=663779
+	epatch "${FILESDIR}/${PN}-0.30.1-alt-meta.patch"
+
+	gnome2_src_prepare
+}
+
+src_install() {
+	gnome2_src_install
+	rm -v "${ED}usr/libexec/gnome-pty-helper" || die
+	use python && python_clean_installation_image
+}
diff --git a/x11-libs/vte/vte-0.28.2-r301.ebuild b/x11-libs/vte/vte-0.28.2-r301.ebuild
new file mode 100644
index 000000000000..cbd3a6b26a5d
--- /dev/null
+++ b/x11-libs/vte/vte-0.28.2-r301.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/vte-0.28.2-r301.ebuild,v 1.1 2012/01/30 17:26:59 tetromino Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+GNOME_TARBALL_SUFFIX="xz"
+GNOME2_LA_PUNT="yes"
+
+inherit autotools eutils gnome2
+
+DESCRIPTION="GNOME terminal widget"
+HOMEPAGE="http://git.gnome.org/browse/vte"
+SRC_URI="${SRC_URI} mirror://gentoo/introspection.m4.bz2"
+
+LICENSE="LGPL-2"
+SLOT="2.90"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="debug doc glade +introspection"
+
+PDEPEND="x11-libs/gnome-pty-helper"
+RDEPEND=">=dev-libs/glib-2.26:2
+	>=x11-libs/gtk+-3.0:3[introspection?]
+	>=x11-libs/pango-1.22.0
+
+	sys-libs/ncurses
+	x11-libs/libX11
+	x11-libs/libXft
+
+	glade? ( >=dev-util/glade-3.9:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
+	>=dev-util/pkgconfig-0.9
+	sys-devel/gettext
+	doc? ( >=dev-util/gtk-doc-1.13 )"
+
+pkg_setup() {
+	# Python bindings are via gobject-introspection
+	# Ex: from gi.repository import Vte
+	# Do not disable gnome-pty-helper, bug #401389
+	G2CONF="${G2CONF}
+		--disable-deprecation
+		--disable-maintainer-mode
+		--disable-static
+		$(use_enable debug)
+		$(use_enable glade glade-catalogue)
+		$(use_enable introspection)
+		--with-gtk=3.0"
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-0.28.0-fix-gdk-targets.patch"
+
+	mv "${WORKDIR}/introspection.m4" "${S}/" || die
+	AT_M4DIR="." eautoreconf
+
+	gnome2_src_prepare
+}
+
+src_install() {
+	gnome2_src_install
+	rm -v "${ED}usr/libexec/gnome-pty-helper" || die
+}
diff --git a/x11-libs/vte/vte-0.30.1-r3.ebuild b/x11-libs/vte/vte-0.30.1-r3.ebuild
new file mode 100644
index 000000000000..f59605f203e1
--- /dev/null
+++ b/x11-libs/vte/vte-0.30.1-r3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/vte-0.30.1-r3.ebuild,v 1.1 2012/01/30 17:26:59 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2
+
+DESCRIPTION="GNOME terminal widget"
+HOMEPAGE="http://git.gnome.org/browse/vte"
+
+LICENSE="LGPL-2"
+SLOT="2.90"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="debug doc glade +introspection"
+
+PDEPEND="x11-libs/gnome-pty-helper"
+RDEPEND=">=dev-libs/glib-2.26:2
+	>=x11-libs/gtk+-3.1.9:3[introspection?]
+	>=x11-libs/pango-1.22.0
+
+	sys-libs/ncurses
+	x11-libs/libX11
+	x11-libs/libXft
+
+	glade? ( >=dev-util/glade-3.9:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
+	>=dev-util/pkgconfig-0.9
+	sys-devel/gettext
+	doc? ( >=dev-util/gtk-doc-1.13 )"
+
+pkg_setup() {
+	# Python bindings are via gobject-introspection
+	# Ex: from gi.repository import Vte
+	# Do not disable gnome-pty-helper, bug #401389
+	G2CONF="${G2CONF}
+		--disable-deprecation
+		--disable-maintainer-mode
+		--disable-static
+		$(use_enable debug)
+		$(use_enable glade glade-catalogue)
+		$(use_enable introspection)"
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+}
+
+src_prepare() {
+	# https://bugzilla.gnome.org/show_bug.cgi?id=663779
+	epatch "${FILESDIR}/${PN}-0.30.1-alt-meta.patch"
+
+	gnome2_src_prepare
+}
+
+src_install() {
+	gnome2_src_install
+	rm -v "${ED}usr/libexec/gnome-pty-helper" || die
+}