dev-ruby/better_html: update EAPI 7 -> 8

Signed-off-by: Hans de Graaff <hans@degraaff.org>

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-ruby/better_html/better_html-1.0.16-r1.ebuild b/dev-ruby/better_html/better_html-1.0.16-r1.ebuild
new file mode 100644
index 00000000..68b69c07
--- /dev/null
+++ b/dev-ruby/better_html/better_html-1.0.16-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby27 ruby30"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Better HTML for Rails"
+HOMEPAGE="https://github.com/Shopify/better-html"
+LICENSE="MIT"
+
+KEYWORDS="~amd64"
+SLOT="$(ver_cut 1)"
+IUSE=""
+
+ruby_add_rdepend "
+	>=dev-ruby/actionview-4.2:*
+	>=dev-ruby/activesupport-4.2:*
+	dev-ruby/ast:0
+	dev-ruby/erubi:0
+	>=dev-ruby/html_tokenizer-0.0.6 =dev-ruby/html_tokenizer-0.0*
+	>=dev-ruby/parser-2.4
+	dev-ruby/smart_properties
+"
+
+ruby_add_bdepend "test? ( dev-ruby/mocha dev-ruby/railties:7.0 )"
+
+all_ruby_prepare() {
+	sed -i -e '/mocha/ s/mini_test/minitest/' -e '1i gem "actionview", " ~> 7.0.0" ; gem "railties", "~> 7.0.0"' test/test_helper.rb || die
+
+	# The ERB implementation tests don't work with Rails 6.0, even though erblint seems to work fine with it. Skip them for now.
+	rm -f test/better_html/better_erb/implementation_test.rb || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:test:. -e "Dir['test/**/*_test.rb'].each{|f| require f}" || die
+}