x11-libs/xbae/xbae-4.60.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/xbae/xbae-4.60.4.ebuild,v 1.17 2012/08/15 17:43:22 bicatali Exp $

EAPI=4

inherit autotools-utils

DESCRIPTION="Motif-based widget to display a grid of cells as a spreadsheet"
HOMEPAGE="http://xbae.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="BSD"
KEYWORDS="alpha amd64 hppa ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux"
SLOT="0"
IUSE="doc examples static-libs"

RDEPEND="
	x11-libs/openmotif:0
	x11-libs/libXau
	x11-libs/libXdmcp
	x11-libs/libXext
	x11-libs/libXmu
	x11-libs/libXpm
	x11-libs/libXt"

DEPEND="${RDEPEND}"

# tests need X display
# and are interactive so virtualx will not help
RESTRICT=test

PATCHES=(
	"${FILESDIR}"/${P}-tmpl.patch
	"${FILESDIR}"/${P}-lxmp.patch
	"${FILESDIR}"/${P}-Makefile.in.patch
	)

src_configure() {
	local myeconfargs=( --enable-production )
	autotools-utils_src_configure
}

src_test() {
	cd ${AUTOTOOLS_BUILD_DIR}/examples
	emake
	"${S}"/examples/testall
	emake clean
}

src_install() {
	autotools-utils_src_install

	insinto /usr/share/aclocal
	doins ac_find_xbae.m4

	 use doc && dohtml -r doc/*

	if use examples; then
		find examples -name '*akefile*' -delete || die
		rm examples/{testall,extest} || die
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi
}