media-libs/stk/stk-4.3.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/stk/stk-4.3.1.ebuild,v 1.4 2009/07/30 11:28:31 ssuominen Exp $

inherit eutils autotools

DESCRIPTION="Synthesis ToolKit in C++"
HOMEPAGE="http://ccrma.stanford.edu/software/stk/"
SRC_URI="http://ccrma.stanford.edu/software/stk/release/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa debug doc jack oss"

RDEPEND="alsa? ( media-libs/alsa-lib )
	jack? ( media-sound/jack-audio-connection-kit )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-lang/perl"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}-cflags-lib.patch"
	epatch "${FILESDIR}/${P}-gcc43.patch"
	epatch "${FILESDIR}/${P}-fpic.patch"
	epatch "${FILESDIR}/${P}-missing.patch"
	epatch "${FILESDIR}/${P}-ldflags.patch"
	epatch "${FILESDIR}/${P}-gcc44.patch"
	eautoreconf
}

src_compile() {
	local myconf
	# --without-jack is broken in autofoo, see #232302
	use jack && myconf="--with-jack"

	econf \
		`use_with alsa` \
		`use_with oss` \
		`use_enable debug` \
		RAWWAVE_PATH=/usr/share/stk/rawwaves/ \
		${myconf} \
		|| die "configure failed!"

	# compile libstk
	cd src
	emake || die "make in src failed!"
}

src_install() {
	dodoc README
	# install the lib
	dolib src/libstk.*
	# install headers
	insinto /usr/include/stk
	doins include/*.h include/*.msg include/*.tbl
	# install rawwaves
	insinto /usr/share/stk/rawwaves
	doins rawwaves/*.raw
	# install docs
	if use doc; then
		dohtml -r doc/html/*
	fi
}