x11-base/nouveau-drm/nouveau-drm-20100226.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-base/nouveau-drm/nouveau-drm-20100226.ebuild,v 1.2 2010/03/16 04:21:47 chithanh Exp $

EAPI=2

inherit linux-info linux-mod

DESCRIPTION="Nouveau DRM Kernel Modules for X11"
HOMEPAGE="http://nouveau.freedesktop.org/"
SRC_URI="mirror://gentoo/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE=""

DEPEND="virtual/linux-sources"
RDEPEND="${DEPEND}"

S=${WORKDIR}/master

CONFIG_CHECK="~BACKLIGHT_CLASS_DEVICE ~DEBUG_FS !DRM ~FB_CFB_FILLRECT ~FB_CFB_COPYAREA ~FB_CFB_IMAGEBLIT ~FRAMEBUFFER_CONSOLE ~!FB_UVESA ~I2C_ALGOBIT ~VGA_ARB"

pkg_setup() {
	linux-mod_pkg_setup
	if kernel_is lt 2 6 32; then
		eerror "You need kernel 2.6.32 for nouveau-drm"
		die "Incompatible kernel version"
	fi
	if kernel_is ge 2 6 33; then
		elog "For newer kernels newer than 2.6.32 there is integrated nouveau DRM."
		elog "Use that if you experience build issues."
	fi
}

src_compile() {
	set_arch_to_kernel
	emake \
		LINUXDIR="${KERNEL_DIR}" \
		NOUVEAUROOTDIR="${PWD}" \
		-f "${FILESDIR}"/${PN}-20100212-Makefile \
		|| die "Compiling kernel modules failed"
}

src_install() {
	insinto /lib/modules/${KV_FULL}/${PN}
	doins drivers/gpu/drm/{*/,}*.ko || die "doins failed"
}