10 files changed, 418 insertions, 3 deletions
diff --git a/kde-base/arts/ChangeLog b/kde-base/arts/ChangeLog
index d40dadaf0ba5..64368a22548f 100644
--- a/kde-base/arts/ChangeLog
+++ b/kde-base/arts/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/arts
 # Copyright 2002-2005 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/ChangeLog,v 1.179 2005/09/18 14:16:38 caleb Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/ChangeLog,v 1.180 2005/09/21 17:17:58 greg_g Exp $
+
+*arts-3.5_beta1 (21 Sep 2005)
+
+  21 Sep 2005; Gregorio Guidi <greg_g@gentoo.org> +arts-3.5_beta1.ebuild:
+  New version.
 
   18 Sep 2005; Caleb Tennis <caleb@gentoo.org> arts-3.4.1-r2.ebuild,
   arts-3.4.2.ebuild, arts-3.5_alpha1.ebuild:
diff --git a/kde-base/arts/arts-3.5_beta1.ebuild b/kde-base/arts/arts-3.5_beta1.ebuild
new file mode 100644
index 000000000000..93e56d6fa443
--- /dev/null
+++ b/kde-base/arts/arts-3.5_beta1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/arts-3.5_beta1.ebuild,v 1.1 2005/09/21 17:17:59 greg_g Exp $
+
+inherit kde flag-o-matic eutils
+set-kdedir 3.5
+
+#MY_PV=${PV/#3/1}
+MY_PV=1.4.91
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+DESCRIPTION="aRts, the KDE sound (and all-around multimedia) server/output manager"
+HOMEPAGE="http://multimedia.kde.org/"
+#SRC_URI="mirror://kde/stable/${PV}/src/${P}.tar.bz2"
+SRC_URI="mirror://kde/unstable/${PV/_/-}/src/${PN}-${MY_PV}.tar.bz2"
+LICENSE="GPL-2 LGPL-2"
+
+SLOT="3.5"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="alsa esd artswrappersuid jack mp3 nas hardened vorbis"
+
+RDEPEND="$(qt_min_version 3.3)
+	>=dev-libs/glib-2
+	alsa? ( media-libs/alsa-lib )
+	vorbis? ( media-libs/libogg
+	          media-libs/libvorbis )
+	esd? ( media-sound/esound )
+	jack? ( >=media-sound/jack-audio-connection-kit-0.90 )
+	mp3? ( media-libs/libmad )
+	nas? ( media-libs/nas )
+	media-libs/audiofile"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+src_unpack() {
+	kde_src_unpack
+	epatch "${FILESDIR}/arts-1.3.2-alsa-bigendian.patch"
+
+	if (is-flag -fstack-protector || is-flag -fstack-protector-all || use hardened); then
+		epatch ${FILESDIR}/arts-1.4-mcopidl.patch
+		make -f admin/Makefile.common || die
+	fi
+}
+
+src_compile() {
+	myconf="$(use_enable alsa) $(use_enable vorbis)
+	        $(use_enable mp3 libmad) $(use_with jack)
+	        $(use_with esd) $(use_with nas)
+		--with-audiofile --without-mas"
+
+	#fix bug 13453
+	filter-flags -foptimize-sibling-calls
+
+	#fix bug 41980
+	use sparc && filter-flags -fomit-frame-pointer
+
+	kde_src_compile
+}
+
+src_install() {
+	kde_src_install
+
+	# moved here from kdelibs so that when arts is installed
+	# without kdelibs it's still in the path.
+	# List all the multilib libdirs
+	local libdirs
+	for libdir in $(get_all_libdirs); do
+		libdirs="${libdirs}:${PREFIX}/${libdir}"
+	done
+
+	dodir /etc/env.d
+echo "PATH=${PREFIX}/bin
+ROOTPATH=${PREFIX}/sbin:${PREFIX}/bin
+LDPATH=${libdirs:1}
+CONFIG_PROTECT=\"${PREFIX}/share/config ${PREFIX}/env ${PREFIX}/shutdown\"" > ${D}/etc/env.d/45kdepaths-3.4 # number goes down with version upgrade
+
+	# used for realtime priority, but off by default as it is a security hazard
+	use artswrappersuid && chmod u+s ${D}/${PREFIX}/bin/artswrapper
+}
+
+pkg_postinst() {
+	if ! use artswrappersuid ; then
+		einfo "Run chmod u+s ${PREFIX}/bin/artswrapper to let artsd use realtime priority"
+		einfo "and so avoid possible skips in sound. However, on untrusted systems this"
+		einfo "creates the possibility of a DoS attack that'll use 100% cpu at realtime"
+		einfo "priority, and so is off by default. See bug #7883."
+		einfo "Or, you can set the local artswrappersuid USE flag to make the ebuild do this."
+	fi
+}
diff --git a/kde-base/arts/files/digest-arts-3.5_beta1 b/kde-base/arts/files/digest-arts-3.5_beta1
new file mode 100644
index 000000000000..52272d938976
--- /dev/null
+++ b/kde-base/arts/files/digest-arts-3.5_beta1
@@ -0,0 +1 @@
+MD5 51106f008798a75419aaec39ab7ba772 arts-1.4.91.tar.bz2 949254
diff --git a/kde-base/kdebase/ChangeLog b/kde-base/kdebase/ChangeLog
index 33749ac80b5a..50b7bafe6f57 100644
--- a/kde-base/kdebase/ChangeLog
+++ b/kde-base/kdebase/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kdebase
 # Copyright 2002-2005 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase/ChangeLog,v 1.217 2005/09/17 14:49:18 kloeri Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase/ChangeLog,v 1.218 2005/09/21 17:19:54 greg_g Exp $
+
+*kdebase-3.5_beta1 (21 Sep 2005)
+
+  21 Sep 2005; Gregorio Guidi <greg_g@gentoo.org> +kdebase-3.5_beta1.ebuild:
+  New version.
 
   25 Aug 2005; Aron Griffis <agriffis@gentoo.org> kdebase-3.4.1-r1.ebuild:
   stable on ia64
diff --git a/kde-base/kdebase/files/digest-kdebase-3.5_beta1 b/kde-base/kdebase/files/digest-kdebase-3.5_beta1
new file mode 100644
index 000000000000..0cf3430259a9
--- /dev/null
+++ b/kde-base/kdebase/files/digest-kdebase-3.5_beta1
@@ -0,0 +1 @@
+MD5 50674508355d37a0fddb71af540f085d kdebase-3.4.91.tar.bz2 23351343
diff --git a/kde-base/kdebase/kdebase-3.5_beta1.ebuild b/kde-base/kdebase/kdebase-3.5_beta1.ebuild
new file mode 100644
index 000000000000..8d5d8611c027
--- /dev/null
+++ b/kde-base/kdebase/kdebase-3.5_beta1.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase/kdebase-3.5_beta1.ebuild,v 1.1 2005/09/21 17:19:54 greg_g Exp $
+
+inherit kde-dist eutils
+
+DESCRIPTION="KDE base packages: the desktop, panel, window manager, konqueror..."
+
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~sparc ~x86"
+IUSE="arts cups java ldap ieee1394 hal lm_sensors logitech-mouse openexr opengl pam samba ssl zeroconf"
+# hal: enables hal backend for 'media:' ioslave
+
+DEPEND="arts? ( ~kde-base/arts-${PV} )
+	>=media-libs/freetype-2
+	media-libs/fontconfig
+	pam? ( kde-base/kdebase-pam )
+	>=dev-libs/cyrus-sasl-2
+	ldap? ( >=net-nds/openldap-2 )
+	cups? ( net-print/cups )
+	ssl? ( dev-libs/openssl )
+	opengl? ( virtual/opengl )
+	openexr? ( >=media-libs/openexr-1.2 )
+	samba? ( >=net-fs/samba-3.0.4 )
+	lm_sensors? ( sys-apps/lm_sensors )
+	logitech-mouse? ( >=dev-libs/libusb-0.1.10a )
+	ieee1394? ( sys-libs/libraw1394 )
+	hal? ( >=sys-apps/dbus-0.33
+	       =sys-apps/hal-0.5* )
+	zeroconf? ( net-misc/mDNSResponder )"
+
+RDEPEND="${DEPEND}
+	java? ( >=virtual/jre-1.4 )
+	virtual/eject"
+
+DEPEND="${DEPEND}
+	dev-util/pkgconfig"
+
+src_unpack() {
+	kde_src_unpack
+
+	epatch "${FILESDIR}/kdebase-3.5-startkde-gentoo.patch"
+
+	# Configure patch.
+	epatch "${FILESDIR}/kdebase-3.5-configure-openexr.patch"
+
+	# For the configure patch.
+	make -f admin/Makefile.common || die
+}
+
+src_compile() {
+	local myconf="--with-dpms
+	              $(use_with arts) $(use_with ldap)
+	              $(use_with opengl gl) $(use_with ssl)
+	              $(use_with samba) $(use_with openexr)
+	              $(use_with lm_sensors sensors) $(use_with logitech-mouse libusb)
+	              $(use_with ieee1394 libraw1394) $(use_with hal)
+	              $(use_enable zeroconf dnssd)"
+
+	if use pam; then
+		myconf="${myconf} --with-pam=yes"
+	else
+		myconf="${myconf} --with-pam=no --with-shadow"
+	fi
+
+	# the java test is problematic (see kde bug 100729) and
+	# useless. All that's needed for java applets to work is
+	# to have the 'java' executable in PATH.
+	myconf="${myconf} --without-java"
+
+	kde_src_compile
+}
+
+src_install() {
+	kde_src_install
+	cd ${S}/kdm && make DESTDIR=${D} GENKDMCONF_FLAGS="--no-old --no-backup --no-in-notice" install
+
+	# startup and shutdown scripts
+	insinto ${KDEDIR}/env
+	doins ${FILESDIR}/agent-startup.sh
+
+	exeinto ${KDEDIR}/shutdown
+	doexe ${FILESDIR}/agent-shutdown.sh
+
+	# freedesktop environment variables
+	cat <<EOF > ${T}/xdg.sh
+export XDG_DATA_DIRS="${KDEDIR}/share:/usr/share"
+export XDG_CONFIG_DIRS="${KDEDIR}/etc/xdg"
+EOF
+	insinto ${KDEDIR}/env
+	doins ${T}/xdg.sh
+
+	# x11 session script
+	cat <<EOF > ${T}/kde-${SLOT}
+#!/bin/sh
+exec ${KDEDIR}/bin/startkde
+EOF
+	exeinto /etc/X11/Sessions
+	doexe ${T}/kde-${SLOT}
+
+	# freedesktop compliant session script
+	sed -e "s:@KDE_BINDIR@:${KDEDIR}/bin:g;s:Name=KDE:Name=KDE ${SLOT}:" \
+		${S}/kdm/kfrontend/sessions/kde.desktop.in > ${T}/kde-${SLOT}.desktop
+	insinto /usr/share/xsessions
+	doins ${T}/kde-${SLOT}.desktop
+
+	# Customize the kdmrc configuration
+	sed -i -e "s:#SessionsDirs=:SessionsDirs=/usr/share/xsessions\n#SessionsDirs=:" \
+		${D}/${KDEDIR}/share/config/kdm/kdmrc || die
+
+	rmdir ${D}/${KDEDIR}/share/templates/.source/emptydir
+}
+
+pkg_postinst() {
+	# set the default kdm face icon if it's not already set by the system admin
+	if [ ! -e "${ROOT}${KDEDIR}/share/apps/kdm/faces/.default.face.icon" ]; then
+		mkdir -p "${ROOT}${KDEDIR}/share/apps/kdm/faces"
+		cp "${ROOT}${KDEDIR}/share/apps/kdm/pics/users/default1.png" \
+			"${ROOT}${KDEDIR}/share/apps/kdm/faces/.default.face.icon"
+	fi
+	if [ ! -e "${ROOT}${KDEDIR}/share/apps/kdm/faces/root.face.icon" ]; then
+		mkdir -p "${ROOT}${KDEDIR}/share/apps/kdm/faces"
+		cp "${ROOT}${KDEDIR}/share/apps/kdm/pics/users/root1.png" \
+			"${ROOT}${KDEDIR}/share/apps/kdm/faces/root.face.icon"
+	fi
+
+	mkdir -p ${ROOT}${KDEDIR}/share/templates/.source/emptydir
+
+	echo
+	einfo "To enable gpg-agent and/or ssh-agent in KDE sessions,"
+	einfo "edit ${KDEDIR}/env/agent-startup.sh and"
+	einfo "${KDEDIR}/shutdown/agent-shutdown.sh"
+	echo
+}
diff --git a/kde-base/kdelibs/ChangeLog b/kde-base/kdelibs/ChangeLog
index 70f19738e44e..e5b1929d17c7 100644
--- a/kde-base/kdelibs/ChangeLog
+++ b/kde-base/kdelibs/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kdelibs
 # Copyright 2002-2005 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/ChangeLog,v 1.272 2005/09/17 16:49:42 caleb Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/ChangeLog,v 1.273 2005/09/21 17:18:55 greg_g Exp $
+
+*kdelibs-3.5_beta1 (21 Sep 2005)
+
+  21 Sep 2005; Gregorio Guidi <greg_g@gentoo.org>
+  +files/kdelibs-3.5_beta1-configure-acl.patch, +kdelibs-3.5_beta1.ebuild:
+  New version. Add support for ACLs.
 
 *kdelibs-3.4.2-r1 (17 Sep 2005)
 
diff --git a/kde-base/kdelibs/files/digest-kdelibs-3.5_beta1 b/kde-base/kdelibs/files/digest-kdelibs-3.5_beta1
new file mode 100644
index 000000000000..15fc1f6a2f69
--- /dev/null
+++ b/kde-base/kdelibs/files/digest-kdelibs-3.5_beta1
@@ -0,0 +1 @@
+MD5 9981060a65037471f561ca11b2501792 kdelibs-3.4.91.tar.bz2 15267497
diff --git a/kde-base/kdelibs/files/kdelibs-3.5_beta1-configure-acl.patch b/kde-base/kdelibs/files/kdelibs-3.5_beta1-configure-acl.patch
new file mode 100644
index 000000000000..f3182dd5b7b6
--- /dev/null
+++ b/kde-base/kdelibs/files/kdelibs-3.5_beta1-configure-acl.patch
@@ -0,0 +1,37 @@
+diff -Nur kdelibs-3.4.91.orig/configure.in.in kdelibs-3.4.91/configure.in.in
+--- kdelibs-3.4.91.orig/configure.in.in	2005-09-10 10:27:50.000000000 +0200
++++ kdelibs-3.4.91/configure.in.in	2005-09-19 16:26:01.000000000 +0200
+@@ -48,16 +48,27 @@
+ AC_HEADER_STDC
+ AC_CHECK_HEADERS(sys/param.h sys/mman.h sys/time.h sysent.h strings.h sys/stat.h sys/select.h paths.h malloc.h limits.h sys/soundcard.h dlfcn.h termios.h)
+ 
+-USE_POSIX_ACL="yes"
++AC_ARG_WITH(acl,
++  [AC_HELP_STRING(--with-acl,
++    [enable support for POSIX ACLs @<:@default=check@:>@])],
++  [], with_acl=check)
++
+ ACL_LIBS=""
+-KDE_CHECK_HEADER(sys/xattr.h, ,[USE_POSIX_ACL="no"])
+-KDE_CHECK_HEADER(sys/acl.h, ,[USE_POSIX_ACL="no"])
+-KDE_CHECK_HEADER(acl/libacl.h, ,[USE_POSIX_ACL="no"])
+-KDE_CHECK_LIB(acl,acl_init, ,[USE_POSIX_ACL="no"])
++if test "x$with_acl" != xno; then
++  USE_POSIX_ACL="yes"
++  KDE_CHECK_HEADER(sys/xattr.h, ,[USE_POSIX_ACL="no"])
++  KDE_CHECK_HEADER(sys/acl.h, ,[USE_POSIX_ACL="no"])
++  KDE_CHECK_HEADER(acl/libacl.h, ,[USE_POSIX_ACL="no"])
++  KDE_CHECK_LIB(acl,acl_init, ,[USE_POSIX_ACL="no"])
+ 
+-if test $USE_POSIX_ACL = "yes" ; then
++  if test $USE_POSIX_ACL = "yes" ; then
+     ACL_LIBS="-lacl -lattr"
+     AC_DEFINE([USE_POSIX_ACL], 1, [Define if system has POSIX ACL support.])
++  fi
++
++  if test "x$with_acl" != xcheck && test "$USE_POSIX_ACL" != "yes"; then
++    AC_MSG_ERROR([--with-acl was given, but test for POSIX ACLs failed])
++  fi
+ fi
+ AC_SUBST(ACL_LIBS)
+ 
diff --git a/kde-base/kdelibs/kdelibs-3.5_beta1.ebuild b/kde-base/kdelibs/kdelibs-3.5_beta1.ebuild
new file mode 100644
index 000000000000..68e2d08507d8
--- /dev/null
+++ b/kde-base/kdelibs/kdelibs-3.5_beta1.ebuild
@@ -0,0 +1,135 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/kdelibs-3.5_beta1.ebuild,v 1.1 2005/09/21 17:18:55 greg_g Exp $
+
+inherit kde flag-o-matic eutils multilib
+set-kdedir 3.5
+
+MY_PV=3.4.91
+S=${WORKDIR}/${PN}-${MY_PV}
+
+DESCRIPTION="KDE libraries needed by all kde programs"
+HOMEPAGE="http://www.kde.org/"
+#SRC_URI="mirror://kde/stable/${PV}/src/${P}.tar.bz2"
+SRC_URI="mirror://kde/unstable/${PV/_/-}/src/${PN}-${MY_PV}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="3.5"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="acl alsa arts cups doc jpeg2k kerberos openexr spell ssl tiff zeroconf"
+
+# kde.eclass has kdelibs in DEPEND, and we can't have that in here.
+# so we recreate the entire DEPEND from scratch.
+RDEPEND="$(qt_min_version 3.3.3)
+	arts? ( ~kde-base/arts-${PV} )
+	app-arch/bzip2
+	>=media-libs/freetype-2
+	media-libs/fontconfig
+	>=dev-libs/libxslt-1.1.4
+	>=dev-libs/libxml2-2.6.6
+	>=dev-libs/libpcre-4.2
+	media-libs/libart_lgpl
+	net-dns/libidn
+	virtual/utempter
+	acl? ( sys-apps/acl )
+	ssl? ( >=dev-libs/openssl-0.9.7d )
+	alsa? ( media-libs/alsa-lib )
+	cups? ( >=net-print/cups-1.1.19 )
+	tiff? ( media-libs/tiff )
+	kerberos? ( virtual/krb5 )
+	jpeg2k? ( media-libs/jasper )
+	openexr? ( >=media-libs/openexr-1.2 )
+	spell? ( || ( app-text/aspell
+	              app-text/ispell ) )
+	zeroconf? ( net-misc/mDNSResponder )
+	virtual/fam
+	virtual/ghostscript"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	sys-devel/gettext
+	dev-util/pkgconfig"
+
+src_unpack() {
+	kde_src_unpack
+
+	# Configure check for ACLs.
+	epatch "${FILESDIR}/${P}-configure-acl.patch"
+
+	# For the configure check.
+	make -f admin/Makefile.common || die
+}
+
+src_compile() {
+	myconf="--with-distribution=Gentoo
+	        --enable-libfam $(use_enable kernel_linux dnotify)
+	        --with-libart --with-libidn --with-utempter
+	        $(use_with acl) $(use_with ssl)
+	        $(use_with alsa) $(use_with arts)
+	        $(use_with kerberos gssapi) $(use_with tiff)
+	        $(use_with jpeg2k jasper) $(use_with openexr)
+	        $(use_enable cups) $(use_enable zeroconf dnssd)"
+
+	if use spell && has_version app-text/aspell; then
+		myconf="${myconf} --with-aspell"
+	else
+		myconf="${myconf} --without-aspell"
+	fi
+
+	myconf="${myconf} --disable-fast-malloc"
+
+	# fix bug 58179, bug 85593
+	# kdelibs-3.4.0 needed -fno-gcse; 3.4.1 needs -mminimal-toc; this needs a
+	# closer look... - corsair
+	use ppc64 && append-flags "-mminimal-toc"
+
+	kde_src_compile
+
+	if use doc; then
+		make apidox || die
+	fi
+}
+
+src_install() {
+	kde_src_install
+
+	if use doc; then
+		make DESTDIR="${D}" install-apidox || die
+	fi
+
+	# Needed to create lib -> lib64 symlink for amd64 2005.0 profile
+	if [ "${SYMLINK_LIB}" = "yes" ]; then
+		dosym $(get_abi_LIBDIR ${DEFAULT_ABI}) ${KDEDIR}/lib
+	fi
+
+	if ! use arts ; then
+		dodir /etc/env.d
+
+		# List all the multilib libdirs
+		local libdirs
+		for libdir in $(get_all_libdirs); do
+			libdirs="${libdirs}:${PREFIX}/${libdir}"
+		done
+
+		cat <<EOF > ${D}/etc/env.d/45kdepaths-${SLOT} # number goes down with version upgrade
+PATH=${PREFIX}/bin
+ROOTPATH=${PREFIX}/sbin:${PREFIX}/bin
+LDPATH=${libdirs:1}
+CONFIG_PROTECT="${PREFIX}/share/config ${PREFIX}/env ${PREFIX}/shutdown"
+EOF
+	fi
+
+}
+
+pkg_postinst() {
+	if use zeroconf; then
+		echo
+		einfo "To make zeroconf support available in KDE"
+		einfo "make sure that the 'mdnsd' daemon is running."
+		einfo "Make sure also that multicast dns lookups are"
+		einfo "enabled by editing the 'hosts:' line in"
+		einfo "/etc/nsswitch.conf to include 'mdns', e.g.:"
+		einfo "hosts: files mdns dns"
+		echo
+	fi
+}