dev-java/jamon/jamon-1.01-r3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/jamon/jamon-1.01-r3.ebuild,v 1.1 2014/03/08 16:55:26 tomwij Exp $

EAPI="5"

JAVA_PKG_IUSE="doc"

inherit java-pkg-2 java-ant-2 eutils

MY_PN="JAMon"
MY_PV="103005"

DESCRIPTION="Java API to monitor production applications"
HOMEPAGE="http://www.javaperformancetuning.com/tools/jamon/index.shtml"
SRC_URI="mirror://sourceforge/jamonapi/${MY_PN}All_${MY_PV}.zip"

LICENSE="BSD"
SLOT="1"
KEYWORDS="~amd64 ~x86"

RDEPEND=">=virtual/jre-1.4
	java-virtuals/servlet-api:2.3"

DEPEND=">=virtual/jdk-1.4
	app-arch/unzip
	${RDEPEND}"

S="${WORKDIR}"

java_prepare() {
	rm ${MY_PN}.{j,w}ar || die

	epatch "${FILESDIR}"/${P}-java1.5.patch

	mv Code src || die

	# No provided ant script! Bad upstream, bad!
	cp "${FILESDIR}"/build-1.0.xml build.xml || die
}

src_compile() {
	eant jar $(use_doc) \
		-Dproject.name=${PN} \
		-Dclasspath=$(java-pkg_getjars servlet-api-2.3)
}

src_install() {
	java-pkg_dojar dist/${PN}.jar

	use doc && java-pkg_dojavadoc dist/doc/api
}