dev-ruby/redcarpet/redcarpet-2.2.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/redcarpet/redcarpet-2.2.2.ebuild,v 1.1 2012/11/13 19:16:49 graaff Exp $

EAPI=4
USE_RUBY="ruby18 ree18 ruby19"

RUBY_FAKEGEM_TASK_DOC=""

# There are also conformance tests but these files are not shipped in
# the gem.
RUBY_FAKEGEM_TASK_TEST="test:unit"

inherit multilib ruby-fakegem

DESCRIPTION="A Ruby wrapper for Upskirt."
HOMEPAGE="https://github.com/tanoku/redcarpet"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

all_ruby_prepare() {
	# Remove test depending on compile, since we handle compilation
	# directly.
	sed -i -e 's/:compile//' Rakefile || die
}

each_ruby_configure() {
	${RUBY} -Cext/redcarpet extconf.rb || die
}

each_ruby_compile() {
	emake -Cext/redcarpet
	cp ext/redcarpet/*$(get_modname) lib/ || die
}