net-dialup/umtsmon/umtsmon-0.8.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dialup/umtsmon/umtsmon-0.8.ebuild,v 1.3 2008/10/05 09:11:19 mrness Exp $

EAPI=1

inherit eutils qt3

DESCRIPTION="Tool to control and monitor wireless mobile network cards (GPRS, EDGE, WCDMA, UMTS, EV-DO, HSDPA)"
HOMEPAGE="http://umtsmon.sourceforge.net/"
SRC_URI="mirror://sourceforge/umtsmon/${P}.src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="x11-libs/qt:3
	dev-libs/libusb"
RDEPEND="${DEPEND}
	net-dialup/ppp
	sys-apps/pcmciautils"

# for i18n support
# Supported languages and translated documentation
# Be sure all languages are prefixed with a single space!
MY_AVAILABLE_LINGUAS=" nl de pt_PT pt_BR"
IUSE="${IUSE} ${MY_AVAILABLE_LINGUAS// / linguas_}"

src_compile() {
	eqmake3 || die "eqmake3 failed"
	emake || die "emake failed"

	#for i18n support
	local MY_LINGUAS="" lang

	for lang in ${MY_AVAILABLE_LINGUAS} ; do
		if use linguas_${lang} ; then
			MY_LINGUAS="${MY_LINGUAS} ${lang}"
		fi
	done
	if [[ -z "${MY_LINGUAS}" ]] ; then
		#If no language is selected, install 'em all
		MY_LINGUAS="${MY_AVAILABLE_LINGUAS}"
	fi

	einfo "Following langpacks will be installed:"
	einfo "   ${MY_LINGUAS}"

	for lang in ${MY_LINGUAS}; do
		lrelease i18n/umtsmon_${lang}.ts \
			|| die "failed to install langpack for ${lang} language"
	done
}

src_install() {
	dobin umtsmon || die "dobin failed"

	domenu umtsmon.desktop
	doicon images/128

	# for i18n support
	insinto /usr/share/umtsmon/translations
	doins i18n/*.qm

	dodoc AUTHORS README TODO
}