1 files changed, 111 insertions, 0 deletions
diff --git a/x11-misc/lightdm/lightdm-1.4.0.ebuild b/x11-misc/lightdm/lightdm-1.4.0.ebuild
new file mode 100644
index 000000000000..1381127178f6
--- /dev/null
+++ b/x11-misc/lightdm/lightdm-1.4.0.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/lightdm-1.4.0.ebuild,v 1.1 2012/10/12 17:56:01 hwoarang Exp $
+
+EAPI=4
+inherit autotools eutils pam
+
+TRUNK_VERSION="1.4"
+DESCRIPTION="A lightweight display manager"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/LightDM"
+SRC_URI="http://launchpad.net/${PN}/${TRUNK_VERSION}/${PV}/+download/${P}.tar.gz
+	mirror://gentoo/introspection-20110205.m4.tar.bz2"
+
+LICENSE="GPL-3 LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+introspection qt4"
+
+COMMON_DEPEND=">=dev-libs/glib-2.32.3:2
+	dev-libs/libxml2
+	sys-apps/accountsservice
+	virtual/pam
+	x11-libs/libX11
+	>=x11-libs/libxklavier-5
+	introspection? ( >=dev-libs/gobject-introspection-1 )
+	qt4? (
+		x11-libs/qt-core:4
+		x11-libs/qt-dbus:4
+		x11-libs/qt-gui:4
+		)"
+RDEPEND="${COMMON_DEPEND}
+	>=sys-auth/pambase-20101024-r2"
+DEPEND="${COMMON_DEPEND}
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	gnome-base/gnome-common
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+DOCS=( NEWS )
+
+src_prepare() {
+	sed -i -e 's:getgroups:lightdm_&:' tests/src/libsystem.c || die #412369
+	sed -i -e '/minimum-uid/s:500:1000:' data/users.conf || die
+
+	epatch "${FILESDIR}"/session-wrapper-${PN}.patch
+	epatch "${FILESDIR}"/${PN}-1.2.0-fix-configure.patch
+	epatch_user
+
+	# Remove bogus Makefile statement. This needs to go upstream
+	sed -i /"@YELP_HELP_RULES@"/d help/Makefile.am || die
+	if has_version dev-libs/gobject-introspection; then
+		eautoreconf
+	else
+		AT_M4DIR=${WORKDIR} eautoreconf
+	fi
+}
+
+src_configure() {
+	# Set default values if global vars unset
+	local _greeter _session _user
+	_greeter=${LIGHTDM_GREETER:=lightdm-gtk-greeter}
+	_session=${LIGHTDM_SESSION:=gnome}
+	_user=${LIGHTDM_USER:=root}
+	# Let user know how lightdm is configured
+	einfo "Gentoo configuration"
+	einfo "Default greeter: ${_greeter}"
+	einfo "Default session: ${_session}"
+	einfo "Greeter user: ${_user}"
+
+	econf \
+		--localstatedir=/var \
+		--disable-static \
+		$(use_enable introspection) \
+		$(use_enable qt4 liblightdm-qt) \
+		--with-user-session=${_session} \
+		--with-greeter-session=${_greeter} \
+		--with-greeter-user=${_user} \
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+}
+
+src_install() {
+	default
+
+	insinto /etc/${PN}
+	doins data/{${PN},keys}.conf
+	doins "${FILESDIR}"/Xsession
+	fperms +x /etc/${PN}/Xsession
+
+	prune_libtool_files --all
+	rm -rf "${ED}"/etc/init
+
+	pamd_mimic system-local-login ${PN} auth account session #372229
+	dopamd "${FILESDIR}"/${PN}-autologin #390863, #423163
+}
+
+pkg_postinst() {
+	elog
+	elog "You will need to install a greeter as actual GUI for LightDM."
+	elog
+	elog "Even though the default /etc/${PN}/${PN}.conf will work for"
+	elog "most users, make sure you configure it to suit your needs"
+	elog "before using ${PN} for the first time."
+	elog "You can test the configuration file using the following"
+	elog "command: ${PN} --test-mode -c /etc/${PN}/${PN}.conf. This"
+	elog "requires xorg-server to be built with the 'kdrive' useflag."
+	elog
+	elog "You can also set your own default values for LIGHTDM_GREETER,"
+	elog "LIGHTDM_SESSION, LIGHTDM_USER in /etc/make.conf"
+	elog
+}