dev-libs/libinput: Bump to version 1.16.1

Package-Manager: Portage-3.0.2, Repoman-2.3.23
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 84 insertions, 0 deletions

diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index df59275cd86f..a66ce87d9cb7 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1,2 +1,3 @@
 DIST libinput-1.15.6.tar.xz 584184 BLAKE2B 9963e9df41cb32c40454a3dc76975315f74a2e8b2549c037868c651c2ada90f77a605048ba603a4c01d0641fc39154b578a766309f1c376c07d3bdd02dfd387c SHA512 90459e5a1f22fd42ffcbab157b461e4514c30803bcebdaced76c65c05cccfa6f259640a50497055fe7ed0b376a6979f6d1d01227ae447fe60ba88fa81142b969
 DIST libinput-1.16.0.tar.xz 593304 BLAKE2B 959b9e5720b1aa196eb45cf772e8edc800032ee0cd2db1c06537ed979cbf83eaef8c50d2f6aa194e8cf668fcfd1bcb46767a897f99679867b7d816e2567c16a8 SHA512 0c932a88f2a1d23ebef0d58c0cdbfb558e9e3d990fca15b21f5b9011bdd1bc2da81aad374fcdb8f4590f6ee2fc45e668e0583371ceb354437e585240e687aac6
+DIST libinput-1.16.1.tar.xz 595548 BLAKE2B 497089248c2104ff7784b7d46d8e846047e054f01c6ea192f1c41171b39213fa1f19be8c8253c32f988bfc6f025d2519697256ffaf62884182c511bcd5c5d335 SHA512 86b2d563c2cff2b3d3cae3acdd399030cc785cc9859a06357a99565ef51f95122a8427c8c0883121fb0760613460a29c8cd8c7a7e3ac68115c10330b3b75cbe0
diff --git a/dev-libs/libinput/libinput-1.16.1.ebuild b/dev-libs/libinput/libinput-1.16.1.ebuild
new file mode 100644
index 000000000000..cfbdf1816876
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.16.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 2014-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/10"
+[[ "$(ver_cut 3)" -gt 900 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="doc input_devices_wacom test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/commonmark[${PYTHON_USEDEP}]
+			dev-python/recommonmark[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+		')
+		>=app-doc/doxygen-1.8.3
+		>=media-gfx/graphviz-2.38.0
+	)
+"
+#	test? ( dev-util/valgrind )
+RDEPEND="
+	input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
+	>=dev-libs/libevdev-1.3
+	>=sys-libs/mtdev-1.1
+	virtual/libudev:=
+	virtual/udev
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-libs/check-0.9.10 )"
+
+python_check_deps() {
+	has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+	has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+	has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# gui can be built but will not be installed
+	local emesonargs=(
+		-Ddebug-gui=false
+		$(meson_use doc documentation)
+		$(meson_use input_devices_wacom libwacom)
+		$(meson_use test tests)
+		-Dudev-dir="${EPREFIX}$(get_udevdir)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc ; then
+		docinto html
+		dodoc -r "${BUILD_DIR}"/Documentation/.
+	fi
+}
+
+pkg_postinst() {
+	pkgname="dev-python/python-libevdev"
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version "${pkgname}" ; then
+		einfo "${pkgname} must be installed to use the"
+		einfo "libinput measure and libinput replay tools."
+	fi
+
+	udevadm hwdb --update --root="${ROOT}"
+}