sci-libs/libdap/libdap-3.10.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/libdap/libdap-3.10.0.ebuild,v 1.2 2010/04/27 15:19:14 scarabeus Exp $

EAPI="3"

inherit base

DESCRIPTION="Implementation of a C++ SDK for DAP 2.0 and 3.2"
HOMEPAGE="http://opendap.org/"
SRC_URI="http://www.opendap.org/pub/source/${P}.tar.gz"

LICENSE="|| ( LGPL-2.1 URI )"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="doc static-libs"

RDEPEND="
	dev-util/cppunit
	dev-libs/libxml2
	net-misc/curl
	sys-libs/zlib
"

DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

PATCHES=( "${FILESDIR}/${PV}-fix_tests.patch" )

RESTRICT="test"
# needs http connection
# FAIL: MIMEUtilTest

src_configure() {
	econf \
		$(use_enable static-libs static)
}

src_compile() {
	base_src_compile
	if use doc; then
		emake docs || die "make docs failed"
	fi
}

src_test() {
	cd "${S}"/unit-tests
	emake check || die
}

src_install() {
	base_src_install
	dodoc README NEWS README.dodsrc || die
	use doc && { dohtml docs/html/* || die ; }
}