media-sound/nted/nted-1.10.18-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/nted/nted-1.10.18-r2.ebuild,v 1.5 2013/02/18 13:23:30 pinkbyte Exp $

EAPI=5

inherit autotools eutils toolchain-funcs

DESCRIPTION="WYSIWYG score editor for GTK+"
HOMEPAGE="http://vsr.informatik.tu-chemnitz.de/staff/jan/nted/nted.xhtml"
SRC_URI="http://vsr.informatik.tu-chemnitz.de/staff/jan/${PN}/sources/${P}.tar.gz"

LICENSE="GPL-2 FDL-1.2 NTED_FONT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc debug nls"

RDEPEND=">=dev-libs/glib-2
	media-libs/alsa-lib
	>=media-libs/freetype-2
	x11-libs/cairo
	>=x11-libs/gdk-pixbuf-2
	x11-libs/gtk+:2
	x11-libs/libX11
	x11-libs/pango"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( app-text/xmlto )
	nls? ( sys-devel/gettext )"

DOCS=( ABOUT_THE_EXAMPLES.TXT AUTHORS FAQ README )

src_prepare() {
	# bug #424291
	epatch "${FILESDIR}"/${P}-gcc47.patch
	# bug #437540
	epatch "${FILESDIR}"/${P}-lilypond.patch
	epatch "${FILESDIR}"/${P}-lilypond-tremolo.patch
	# fix desktop file, wrt bug #458080
	sed -i \
		-e 's/nted.png/nted/' \
		-e '/^Categories/s/Application;//' \
		datafiles/applications/nted.desktop || die 'sed on desktop file failed'
	# drop -g from CXXFLAGS, wrt bug #458086
	sed -i -e '/CXXFLAGS/s/ -g//' configure.in || die 'sed on configure.in failed'
	eautoreconf
}

src_configure() {
	# Trick ./configure to believe we have gnome-extra/yelp installed.
	has_version gnome-extra/yelp || export ac_cv_path_YELP="$(type -P true)"

	econf \
		--docdir=/usr/share/doc/${PF} \
		$(use_enable debug) \
		$(use_enable nls) \
		$(use_with doc)
}

src_compile() {
	emake AR="$(tc-getAR)"
}