Add ebuild for dev-libs/efl

Package-Manager: portage-2.2.7
Manifest-Sign-Key: 3C5CF75A

3 files changed, 277 insertions, 0 deletions

diff --git a/dev-libs/efl/Manifest b/dev-libs/efl/Manifest
new file mode 100644
index 0000000..370e01f
--- /dev/null
+++ b/dev-libs/efl/Manifest
@@ -0,0 +1,15 @@
+-----BEGIN PGP SIGNED MESSAGE-----
+Hash: SHA256
+
+DIST efl-1.8.3.tar.bz2 28097589 SHA256 e78479ce5255ecd310d8b27f1dc32a51c3db1271742f85f8d0a696ebfcc8e72f SHA512 5b0f4446531be8ff46011d64a4f352bbc2b3d8972f57340abe14f425b916a7fdddd53a3c7106748d884e41e34fd6b44d93ff9f2580a08e169128015883dc9020 WHIRLPOOL 4a0e29740866d0bb12ed35f717dce6d68459d43ea67531504145781e8847729d95fc2167135b333a9e2bb01581265c0742c35ccc2a2d34ec21b4b636ea50005b
+-----BEGIN PGP SIGNATURE-----
+Version: GnuPG v2.0.22 (GNU/Linux)
+
+iQEcBAEBCAAGBQJSuETWAAoJELjwI6Q8XPdauAwH+QGjPlNKEkwXJ5jrJ00JThsB
+N6b9iHcFX1iDVaGiGO9sBSEABERFJzKtl0OBimt5d5mueskAnnE7SNWeGFu01JOs
+t3NYFPXBgNIwDrw/PgrypWa6VXM3B9GPAbr3nmvQ6DBlowT9+kCMgy6LUK8fr9or
+V/d6tgPLczCJScX90etPp6KzScByyuuAa16lJVCF0oOk40X8aQYnCBZZf+uSEEBt
+/AawO9TcTGzIG6uZW1nt3uZCEq136qy7/DdbJDeuj+BS18qqzCFG/lqS7bt61oWW
+aSzEY6QD5Kc+C9k2KSgOYGPHNYzOL33wHL2so/mhWVE8FricKB0q6BhGSXaZnK0=
+=b5Ma
+-----END PGP SIGNATURE-----
diff --git a/dev-libs/efl/efl-1.8.3.ebuild b/dev-libs/efl/efl-1.8.3.ebuild
new file mode 100644
index 0000000..90530af
--- /dev/null
+++ b/dev-libs/efl/efl-1.8.3.ebuild
@@ -0,0 +1,236 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+
+inherit eutils
+
+DESCRIPTION="Enlightenment Foundation Core Libraries"
+HOMEPAGE="http://www.enlightenment.org/"
+SRC_URI="http://download.enlightenment.org/rel/libs/${PN}/${P}.tar.bz2"
+
+LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RESTRICT="test"
+
+IUSE="+X audio debug doc drm egl fbcon +fontconfig fribidi gif gles glib gnutls gstreamer harfbuzz ibus jp2k +jpeg nls +opengl ssl physics pixman +png pulseaudio scim sdl static-libs systemd test tiff tslib v4l2 wayland webp xcb xim xine xpm"
+
+COMMON_DEP="
+	dev-lang/lua
+	sys-apps/dbus
+	>=sys-apps/util-linux-2.20.0
+	sys-libs/zlib
+	virtual/udev
+	X? (
+		x11-libs/libX11
+		gles? (
+			media-libs/mesa[egl,gles2]
+			x11-libs/libXrender
+		)
+		opengl? (
+			virtual/opengl
+			x11-libs/libXrender
+		)
+		xcb? (
+			x11-libs/libxcb
+			x11-libs/pixman
+			x11-libs/xcb-util
+			x11-libs/xcb-util-image
+			x11-libs/xcb-util-keysyms
+			x11-libs/xcb-util-renderutil
+			x11-libs/xcb-util-wm
+		)
+		!xcb? (
+			x11-libs/libXScrnSaver
+			x11-libs/libXcomposite
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			x11-libs/libXinerama
+			x11-libs/libXp
+			x11-libs/libXrandr
+			x11-libs/libXrender
+			x11-libs/libXtst
+		)
+	)
+	audio? ( media-libs/libsndfile )
+	debug? ( dev-util/valgrind )
+	fontconfig? ( media-libs/fontconfig )
+	fribidi? ( dev-libs/fribidi )
+	gif? ( media-libs/giflib )
+	glib? ( dev-libs/glib )
+	gnutls? ( net-libs/gnutls )
+	!gnutls? ( ssl? ( dev-libs/openssl ) )
+	gstreamer? (
+		media-libs/gstreamer:0.10
+		media-libs/gst-plugins-good:0.10
+		media-plugins/gst-plugins-ffmpeg:0.10
+	)
+	harfbuzz? ( media-libs/harfbuzz )
+	ibus? ( app-i18n/ibus )
+	jp2k? ( media-libs/openjpeg )
+	jpeg? ( virtual/jpeg )
+	nls? ( sys-devel/gettext )
+	physics? ( sci-physics/bullet )
+	pixman? ( x11-libs/pixman )
+	png? ( media-libs/libpng:0= )
+	pulseaudio? (
+		media-sound/pulseaudio
+		media-libs/libsndfile
+	)
+	scim?	( app-i18n/scim )
+	sdl? (
+		>=media-libs/libsdl-1.2.0:0[opengl?]
+		gles? ( >=media-libs/libsdl-1.2.0:0[opengl] )
+	)
+	systemd? ( sys-apps/systemd )
+	tiff? ( media-libs/tiff:0 )
+	tslib? ( x11-libs/tslib )
+	wayland? (
+		>=dev-libs/wayland-1.3.0:0
+		>=x11-libs/libxkbcommon-0.3.1
+		egl? ( media-libs/mesa[egl,gles2] )
+	)
+	webp? ( media-libs/libwebp )
+	xine? ( >=media-libs/xine-lib-1.1.1 )
+	xpm? ( x11-libs/libXpm )"
+DEPEND="${COMMON_DEP}
+	!!dev-libs/ecore
+	!!dev-libs/edbus
+	!!dev-libs/eet
+	!!dev-libs/eeze
+	!!dev-libs/efreet
+	!!dev-libs/eina
+	!!dev-libs/eio
+	!!dev-libs/embryo
+	!!dev-libs/eobj
+	!!dev-libs/ephysics
+	!!media-libs/edje
+	!!media-libs/emotion
+	!!media-libs/ethumb
+	!!media-libs/evas
+	doc? ( app-doc/doxygen )
+	test? ( dev-libs/check )"
+
+src_configure() {
+	local config=()
+
+	# gnutls / openssl
+	if use gnutls; then
+		config+=( --with-crypto=gnutls )
+		use ssl && \
+			einfo "You enabled both USE=ssl and USE=gnutls, using gnutls"
+	elif use ssl; then
+		config+=( --with-crypto=openssl )
+	else
+		config+=( --with-crypto=none )
+	fi
+
+	# X
+	config+=(
+		$(use_with X x)
+		--with-x11=$(usex xcb xcb xlib)
+	)
+	if use opengl; then
+		config+=( --with-opengl=full )
+		use gles &&  \
+			einfo "You enabled both USE=opengl and USE=gles, using opengl"
+	elif use gles; then
+		config+=( --with-opengl=es )
+	else
+		config+=( --with-opengl=none )
+	fi
+
+	# wayland
+	config+=(
+		$(use_enable egl)
+		$(use_enable wayland)
+	)
+
+	# audio
+	# there is no alsa support currently
+	if use audio || use pulseaudio; then
+		config+=(
+			--enable-audio
+			$(use_enable pulseaudio)
+		)
+	else
+		config+=( --disable-audio )
+	fi
+
+	config+=(
+		$(use_enable drm)
+		$(use_enable doc)
+		$(use_enable fbcon fb)
+		$(use_enable fontconfig)
+		$(use_enable fribidi)
+		$(use_enable gstreamer)
+		$(use_enable harfbuzz)
+		$(use_enable ibus)
+		$(use_enable nls)
+		$(use_enable physics)
+		$(use_enable pixman)
+		$(use_enable pixman pixman-font)
+		$(use_enable pixman pixman-rect)
+		$(use_enable pixman pixman-line)
+		$(use_enable pixman pixman-poly)
+		$(use_enable pixman pixman-image)
+		$(use_enable pixman pixman-image-scale-sample)
+		$(use_enable scim)
+		$(use_enable sdl)
+		$(use_enable static-libs static)
+		$(use_enable systemd)
+		$(use_enable tslib)
+		$(use_enable v4l2)
+		$(use_enable xim)
+		$(use_enable xine)
+
+		# image loders
+		--enable-image-loader-bmp
+		--enable-image-loader-eet
+		--enable-image-loader-generic
+		--enable-image-loader-ico
+		--enable-image-loader-ppm
+		--enable-image-loader-psd
+		--enable-image-loader-tga
+		--enable-image-loader-wbmp
+		$(use_enable gif image-loader-gif)
+		$(use_enable jp2k image-loader-jp2k)
+		$(use_enable jpeg image-loader-jpeg)
+		$(use_enable png image-loader-png)
+		$(use_enable tiff image-loader-tiff)
+		$(use_enable webp image-loader-webp)
+		$(use_enable xpm image-loader-xpm)
+
+		--enable-cserve
+		--enable-libmount
+		--enable-threads
+		--enable-xinput22
+
+		--disable-gesture
+		--disable-multisense
+		--disable-tizen
+		--disable-xinput2
+
+		--with-profile=$(usex debug debug release)
+		--with-glib=$(usex glib yes no)
+		--with-tests=$(usex test regular none)
+	)
+
+	econf "${config[@]}"
+}
+
+src_test() {
+	MAKEOPTS+=" -j1"
+	default
+}
+
+src_install() {
+	MAKEOPTS+=" -j1"
+	default
+	prune_libtool_files
+}
diff --git a/dev-libs/efl/metadata.xml b/dev-libs/efl/metadata.xml
new file mode 100644
index 0000000..07b0dc3
--- /dev/null
+++ b/dev-libs/efl/metadata.xml
@@ -0,0 +1,26 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer>
+    <email>sera@gentoo.org</email>
+    <name>Ralph Sennhauser</name>
+  </maintainer>
+  <use>
+    <flag name="audio"></flag>
+    <flag name="drm"></flag>
+    <flag name="egl"></flag>
+    <flag name="fribidi"></flag>
+    <flag name="gles"></flag>
+    <flag name="glib"></flag>
+    <flag name="harfbuzz"></flag>
+    <flag name="ibus"></flag>
+    <flag name="jp2k"></flag>
+    <flag name="physics"></flag>
+    <flag name="pixman"></flag>
+    <flag name="scim"></flag>
+    <flag name="tslib"></flag>
+    <flag name="v4l2"></flag>
+    <flag name="webp"></flag>
+    <flag name="xim"></flag>
+  </use>
+</pkgmetadata>