dev-ruby/iobuffer/iobuffer-1.1.2-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/iobuffer/iobuffer-1.1.2-r2.ebuild,v 1.2 2012/04/17 17:18:48 graaff Exp $

EAPI="4"
# jruby: mkmf
# rbx: Kernel(Autoload)#allocate (method_missing)
USE_RUBY="ruby18 ruby19 ree18"

RUBY_FAKEGEM_TASK_DOC=""
RUBY_FAKEGEM_EXTRADOC="CHANGES.md README.md"

RUBY_FAKEGEM_TASK_TEST="spec"

inherit ruby-fakegem

GITHUB_USER="tarcieri"

DESCRIPTION="IO::Buffer is a fast byte queue which is primarily intended for non-blocking I/O applications"
HOMEPAGE="http://github.com/tarcieri/iobuffer"
SRC_URI="http://github.com/${GITHUB_USER}/iobuffer/tarball/v${PV} -> ${PN}-git-${PV}.tgz"

LICENSE="MIT"
KEYWORDS="~amd64 ~x86 ~x86-macos"
SLOT="0"
IUSE=""

RUBY_S="${GITHUB_USER}-${PN}-*"

ruby_add_bdepend "test? ( dev-ruby/bundler dev-ruby/rspec )"

all_ruby_prepare() {
	rm .rspec lib/.gitignore || die
}

each_ruby_configure() {
	${RUBY} -C ext extconf.rb || die
	sed -i -e "s/^ldflags  = /ldflags = $\(LDFLAGS\) /" ext/Makefile || die
}

each_ruby_compile() {
	emake -C ext
	cp ext/iobuffer_ext.so lib/ || die
}

each_ruby_test() {
	${RUBY} -Ilib -S rspec spec || die
}