sci-biology/qrna/qrna-2.0.3c-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-biology/qrna/qrna-2.0.3c-r1.ebuild,v 1.4 2012/12/06 04:15:42 phajdan.jr Exp $

EAPI=4

inherit eutils toolchain-funcs

DESCRIPTION="Prototype ncRNA genefinder"
HOMEPAGE="http://selab.janelia.org/software.html"
SRC_URI="mirror://gentoo/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~ppc x86"
IUSE=""

RDEPEND="
	dev-lang/perl
	sci-biology/hmmer"
DEPEND="${RDEPEND}"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-glibc-2.10.patch \
		"${FILESDIR}"/${P}-ldflags.patch
	sed \
		-e "s:^CC.*:CC = $(tc-getCC):" \
		-e "/^AR/s:ar:$(tc-getAR):g" \
		-e "/^RANLIB/s:ranlib:$(tc-getRANLIB):g" \
		-e "/CFLAGS/s:=.*$:= ${CFLAGS}:" \
		-i {src,squid,squid02}/Makefile || die
	rm -v squid*/*.a
}

src_compile() {
	local dir
	for dir in squid squid02 src; do
		emake -C ${dir}
	done
}

src_install () {
	dobin src/{cfgbuild,eqrna,eqrna_sample,rnamat_main} scripts/*

	newdoc 00README README
	insinto /usr/share/doc/${PF}
	doins documentation/*

	insinto /usr/share/${PN}/data
	doins lib/*
	insinto /usr/share/${PN}/demos
	doins Demos/*

	# Sets the path to the QRNA data files.
	doenvd "${FILESDIR}"/26qrna
}