version bump

(Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key 0xB2EFA1D4)

2 files changed, 67 insertions, 1 deletions

diff --git a/x11-misc/pcmanfm-qt/ChangeLog b/x11-misc/pcmanfm-qt/ChangeLog
index 072c33e3cb82..60753162b522 100644
--- a/x11-misc/pcmanfm-qt/ChangeLog
+++ b/x11-misc/pcmanfm-qt/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/pcmanfm-qt
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/pcmanfm-qt/ChangeLog,v 1.5 2014/05/29 07:49:55 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/pcmanfm-qt/ChangeLog,v 1.6 2014/11/08 17:51:43 jauhien Exp $
+
+*pcmanfm-qt-0.8.0 (08 Nov 2014)
+
+  08 Nov 2014; Jauhien Piatlicki <jauhien@gentoo.org> +pcmanfm-qt-0.8.0.ebuild:
+  version bump
 
   29 May 2014; Manuel Rüger <mrueg@gentoo.org> pcmanfm-qt-0.7.0.ebuild:
   Add ~arm keyword.
diff --git a/x11-misc/pcmanfm-qt/pcmanfm-qt-0.8.0.ebuild b/x11-misc/pcmanfm-qt/pcmanfm-qt-0.8.0.ebuild
new file mode 100644
index 000000000000..58cbbb7fdae5
--- /dev/null
+++ b/x11-misc/pcmanfm-qt/pcmanfm-qt-0.8.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/pcmanfm-qt/pcmanfm-qt-0.8.0.ebuild,v 1.1 2014/11/08 17:51:43 jauhien Exp $
+
+EAPI=5
+
+inherit cmake-utils multilib readme.gentoo
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}"
+else
+	SRC_URI="http://lxqt.org/downloads/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Fast lightweight tabbed filemanager (Qt port)"
+HOMEPAGE="http://pcmanfm.sourceforge.net/"
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+CDEPEND=">=dev-libs/glib-2.18:2
+	dev-qt/linguist-tools:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	>=lxde-base/menu-cache-0.4.1
+	>=x11-libs/libfm-1.2.0
+	x11-libs/libxcb:=
+"
+RDEPEND="${CDEPEND}
+	x11-misc/xdg-utils
+	virtual/eject
+	virtual/freedesktop-icon-theme"
+DEPEND="${CDEPEND}
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_prepare() {
+	# fix multilib
+	sed -i -e "/LIBRARY\ DESTINATION/s:lib:$(get_libdir):" \
+		libfm-qt/CMakeLists.txt || die
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_QT5=ON
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	DOC_CONTENTS="Be sure to set an icon theme in Edit > Preferences > User Interface"
+	readme.gentoo_src_install
+}