games-puzzle/ltris/ltris-1.0.11.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-puzzle/ltris/ltris-1.0.11.ebuild,v 1.5 2005/12/10 12:37:45 blubb Exp $

inherit eutils games

DESCRIPTION="very polished Tetris clone"
HOMEPAGE="http://lgames.sourceforge.net/"
SRC_URI="mirror://sourceforge/lgames/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc sparc x86"
IUSE="nls"

RDEPEND=">=media-libs/libsdl-1.1.5
	media-libs/sdl-mixer
	nls? ( sys-devel/gettext )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/autoconf )"

src_unpack() {
	unpack "${A}"
	cd "${S}"
	if use nls ; then
		sed -i \
			-e '/^localedir/s:$(datadir):/usr/share:' \
			po/Makefile.in.in \
			|| die "sed failed"
		sed -i \
			-e '/^localedir/s:$datadir:/usr/share:' \
			configure.in \
			|| die "sed failed"
		aclocal && automake -a -c && autoconf || die "autotools failed"
	fi
}

src_compile() {
	egamesconf \
		--disable-dependency-tracking \
		--with-highscore-path="${GAMES_STATEDIR}" \
		$(use_enable nls) || die
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS ChangeLog README TODO
	newicon icons/ltris48.xpm ${PN}.xpm
	make_desktop_entry ltris LTris ${PN}.xpm
	prepgamesdirs
}