1 files changed, 43 insertions, 0 deletions
diff --git a/net-libs/libnice/libnice-0.1.0.ebuild b/net-libs/libnice/libnice-0.1.0.ebuild
new file mode 100644
index 000000000000..c2940e3309a9
--- /dev/null
+++ b/net-libs/libnice/libnice-0.1.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libnice/libnice-0.1.0.ebuild,v 1.1 2011/02/21 07:25:04 nirbheek Exp $
+
+EAPI="3"
+
+inherit eutils libtool
+
+DESCRIPTION="An implementation of the Interactice Connectivity Establishment standard (ICE)"
+HOMEPAGE="http://nice.freedesktop.org/wiki/"
+SRC_URI="http://nice.freedesktop.org/releases/${P}.tar.gz"
+
+LICENSE="LGPL-2.1 MPL-1.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="+gstreamer upnp"
+
+RDEPEND=">=dev-libs/glib-2.10
+	gstreamer? (
+		media-libs/gstreamer:0.10
+		media-libs/gst-plugins-base:0.10 )
+	upnp? ( >=net-libs/gupnp-igd-0.1.3 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.0.13-darwin.patch
+	elibtoolize  # for .bundle on Darwin
+}
+
+src_configure() {
+	econf --disable-static \
+		$(use_with gstreamer) \
+		$(use_enable upnp gupnp)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+	dodoc AUTHORS COPYING* README NEWS || die "dodoc failed."
+
+	# Remove .la files since static libs are no longer being installed
+	find "${D}" -name '*.la' -exec rm -f '{}' + || die
+}