1 files changed, 86 insertions, 0 deletions
diff --git a/net-wireless/hostapd/hostapd-0.4.2.ebuild b/net-wireless/hostapd/hostapd-0.4.2.ebuild
new file mode 100644
index 000000000000..89449ed503da
--- /dev/null
+++ b/net-wireless/hostapd/hostapd-0.4.2.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/hostapd/hostapd-0.4.2.ebuild,v 1.1 2005/06/13 14:43:25 brix Exp $
+
+inherit toolchain-funcs
+
+MADWIFI_VERSION="2005-04-20"
+
+DESCRIPTION="IEEE 802.11 wireless LAN Host AP daemon"
+HOMEPAGE="http://hostap.epitest.fi"
+SRC_URI="http://hostap.epitest.fi/releases/${P}.tar.gz
+		mirror://gentoo/madwifi-cvs-snapshot-${MADWIFI_VERSION}.tar.bz2"
+
+LICENSE="|| ( GPL-2 BSD )"
+SLOT="0"
+KEYWORDS="~x86 ~ppc"
+
+IUSE="ipv6 ssl"
+
+DEPEND="sys-apps/sed"
+RDEPEND="ssl? ( dev-libs/openssl )"
+
+src_unpack() {
+	local CONFIG=${S}/.config
+
+	unpack ${A}
+
+	sed -i -e "s:/etc/hostapd:/etc/hostapd/hostapd:g" \
+		${S}/hostapd.conf
+
+	# toolchain setup
+	echo "CC = $(tc-getCC)" > ${CONFIG}
+
+	# authentication methods
+	echo "CONFIG_EAP=y"           >> ${CONFIG}
+	echo "CONFIG_EAP_MD5=y"       >> ${CONFIG}
+	echo "CONFIG_EAP_GTC=y"       >> ${CONFIG}
+	echo "CONFIG_IAPP=y"          >> ${CONFIG}
+	echo "CONFIG_PKCS12=y"        >> ${CONFIG}
+	echo "CONFIG_RADIUS_SERVER=y" >> ${CONFIG}
+	echo "CONFIG_RSN_PREAUTH=y"   >> ${CONFIG}
+	echo "CONFIG_EAP_SIM=y"       >> ${CONFIG}
+
+	if use ssl; then
+		# SSL authentication methods
+		echo "CONFIG_EAP_MSCHAPV2=y" >> ${CONFIG}
+		echo "CONFIG_EAP_PEAP=y"     >> ${CONFIG}
+		echo "CONFIG_EAP_TLS=y"      >> ${CONFIG}
+		echo "CONFIG_EAP_TTLS=y"     >> ${CONFIG}
+	fi
+
+	if use ipv6; then
+		echo "CONFIG_IPV6=y" >> ${CONFIG}
+	fi
+
+	# Linux specific drivers
+	echo "CONFIG_DRIVER_HOSTAP=y"  >> ${CONFIG}
+	echo "CONFIG_DRIVER_WIRED=y"   >> ${CONFIG}
+	echo "CONFIG_DRIVER_PRISM54=y" >> ${CONFIG}
+
+	# Add include path for madwifi-driver headers
+	echo "CFLAGS += -I${WORKDIR}/madwifi" >> ${CONFIG}
+	echo "CONFIG_DRIVER_MADWIFI=y"        >> ${CONFIG}
+}
+
+src_compile() {
+	emake || die "emake failed"
+}
+
+src_install() {
+	insinto /etc/hostapd
+	doins hostapd.conf hostapd.accept hostapd.deny
+
+	dosbin hostapd
+	dobin hostapd_cli
+
+	newinitd ${FILESDIR}/${P}-init.d hostapd
+	newconfd ${FILESDIR}/${P}-conf.d hostapd
+
+	doman hostapd.8 hostapd_cli.1
+
+	dodoc ChangeLog developer.txt README
+
+	docinto examples
+	dodoc madwifi.conf wired.conf
+}