sys-apps/s390-tools/s390-tools-1.6.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/s390-tools/s390-tools-1.6.2.ebuild,v 1.5 2009/01/11 08:56:20 vapier Exp $

inherit eutils

E2FSPROGS_P=e2fsprogs-1.37
LINUX_P=linux-2.6.12

DESCRIPTION="A set of user space utilities that should be used together with the zSeries (s390) Linux kernel and device drivers"
HOMEPAGE="http://www.ibm.com/developerworks/linux/linux390/october2005_recommended.html"
SRC_URI="mirror://gentoo/${P}.tar.gz
	mirror://sourceforge/e2fsprogs/${E2FSPROGS_P}.tar.gz
	mirror://kernel/linux/kernel/v2.6/${LINUX_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* s390"
IUSE="snmp"

RDEPEND="sys-fs/sysfsutils
	snmp? ( net-analyzer/net-snmp )"
DEPEND="${RDEPEND}
	dev-util/indent
	app-admin/genromfs"
PROVIDE="virtual/bootloader"

src_unpack() {
	unpack ${P}.tar.gz
	cd "${S}"
	local x
	for x in ${E2FSPROGS_P}.tar.gz ${LINUX_P}.tar.bz2 ; do
		ln -s "${DISTDIR}"/${x} zfcpdump/extern/${x} || die "ln ${x}"
	done
	sed -i -re 's:__u(8|16|32):uint\1_t:' $(find osasnmpd -name '*.h')
	sed -i -e "s:-lrpm[iodb]*::g" osasnmpd/Makefile.rules
	use snmp || sed -i -e '/SUB_DIRS/s:osasnmpd::' Makefile
	sed -i -e '/^ZFCPDUMP_DIR/s:local/::' common.mak
}

src_install() {
	emake install INSTROOT="${D}" USRBINDIR="${D}/sbin" || die
	dodoc README
	insinto /etc/udev/rules.d
	doins etc/udev/rules.d/*.rules || die
}