1 files changed, 84 insertions, 0 deletions
diff --git a/media-sound/guayadeque/guayadeque-9999.ebuild b/media-sound/guayadeque/guayadeque-9999.ebuild
new file mode 100644
index 0000000..d770f6e
--- /dev/null
+++ b/media-sound/guayadeque/guayadeque-9999.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/guayadeque/guayadeque-0.3.1.ebuild,v 1.6 2011/12/05 16:49:30 jlec Exp $
+
+EAPI=3
+
+WX_GTK_VER="2.8"
+
+inherit cmake-utils wxwidgets subversion
+
+DESCRIPTION="Music management program designed for all music enthusiasts"
+HOMEPAGE="http://guayadeque.org"
+SRC_URI=""
+ESVN_REPO_URI="http://guayadeque.svn.sourceforge.net/svnroot/${PN}/Trunk"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ayatana ipod"
+
+# No test available, Making src_test fail
+RESTRICT="test"
+
+RDEPEND="
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-vcs/subversion
+	media-libs/flac
+	media-libs/gstreamer
+	media-libs/taglib
+	media-plugins/gst-plugins-soup
+	net-misc/curl
+	sys-apps/dbus
+	x11-libs/wxGTK:2.8[X]
+	ayatana? ( dev-libs/libindicate )
+	ipod? ( media-libs/libgpod )"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	dev-util/pkgconfig
+	dev-util/cmake"
+
+# echo $(cat po/CMakeLists.txt | grep ADD_SUBDIRECTORY | sed 's#ADD_SUBDIRECTORY( \(\w\+\) )#\1#')
+LANGS="es uk it de fr is nb th cs ru hu sv nl pt_BR pt"
+for l in ${LANGS}; do
+	IUSE="$IUSE linguas_${l}"
+done
+
+src_prepare() {
+	for l in ${LANGS} ; do
+		if ! use linguas_${l} ; then
+			sed \
+				-e "/${l}/d" \
+				-i po/CMakeLists.txt || die
+		fi
+	done
+
+	if ! use ipod; then
+		sed \
+			-e '/PKG_CHECK_MODULES( LIBGPOD/,/^ENDIF/d' \
+			-i CMakeLists.txt || die
+	fi
+
+	if ! use ayatana; then
+		sed \
+			-e '/PKG_CHECK_MODULES( LIBINDICATE/,/^ENDIF/d' \
+			-i CMakeLists.txt || die
+	fi
+
+	base_src_prepare
+
+	sed 's:-O2::g' -i CMakeLists.txt || die
+}
+
+src_configure() {
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+}