x11-misc/lavaps/lavaps-2.7-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/lavaps/lavaps-2.7-r2.ebuild,v 1.2 2008/06/29 12:44:25 loki_val Exp $

inherit eutils

DESCRIPTION="Lava Lamp graphical representation of running processes."
HOMEPAGE="http://www.isi.edu/~johnh/SOFTWARE/LAVAPS/"
SRC_URI="http://www.isi.edu/~johnh/SOFTWARE/LAVAPS/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="gtk"

DEPEND=">=dev-lang/tk-8.3.3
	gtk? ( >=x11-libs/gtk+-2.2
		>=gnome-base/libgnomecanvas-2.2
		>=gnome-base/libgnomeui-2.2 )
	!gtk? ( dev-lang/tcl )"
RDEPEND="${DEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}-this-makes-it-compile.patch"
	epatch "${FILESDIR}/${P}-build-fixes.patch"
	epatch "${FILESDIR}/${P}-gcc43.patch"
}

src_compile() {
	local myconf="--with-x"
	use gtk && myconf="${myconf} --with-gtk" \
		|| myconf="${myconf} --with-tcltk"

	econf ${myconf} || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	dodoc README
	doman doc/lavaps.1
	dohtml doc/*.html
}